Implement stabilize_sig_stack

Author: Blackhex

winsup/cygwin/scripts/gendef

@@ -407,7 +407,75 @@ _ZN7_cygtls3popEv:
 
 	.seh_proc stabilize_sig_stack
 stabilize_sig_stack:
+	// prologue
+	stp	fp, lr, [sp, #-0x10]!		// save FP and LR registers
+	stp	x9, x10, [sp, #-0x10]!		// save x9 and x10 registers used next
+	stp	x11, x12, [sp, #-0x10]!		// save x11 and x12 registers used next
+	stp	x13, x14, [sp, #-0x10]!		// save x13 register used next and x14 just to keep stack orientation and alignment
 	.seh_endprologue
+
+	ldr	x10, [x18, #0x8]		// keep thread local storage base address in x10
+
+	// try to acquire the lock
+	mov	w9, #1				// set up value for atomic exchange
+	ldr	x11, =_cygtls.stacklock		// load the symbol address/offset
+	add	x11, x10, x11			// calculate final address
+1:
+	ldaxr	w12, [x11]			// load with acquire semantics
+	stlxr	w13, w9, [x11]			// store with release semantics
+	cbnz	w13, 1b				// if store failed, retry
+	cbz	w12, 2f				// if lock was acquired, continue
+	yield					// yield to allow other threads to run
+	b	1b				// retry acquiring the lock
+2:
+	// lock acquired, increment incyg counter
+	ldr	x11, =_cygtls.incyg		// load the symbol address/offset
+	add	x11, x10, x11			// calculate final address
+	ldr	w9, [x11]			// load current value of incyg counter
+	add	w9, w9, #1			// increment incyg counter
+	str	w9, [x11]			// store incremented value back
+
+	// check if there is a current signal to handle 
+	ldr	x11, =_cygtls.current_sig	// load the symbol address/offset
+	ldr	w9, [x10, x11]			// load current value of current_sig
+	cbz	w9, 3f				// if no current signal, jump to cleanup
+
+	// release lock before calling signal handler
+	ldr	x11, =_cygtls.stacklock		// load the symbol address/offset
+	add	x11, x10, x11			// calculate final address
+	ldr	w9, [x11]			// load current value of stacklock counter
+	sub	w9, w9, #1			// decrement stacklock counter
+	stlr	w9, [x11]			// store with release semantics
+
+	// prepare arguments and call signal handler
+	ldr	x0, =_cygtls.start_offset	// load the symbol address/offset
+	add	x0, x10, x0			// calculate final address
+	bl	_ZN7_cygtls19call_signal_handlerEv
+
+	// decrement incyg counter
+	ldr	x11, =_cygtls.incyg		// load the symbol address/offset
+	add	x11, x10, x11			// calculate final address
+	ldr	w9, [x11]			// load current value of incyg counter
+	sub	w9, w9, #1			// decrement incyg counter
+	str	w9, [x11]			// store incremented value back
+
+	// go to the beginning to handle another signal
+	b	1b
+3:
+	// no signal to handle, decrement incyg counter
+	ldr	x11, =_cygtls.incyg		// load the symbol address/offset
+	add	x11, x10, x11			// calculate final address
+	ldr	w9, [x11]			// load current value of incyg counter
+	sub	w9, w9, #1			// decrement incyg counter
+	str	w9, [x11]			// store incremented value back
+
+	mov	x0, x10				// return TLS address in x0 (return value)
+
+	// epilogue
+	ldp	x13, x14, [sp], #0x10
+	ldp	x11, x12, [sp], #0x10
+	ldp	x9, x10, [sp], #0x10
+	ldp	fp, lr, [sp], #0x10
 	ret
 	.seh_endproc
 EOF