Apply Spotless only in JDK 11+

Author: emlun

buildSrc/build.gradle.kts

@@ -10,8 +10,12 @@ repositories {
 }
 
 dependencies {
-  implementation("com.diffplug.spotless:spotless-plugin-gradle:6.18.0")
   implementation("info.solidsoft.gradle.pitest:gradle-pitest-plugin:1.9.11")
   implementation("io.franzbecker:gradle-lombok:5.0.0")
-  implementation("io.github.cosmicsilence:gradle-scalafix:0.1.14")
+
+  // Spotless dropped Java 8 support in version 2.33.0
+  if (JavaVersion.current().isJava11Compatible) {
+    implementation("com.diffplug.spotless:spotless-plugin-gradle:6.18.0")
+    implementation("io.github.cosmicsilence:gradle-scalafix:0.1.14")
+  }
 }

buildSrc/src/main/groovy/project-convention-code-formatting-internal.gradle

@@ -0,0 +1,33 @@
+project.apply(plugin: "com.diffplug.spotless")
+project.apply(plugin: "io.github.cosmicsilence.scalafix")
+
+spotless {
+    java {
+        googleJavaFormat()
+    }
+    scala {
+        scalafmt("2.6.3").configFile(project.rootProject.file("scalafmt.conf"))
+    }
+}
+
+scalafix {
+    configFile.set(project.rootProject.file("scalafix.conf"))
+
+    // Work around dependency resolution issues in April 2022
+    semanticdb.autoConfigure.set(true)
+    semanticdb.version.set("4.5.5")
+}
+
+project.dependencies.scalafix("com.github.liancheng:organize-imports_2.13:0.6.0")
+
+
+project.afterEvaluate {
+    // These need to be in afterEvaluate due to this plugin
+    // being conditionally applied for Java 11+ only
+    project.tasks.spotlessApply.configure { dependsOn(project.tasks.scalafix) }
+    project.tasks.spotlessCheck.configure { dependsOn(project.tasks.checkScalafix) }
+
+    // Scalafix adds tasks in afterEvaluate, so their configuration must be deferred
+    project.tasks.scalafix.finalizedBy(project.tasks.spotlessApply)
+    project.tasks.checkScalafix.finalizedBy(project.tasks.spotlessCheck)
+}

buildSrc/src/main/kotlin/project-convention-code-formatting.gradle.kts

@@ -1,32 +1,4 @@
-plugins {
-    id("com.diffplug.spotless")
-    id("io.github.cosmicsilence.scalafix")
-}
-
-spotless {
-    java {
-        googleJavaFormat()
-    }
-    scala {
-        scalafmt("2.6.3").configFile(project.rootProject.file("scalafmt.conf"))
-    }
-}
-
-scalafix {
-    configFile.set(project.rootProject.file("scalafix.conf"))
-
-    // Work around dependency resolution issues in April 2022
-    semanticdb.autoConfigure.set(true)
-    semanticdb.version.set("4.5.5")
-}
-
-project.dependencies.scalafix("com.github.liancheng:organize-imports_2.13:0.6.0")
-
-project.tasks.spotlessApply.configure { dependsOn(project.tasks["scalafix"]) }
-project.tasks.spotlessCheck.configure { dependsOn(project.tasks["checkScalafix"]) }
-
-// Scalafix adds tasks in afterEvaluate, so their configuration must be deferred
-project.afterEvaluate {
-    project.tasks["scalafix"].finalizedBy(project.tasks.spotlessApply)
-    project.tasks["checkScalafix"].finalizedBy(project.tasks.spotlessCheck)
+// Spotless dropped Java 8 support in version 2.33.0
+if (JavaVersion.current().isJava11Compatible) {
+    apply(plugin = "project-convention-code-formatting-internal")
 }