add fona example

Author: toddtreece

examples/fona/fona.ino

@@ -0,0 +1,95 @@
+//
+// Adafruit IO FONA Example
+//
+// Written by Todd Treece for Adafruit Industries
+// Copyright (c) 2016 Adafruit Industries
+// Licensed under the MIT license.
+//
+// All text above must be included in any redistribution.
+//
+
+/************************** Cellular Setup **********************************/
+
+#define APN ""
+#define APN_USER ""
+#define APN_PASS ""
+
+/************************* Adafruit IO Setup ********************************/
+
+#define IO_USERNAME    "your_username"
+#define IO_KEY         "your_key"
+
+/*************************** Client Setup ***********************************/
+
+#include "AdafruitIO_FONA.h"
+AdafruitIO_FONA io(APN, APN_USER, APN_PASS);
+
+/************************ Example Starts Here *******************************/
+
+// this int will hold the current count for our sketch
+int count = 0;
+
+// set up the 'counter' feed
+AdafruitIO_Feed *counter = io.feed("counter");
+
+void setup() {
+
+  // start the serial connection
+  Serial.begin(115200);
+
+  // wait for serial monitor to open
+  while(! Serial);
+
+  Serial.print("Connecting to Adafruit IO");
+
+  // connect to io.adafruit.com
+  io.connect(IO_USERNAME, IO_KEY);
+
+  // set up a message handler for the count feed.
+  // the handleMessage function (defined below)
+  // will be called whenever a message is
+  // received from adafruit io.
+  counter->onMessage(handleMessage);
+
+  // wait for a connection
+  while(io.status() < AIO_CONNECTED) {
+    Serial.print(".");
+    delay(500);
+  }
+
+  // we are connected
+  Serial.println();
+  Serial.println(io.statusText());
+
+}
+
+void loop() {
+
+  // this should be present at the top of your loop
+  // function. it keeps the client connected to
+  // io.adafruit.com, and processes any data from
+  // the server
+  io.run();
+
+  // save count to the 'counter' feed on Adafruit IO
+  Serial.print("sending -> ");
+  Serial.println(count);
+  counter->save(count);
+
+  // increment the count by 1
+  count++;
+
+  // wait one second (1000 milliseconds == 1 second)
+  delay(1000);
+
+}
+
+// this function is called whenever a 'counter' message
+// is received from Adafruit IO. it was attached to
+// the counter feed in the setup() function above.
+void handleMessage(AdafruitIO_Data *data) {
+
+  Serial.print("received <- ");
+  Serial.println(data->value());
+
+}