msc spiflash example work in read mode (write require using of erase and cache)

Author: hathach

examples/msc_spiflash/msc_spiflash.ino

@@ -0,0 +1,110 @@
+/*
+ * The MIT License (MIT)
+ *
+ * Copyright (c) 2019 Ha Thach for Adafruit Industries
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a copy
+ * of this software and associated documentation files (the "Software"), to deal
+ * in the Software without restriction, including without limitation the rights
+ * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ * copies of the Software, and to permit persons to whom the Software is
+ * furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+ * THE SOFTWARE.
+ */
+
+#include "Adafruit_TinyUSB.h"
+#include "Adafruit_SPIFlash.h"
+
+// Configuration of the flash chip pins and flash fatfs object.
+// You don't normally need to change these if using a Feather/Metro
+// M0 express board.
+#define FLASH_TYPE     SPIFLASHTYPE_W25Q16BV  // Flash chip type.
+                                              // If you change this be
+                                              // sure to change the fatfs
+                                              // object type below to match.
+
+
+#if defined(__SAMD51__)
+  // Alternatively you can define and use non-SPI pins, QSPI isnt on a sercom
+  Adafruit_SPIFlash flash(PIN_QSPI_SCK, PIN_QSPI_IO1, PIN_QSPI_IO0, PIN_QSPI_CS);
+#else
+  #if (SPI_INTERFACES_COUNT == 1)
+    #define FLASH_SS       SS                    // Flash chip SS pin.
+    #define FLASH_SPI_PORT SPI                   // What SPI port is Flash on?
+  #else
+    #define FLASH_SS       SS1                    // Flash chip SS pin.
+    #define FLASH_SPI_PORT SPI1                   // What SPI port is Flash on?
+  #endif
+
+Adafruit_SPIFlash flash(FLASH_SS, &FLASH_SPI_PORT);     // Use hardware SPI
+#endif
+
+Adafruit_USBD_MSC usb_msc;
+
+// the setup function runs once when you press reset or power the board
+void setup()
+{
+  flash.begin(FLASH_TYPE);
+    
+  // Set disk vendor id, product id and revision with string up to 8, 16, 4 characters respectively
+  usb_msc.setID("Adafruit", "SPI Flash", "1.0");
+
+  // Set callback
+  usb_msc.setReadWriteCallback(msc_read_cb, msc_write_cb, msc_flush_cb);
+
+  // Set disk size, block size should be 512 regardless of spi flash page size
+  usb_msc.setCapacity(flash.pageSize()*flash.numPages()/512, 512);
+
+  // MSC is ready for read/write
+  usb_msc.setUnitReady(true);
+  
+  usb_msc.begin();
+
+  Serial.begin(115200);
+  while ( !Serial ) delay(10);   // wait for native usb
+
+  Serial.println("Mass Storage SPI Flash example");
+  Serial.print("Page size: "); Serial.println(flash.pageSize());
+  Serial.print("Page num : "); Serial.println(flash.numPages());
+}
+
+void loop()
+{
+  // nothing to do
+}
+
+// Callback invoked when received READ10 command.
+// Copy disk's data to buffer (up to bufsize) and 
+// return number of copied bytes (must be multiple of block size) 
+int32_t msc_read_cb (uint32_t lba, void* buffer, uint32_t bufsize)
+{
+  const uint32_t addr = lba*512;
+  return flash.readBuffer(addr, (uint8_t*) buffer, bufsize);
+}
+
+// Callback invoked when received WRITE10 command.
+// Process data in buffer to disk's storage and 
+// return number of written bytes (must be multiple of block size)
+int32_t msc_write_cb (uint32_t lba, uint8_t* buffer, uint32_t bufsize)
+{
+  // need to erase & caching write back
+  const uint32_t addr = lba*512;
+  return flash.writeBuffer(addr, buffer, bufsize);
+}
+
+// Callback invoked when WRITE10 command is completed (status received and accepted by host).
+// used to flush any pending cache.
+void msc_flush_cb (void)
+{
+  // nothing to do
+}