Merge pull request #2 from jtimberman/f-for-stupid-americans

Add configurable temperature unit support for people from Liberia, Puerto Rico, Guam, Micronesia, United States Virgin Islands, Cayman Islands, American Samoa, Northern Mariana Islands, Marshall Islands and Palau. Oh, and the USA.
 
https://worldpopulationreview.com/country-rankings/countries-that-use-fahrenheit

Author: aglet

sparkweather-test.el

@@ -390,6 +390,47 @@
       (should (= (length overlaps) 1))
       (should (equal (car overlaps) '("All Day" "Lunch" 12 14))))))
 
+(ert-deftest sparkweather-test-temperature-unit-symbol-celsius ()
+  "Temperature unit symbol returns °C for celsius."
+  (let ((sparkweather-temperature-unit 'celsius))
+    (should (equal (sparkweather--temperature-unit-symbol) "°C"))))
+
+(ert-deftest sparkweather-test-temperature-unit-symbol-fahrenheit ()
+  "Temperature unit symbol returns °F for fahrenheit."
+  (let ((sparkweather-temperature-unit 'fahrenheit))
+    (should (equal (sparkweather--temperature-unit-symbol) "°F"))))
+
+(ert-deftest sparkweather-test-temperature-unit-symbol-c ()
+  "Temperature unit symbol returns °C for \"C\" string."
+  (let ((sparkweather-temperature-unit "C"))
+    (should (equal (sparkweather--temperature-unit-symbol) "°C"))))
+
+(ert-deftest sparkweather-test-temperature-unit-symbol-f ()
+  "Temperature unit symbol returns °F for \"F\" string."
+  (let ((sparkweather-temperature-unit "F"))
+    (should (equal (sparkweather--temperature-unit-symbol) "°F"))))
+
+(ert-deftest sparkweather-test-convert-temperature-celsius ()
+  "Temperature conversion with celsius returns value unchanged."
+  (let ((sparkweather-temperature-unit 'celsius))
+    (should (= (sparkweather--convert-temperature 0) 0))
+    (should (= (sparkweather--convert-temperature 20) 20))
+    (should (= (sparkweather--convert-temperature -10) -10))))
+
+(ert-deftest sparkweather-test-convert-temperature-fahrenheit ()
+  "Temperature conversion with fahrenheit converts correctly."
+  (let ((sparkweather-temperature-unit 'fahrenheit))
+    (should (= (sparkweather--convert-temperature 0) 32))
+    (should (= (sparkweather--convert-temperature 100) 212))
+    (should (= (sparkweather--convert-temperature -40) -40))
+    (should (= (sparkweather--convert-temperature 20) 68))))
+
+(ert-deftest sparkweather-test-convert-temperature-f-string ()
+  "Temperature conversion with \"F\" string converts correctly."
+  (let ((sparkweather-temperature-unit "F"))
+    (should (= (sparkweather--convert-temperature 0) 32))
+    (should (= (sparkweather--convert-temperature 20) 68))))
+
 (provide 'sparkweather-test)
 
 ;;; sparkweather-test.el ends here

sparkweather.el

@@ -111,6 +111,15 @@ Has no effect if `sparkweather-add-footer' is nil."
   :type 'boolean
   :group 'sparkweather)
 
+(defcustom sparkweather-temperature-unit 'celsius
+  "Temperature unit for display and API requests.
+Valid values are \\='celsius, \\='fahrenheit, \"C\", or \"F\"."
+  :type '(choice (const :tag "Celsius" celsius)
+                 (const :tag "Fahrenheit" fahrenheit)
+                 (const :tag "C" "C")
+                 (const :tag "F" "F"))
+  :group 'sparkweather)
+
 (defcustom sparkweather-lunch-start-hour 12
   "Start hour for lunch time window (24-hour format, 0-23).
 
@@ -151,6 +160,20 @@ DEPRECATED: Use `sparkweather-time-windows' instead."
                         'sparkweather-time-windows
                         "0.2.0")
 
+(defun sparkweather--temperature-unit-symbol ()
+  "Return the display symbol (°C or °F) for the configured temperature unit."
+  (pcase sparkweather-temperature-unit
+    ((or 'fahrenheit "F") "°F")
+    (_ "°C")))
+
+(defun sparkweather--convert-temperature (celsius)
+  "Convert CELSIUS temperature to the configured unit.
+Returns temperature in Fahrenheit if unit is set to fahrenheit or \"F\",
+otherwise returns CELSIUS unchanged."
+  (pcase sparkweather-temperature-unit
+    ((or 'fahrenheit "F") (+ (* celsius 1.8) 32))
+    (_ celsius)))
+
 (defun sparkweather--detect-invalid-windows (windows)
   "Detect windows with invalid hour ranges in WINDOWS list.
 Returns list of invalid windows as (NAME START END REASON), or nil if all valid.
@@ -548,15 +571,19 @@ Returns (temps precip-probs temp-min temp-max precip-max rainy-codes)."
 Returns list of entries for `tabulated-list-mode'."
   (pcase-let* ((`(,temps ,precip-probs ,temp-min ,temp-max ,precip-max ,rainy-codes)
                 (sparkweather--calculate-ranges data))
+               (converted-temps (mapcar #'sparkweather--convert-temperature temps))
                (`(,window-data ,highlights)
                 (sparkweather--prepare-windows data windows))
-               (temp-sparkline (sparkweather--sparkline temps highlights current-hour))
+               (temp-sparkline (sparkweather--sparkline converted-temps highlights current-hour))
                (precip-sparkline (sparkweather--sparkline precip-probs highlights current-hour))
                (worst-weather-code (and rainy-codes (apply #'max rainy-codes)))
                (worst-weather-info (when worst-weather-code
                                     (sparkweather--wmo-code-info worst-weather-code))))
     (append
-     (list (list 'temp (vector (format "%d—%d°C" (round temp-min) (round temp-max))
+     (list (list 'temp (vector (format "%d—%d%s"
+                                      (round (sparkweather--convert-temperature temp-min))
+                                      (round (sparkweather--convert-temperature temp-max))
+                                      (sparkweather--temperature-unit-symbol))
                                temp-sparkline)))
      (when worst-weather-info
        (list (list 'precip (vector (format "%d%% %s"