NativeProcess and Environment Variables on macOS

[pol2095]

Hello,

when I get the $PATH using NativeProcess on macOS, it work fine with adl, but the result it's different using adt bundle

package
{
	import flash.desktop.NativeProcess;
	import flash.desktop.NativeProcessStartupInfo;
	import flash.display.Sprite;
	import flash.events.ProgressEvent;
	import flash.filesystem.File;
	import flash.text.TextField;
	import flash.utils.IDataInput;

	public class Main extends Sprite
	{
		private var textField:TextField = new TextField();
		private var process:NativeProcess = new NativeProcess();
		
		public function Main()
		{
			textField.background = true;
			textField.border = true;
			textField.wordWrap = true;
			textField.multiline = true;
			textField.width = 400;
			textField.height = 200;
			this.addChild(textField);
			
			var file:File = new File("/bin/bash");
			var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo(); 
			nativeProcessStartupInfo.executable = file;
			process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData);
			process.start(nativeProcessStartupInfo);
			process.standardInput.writeUTFBytes("echo $PATH" + "\n");
			process.standardInput.writeUTFBytes("exit" + "\n");
		}
		
		private function onOutputData(event:ProgressEvent):void
		{ 
			var stdOut:IDataInput = process.standardOutput; 
			textField.text = stdOut.readUTFBytes(process.standardOutput.bytesAvailable);
		}
	}
}

adl return :

/opt/local/bin:/opt/local/sbin:/Users/user/apache-ant/ant/bin:/usr/local/bin:/System/Cryptexes/App/usr/bin:/usr/bin:/bin:/usr/sbin:/sbin:/Library/Apple/usr/bin

adt return :

/usr/bin:/bin:/usr/sbin:/sbin

and when I try ant -version, it work using adl and not using adt
ant is added in .bash_profile

The bundle is notarized.

Thanks

[ajwfrost]

Have you tried putting the path updates in .bashrc?
https://stackoverflow.com/questions/18350252/why-bash-profile-doesnt-work
Or potentially you could add source ~/.bash_profile as a first command?

[pol2095]

Thanks, source ~/.bash_profile is a good idea.

[pol2095]

for zsh, it's source ~/.zprofile

but I've found a better way :

var file:File = new File("/bin/bash");
var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo(); 
nativeProcessStartupInfo.executable = file;
process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData);
var processArgs:Vector.<String> = new Vector.<String>();
processArgs.push("--login");
nativeProcessStartupInfo.arguments = processArgs;
process.start(nativeProcessStartupInfo);