feat: job applications

Author: zcesur

lib/algora/jobs/jobs.ex

@@ -6,6 +6,7 @@ defmodule Algora.Jobs do
 
   alias Algora.Accounts
   alias Algora.Bounties.LineItem
+  alias Algora.Jobs.JobApplication
   alias Algora.Jobs.JobPosting
   alias Algora.Payments
   alias Algora.Payments.Transaction
@@ -92,4 +93,18 @@ defmodule Algora.Jobs do
       end
     end)
   end
+
+  def create_application(job_id, user) do
+    %JobApplication{}
+    |> JobApplication.changeset(%{job_id: job_id, user_id: user.id})
+    |> Repo.insert()
+  end
+
+  def list_user_applications(user) do
+    JobApplication
+    |> where([a], a.user_id == ^user.id)
+    |> select([a], a.job_id)
+    |> Repo.all()
+    |> MapSet.new()
+  end
 end

lib/algora/jobs/schemas/job_application.ex

@@ -0,0 +1,26 @@
+defmodule Algora.Jobs.JobApplication do
+  @moduledoc false
+  use Algora.Schema
+
+  alias Algora.Accounts.User
+  alias Algora.Jobs.JobPosting
+
+  typed_schema "job_applications" do
+    field :status, Ecto.Enum, values: [:pending], null: false, default: :pending
+
+    belongs_to :job, JobPosting, null: false
+    belongs_to :user, User, null: false
+
+    timestamps()
+  end
+
+  def changeset(job_application, attrs) do
+    job_application
+    |> cast(attrs, [:status, :job_id, :user_id])
+    |> generate_id()
+    |> validate_required([:status, :job_id, :user_id])
+    |> unique_constraint([:job_id, :user_id])
+    |> foreign_key_constraint(:job_id)
+    |> foreign_key_constraint(:user_id)
+  end
+end

lib/algora/jobs/schemas/job_posting.ex

@@ -15,7 +15,7 @@ defmodule Algora.Jobs.JobPosting do
     field :status, Ecto.Enum, values: [:initialized, :processing, :active, :expired], null: false, default: :initialized
     field :expires_at, :utc_datetime_usec
 
-    belongs_to :user, User
+    belongs_to :user, User, null: false
 
     timestamps()
   end

lib/algora_web/live/jobs_live.ex

@@ -2,6 +2,7 @@ defmodule AlgoraWeb.JobsLive do
   @moduledoc false
   use AlgoraWeb, :live_view
 
+  alias Algora.Accounts
   alias Algora.Jobs
   alias Algora.Jobs.JobPosting
 
@@ -16,7 +17,8 @@ defmodule AlgoraWeb.JobsLive do
      socket
      |> assign(:page_title, "Jobs")
      |> assign(:jobs, jobs)
-     |> assign(:form, to_form(changeset))}
+     |> assign(:form, to_form(changeset))
+     |> assign_user_applications()}
   end
 
   @impl true
@@ -64,6 +66,15 @@ defmodule AlgoraWeb.JobsLive do
                       </div>
                     </div>
                   </div>
+                  <%= if MapSet.member?(@user_applications, job.id) do %>
+                    <.button disabled class="opacity-50">
+                      <.icon name="tabler-check" class="h-4 w-4 mr-2 -ml-1" /> Applied
+                    </.button>
+                  <% else %>
+                    <.button phx-click="apply_job" phx-value-job-id={job.id}>
+                      <.icon name="github" class="h-4 w-4 mr-2" /> Apply with GitHub
+                    </.button>
+                  <% end %>
                 </div>
                 <div class="text-sm text-muted-foreground">
                   {job.description}
@@ -142,4 +153,34 @@ defmodule AlgoraWeb.JobsLive do
         {:noreply, assign(socket, :form, to_form(changeset))}
     end
   end
+
+  @impl true
+  def handle_event("apply_job", %{"job-id" => job_id}, socket) do
+    if socket.assigns[:current_user] do
+      if Accounts.has_fresh_token?(socket.assigns.current_user) do
+        case Jobs.create_application(job_id, socket.assigns.current_user) do
+          {:ok, _application} ->
+            {:noreply, assign_user_applications(socket)}
+
+          {:error, _changeset} ->
+            {:noreply, put_flash(socket, :error, "Failed to submit application. Please try again.")}
+        end
+      else
+        {:noreply, redirect(socket, external: Algora.Github.authorize_url())}
+      end
+    else
+      {:noreply, redirect(socket, external: Algora.Github.authorize_url())}
+    end
+  end
+
+  defp assign_user_applications(socket) do
+    user_applications =
+      if socket.assigns[:current_user] do
+        Jobs.list_user_applications(socket.assigns.current_user)
+      else
+        MapSet.new()
+      end
+
+    assign(socket, :user_applications, user_applications)
+  end
 end

priv/repo/migrations/20250424152036_create_job_postings.exs

@@ -13,7 +13,7 @@ defmodule Algora.Repo.Migrations.CreateJobPostings do
       add :email, :string, null: false
       add :status, :string, null: false, default: "initialized"
       add :expires_at, :utc_datetime_usec
-      add :user_id, references(:users, type: :string, on_delete: :restrict)
+      add :user_id, references(:users, type: :string, on_delete: :restrict), null: false
 
       timestamps()
     end

priv/repo/migrations/20250424152037_create_job_applications.exs

@@ -0,0 +1,18 @@
+defmodule Algora.Repo.Migrations.CreateJobApplications do
+  use Ecto.Migration
+
+  def change do
+    create table(:job_applications, primary_key: false) do
+      add :id, :string, primary_key: true
+      add :status, :string, null: false, default: "pending"
+      add :job_id, references(:job_postings, type: :string, on_delete: :restrict), null: false
+      add :user_id, references(:users, type: :string, on_delete: :restrict), null: false
+
+      timestamps()
+    end
+
+    create index(:job_applications, [:job_id])
+    create index(:job_applications, [:user_id])
+    create unique_index(:job_applications, [:job_id, :user_id])
+  end
+end