feat: add function to sync GitHub data in bulk

Author: zcesur

lib/algora/admin/admin.ex

@@ -22,18 +22,31 @@ defmodule Algora.Admin do
   alias Algora.Workspace.Installation
   alias Algora.Workspace.Jobs.FetchTopContributions
   alias Algora.Workspace.Jobs.ImportStargazer
+  alias Algora.Workspace.Jobs.SyncUser
   alias Algora.Workspace.Repository
   alias Algora.Workspace.Ticket
 
   require Logger
 
-  def sync_user(provider_login) do
-    with {:ok, data} <- Github.get_user_by_username(token(), provider_login),
-         {:ok, user} <- Workspace.ensure_user(token(), data["login"]) do
-      user
-      |> change(%{display_name: data["name"], location: data["location"]})
-      |> Repo.update()
-    end
+  def sync_users do
+    Repo.transact(
+      fn ->
+        User
+        # |> where([u], is_nil(u.display_name))
+        |> where([u], not is_nil(u.provider_login))
+        |> where([u], not is_nil(u.display_name))
+        |> where([u], u.display_name == u.provider_login)
+        |> where([u], not is_nil(u.provider_id))
+        |> where([u], u.type == :individual)
+        |> Repo.stream()
+        |> Enum.each(fn user -> sync_user(provider_id: user.provider_id) end)
+      end,
+      timeout: :infinity
+    )
+  end
+
+  def sync_user(opts) do
+    opts |> Map.new() |> SyncUser.new() |> Oban.insert()
   end
 
   def backfill_charge(id) do

lib/algora/workspace/jobs/sync_user.ex

@@ -0,0 +1,46 @@
+defmodule Algora.Workspace.Jobs.SyncUser do
+  @moduledoc false
+  use Oban.Worker,
+    queue: :sync_contribution,
+    max_attempts: 3
+
+  import Ecto.Changeset
+
+  alias Algora.Github
+  alias Algora.Repo
+  alias Algora.Workspace
+
+  @impl Oban.Worker
+  def perform(%Oban.Job{args: %{"provider_id" => provider_id}}) do
+    token = Github.TokenPool.get_token()
+
+    with {:ok, data} <- Github.get_user(token, provider_id),
+         {:ok, user} <- Workspace.ensure_user_by_provider_id(token, data["id"]) do
+      user
+      |> change(%{
+        display_name: data["name"],
+        location: data["location"],
+        provider_meta: data,
+        provider_login: data["login"]
+      })
+      |> Repo.update()
+    end
+  end
+
+  @impl Oban.Worker
+  def perform(%Oban.Job{args: %{"provider_login" => provider_login}}) do
+    token = Github.TokenPool.get_token()
+
+    with {:ok, data} <- Github.get_user_by_username(token, provider_login),
+         {:ok, user} <- Workspace.ensure_user_by_provider_id(token, data["id"]) do
+      user
+      |> change(%{
+        display_name: data["name"],
+        location: data["location"],
+        provider_meta: data,
+        provider_login: data["login"]
+      })
+      |> Repo.update()
+    end
+  end
+end