feat: auto-join orgs by matching domain on signup

Author: zcesur

lib/algora/accounts/accounts.ex

@@ -413,6 +413,47 @@ defmodule Algora.Accounts do
     params |> User.org_registration_changeset() |> Repo.insert()
   end
 
+  def auto_join_orgs(user) do
+    domain = user.email |> String.split("@") |> List.last()
+
+    orgs =
+      Repo.all(
+        from o in User,
+          left_join: m in Member,
+          on: m.org_id == o.id and m.user_id == ^user.id,
+          where: o.domain == ^domain and is_nil(m.id)
+      )
+
+    Enum.each(orgs, fn org ->
+      case Organizations.create_member(org, user, :mod) do
+        {:ok, _member} ->
+          Algora.Admin.alert("#{user.email} joined #{org.name}", :info)
+
+        {:error, _reason} ->
+          Algora.Admin.alert("#{user.email} failed to join #{org.name}", :error)
+      end
+    end)
+
+    if org = List.first(orgs) do
+      update_settings(user, %{last_context: org.handle})
+    end
+
+    orgs
+  end
+
+  def get_or_register_user(email) do
+    res =
+      case get_user_by_email(email) do
+        nil -> register_org(%{email: email})
+        user -> {:ok, user}
+      end
+
+    with {:ok, user} <- res do
+      auto_join_orgs(user)
+      res
+    end
+  end
+
   # def get_user_by_provider_email(provider, email) when provider in [:github] do
   #   query =
   #     from(u in User,

lib/algora_web/controllers/oauth_callback_controller.ex

@@ -61,7 +61,7 @@ defmodule AlgoraWeb.OAuthCallbackController do
 
   def new(conn, %{"provider" => "email", "email" => email, "token" => token} = params) do
     with {:ok, _login_token} <- AlgoraWeb.UserAuth.verify_login_code(token, email),
-         {:ok, user} <- get_or_register_user(email) do
+         {:ok, user} <- Accounts.get_or_register_user(email) do
       conn =
         if params["return_to"] do
           put_session(conn, :user_return_to, String.trim_leading(params["return_to"], AlgoraWeb.Endpoint.url()))
@@ -90,11 +90,4 @@ defmodule AlgoraWeb.OAuthCallbackController do
   def sign_out(conn, _) do
     AlgoraWeb.UserAuth.log_out_user(conn)
   end
-
-  defp get_or_register_user(email) do
-    case Accounts.get_user_by_email(email) do
-      nil -> Accounts.register_org(%{email: email})
-      user -> {:ok, user}
-    end
-  end
 end

lib/algora_web/live/org/dashboard_live.ex

@@ -783,10 +783,21 @@ defmodule AlgoraWeb.Org.DashboardLive do
               |> Ecto.Changeset.change(handle: handle, email: socket.assigns.email)
               |> Repo.update()
 
-            {:noreply,
-             socket
-             |> assign(:current_user, user)
-             |> assign_achievements()}
+            autojoined? =
+              user
+              |> Accounts.auto_join_orgs()
+              |> Enum.any?(&(&1.id == socket.assigns.previewed_user.id))
+
+            socket =
+              if autojoined? do
+                switch_from_preview(socket, user)
+              else
+                socket
+                |> assign(:current_user, user)
+                |> assign_achievements()
+              end
+
+            {:noreply, socket}
 
           user ->
             socket = switch_from_preview(socket, user)

test/algora/accounts_test.exs

@@ -5,6 +5,7 @@ defmodule Algora.AccountsTest do
   alias Algora.Accounts.Identity
   alias Algora.Accounts.User
   alias Algora.Organizations
+  alias Algora.Organizations.Member
   alias Algora.Repo
   alias Algora.Workspace.Repository
 
@@ -164,6 +165,29 @@ defmodule Algora.AccountsTest do
     end
   end
 
+  describe "get_or_register_user/1" do
+    test "auto-joins all orgs with matching domain" do
+      org1 = insert(:organization, domain: "example.com")
+      org2 = insert(:organization, domain: "example.com")
+
+      {:ok, user} = Accounts.get_or_register_user("[email protected]")
+
+      member1 = Repo.get_by(Member, user_id: user.id, org_id: org1.id)
+      member2 = Repo.get_by(Member, user_id: user.id, org_id: org2.id)
+
+      assert not is_nil(member1)
+      assert not is_nil(member2)
+    end
+
+    test "does not auto-join org with non-matching domain" do
+      org = insert(:organization, domain: "example.com")
+      {:ok, user} = Accounts.get_or_register_user("[email protected]")
+
+      member = Repo.get_by(Member, user_id: user.id, org_id: org.id)
+      assert is_nil(member)
+    end
+  end
+
   describe "accounts" do
     test "query" do
       user_1 = insert(:user)