feat: update RepoController to check and cache invalid repositories during repository retrieval

Author: zcesur

lib/algora/workspace/invalid_repo_cache.ex

@@ -0,0 +1,38 @@
+defmodule Algora.Workspace.InvalidRepoCache do
+  @moduledoc false
+  use Algora.Schema
+
+  import Ecto.Changeset
+  import Ecto.Query
+
+  alias Algora.Repo
+
+  typed_schema "invalid_repos" do
+    field :owner, :string
+    field :name, :string
+
+    timestamps()
+  end
+
+  def changeset(invalid_repo, attrs) do
+    invalid_repo
+    |> cast(attrs, [:owner, :name])
+    |> validate_required([:owner, :name])
+    |> unique_constraint([:owner, :name])
+  end
+
+  def cache_invalid_repo(owner, name) do
+    %__MODULE__{}
+    |> changeset(%{owner: owner, name: name})
+    |> generate_id()
+    |> Repo.insert()
+  end
+
+  def invalid_repo?(owner, name) do
+    query =
+      from r in __MODULE__,
+        where: r.owner == ^owner and r.name == ^name
+
+    Repo.exists?(query)
+  end
+end

lib/algora_web/controllers/repo_controller.ex

@@ -4,18 +4,24 @@ defmodule AlgoraWeb.RepoController do
   alias Algora.Accounts.User
   alias Algora.Repo
   alias Algora.Workspace
+  alias Algora.Workspace.InvalidRepoCache
 
   def index(conn, %{"repo_owner" => repo_owner, "repo_name" => repo_name}) do
     case Repo.get_by(User, provider: "github", provider_login: repo_owner) do
       %{handle: handle} when is_binary(handle) ->
         redirect(conn, to: ~p"/#{handle}")
 
       _ ->
+        if InvalidRepoCache.invalid_repo?(repo_owner, repo_name) do
+          raise AlgoraWeb.NotFoundError
+        end
+
         case Workspace.ensure_repository(Algora.Admin.token(), repo_owner, repo_name) do
           {:ok, _repo} ->
             redirect(conn, to: ~p"/go/#{repo_owner}/#{repo_name}")
 
           {:error, _reason} ->
+            InvalidRepoCache.cache_invalid_repo(repo_owner, repo_name)
             raise AlgoraWeb.NotFoundError
         end
     end

priv/repo/migrations/20250415150356_create_invalid_repos.exs

@@ -0,0 +1,14 @@
+defmodule Algora.Repo.Migrations.CreateInvalidRepos do
+  use Ecto.Migration
+
+  def change do
+    create table(:invalid_repos) do
+      add :owner, :string, null: false
+      add :name, :string, null: false
+
+      timestamps()
+    end
+
+    create unique_index(:invalid_repos, [:owner, :name])
+  end
+end