implement Algora.Analytics.get_company_analytics/0-2

lastcanal · lastcanal · commit d62bdc6b158c · 2025-01-12T21:23:11.000-05:00
diff --git a/lib/algora/analytics/analytics.ex b/lib/algora/analytics/analytics.ex
@@ -1,28 +1,126 @@
 defmodule Algora.Analytics do
   @moduledoc false
-  def get_company_analytics(period \\ "30d") do
+  import Ecto.Query
+
+  alias Algora.Accounts.User
+  alias Algora.Contracts.Contract
+  alias Algora.Repo
+
+  require Algora.SQL
+
+  def get_company_analytics(period \\ "30d", from \\ DateTime.utc_now()) do
     days = period |> String.replace("d", "") |> String.to_integer()
-    _since = DateTime.add(DateTime.utc_now(), -days * 24 * 3600)
+    period_start = DateTime.add(from, -days * 24 * 3600)
+    previous_period_start = DateTime.add(period_start, -days * 24 * 3600)
 
-    # Mock data for demonstration
-    %{
-      total_companies: 150,
-      companies_change: 12,
-      companies_trend: :up,
-      active_companies: 85,
-      active_change: 5,
-      active_trend: :up,
-      avg_time_to_fill: 4.2,
-      time_to_fill_change: -0.8,
-      time_to_fill_trend: :down,
-      contract_success_rate: 92,
-      success_rate_change: 2,
-      success_rate_trend: :up,
-      companies: mock_companies()
-    }
+    orgs_query =
+      from u in User,
+        where: u.type == :organization,
+        select: %{
+          count_all: count(u.id),
+          count_current: u.id |> count() |> filter(u.inserted_at <= ^from and u.inserted_at >= ^period_start),
+          count_previous:
+            u.id |> count() |> filter(u.inserted_at <= ^period_start and u.inserted_at >= ^previous_period_start),
+          active_all: u.id |> count() |> filter(u.seeded and u.activated),
+          active_current:
+            u.id
+            |> count()
+            |> filter(u.seeded and u.activated and u.inserted_at <= ^from and u.inserted_at >= ^period_start),
+          active_previous:
+            u.id
+            |> count()
+            |> filter(
+              u.seeded and u.activated and u.inserted_at <= ^period_start and u.inserted_at >= ^previous_period_start
+            )
+        }
+
+    contracts_query =
+      from u in Contract,
+        where: u.inserted_at >= ^previous_period_start,
+        select: %{
+          count_current: u.id |> count() |> filter(u.inserted_at < ^from and u.inserted_at >= ^period_start),
+          count_previous:
+            u.id |> count() |> filter(u.inserted_at < ^period_start and u.inserted_at >= ^previous_period_start),
+          success_current:
+            u.id
+            |> count()
+            |> filter(
+              u.inserted_at < ^from and u.inserted_at >= ^period_start and (u.status == :active or u.status == :paid)
+            ),
+          success_previous:
+            u.id
+            |> count()
+            |> filter(
+              u.inserted_at < ^period_start and u.inserted_at >= ^previous_period_start and
+                (u.status == :active or u.status == :paid)
+            )
+        }
+
+    companies_query =
+      from u in User,
+        where: u.inserted_at >= ^period_start and u.type == :organization,
+        right_join: c in Contract,
+        on: c.client_id == u.id,
+        group_by: u.id,
+        select: %{
+          id: u.id,
+          name: u.name,
+          handle: u.handle,
+          joined_at: u.inserted_at,
+          total_contracts: c.id |> count() |> filter(c.inserted_at >= ^period_start),
+          successful_contracts:
+            c.id |> count() |> filter(c.status == :active or (c.status == :paid and c.inserted_at >= ^period_start)),
+          last_active_at: u.updated_at,
+          avatar_url: u.avatar_url
+        }
+
+    Ecto.Multi.new()
+    |> Ecto.Multi.one(:orgs, orgs_query)
+    |> Ecto.Multi.one(:contracts, contracts_query)
+    |> Ecto.Multi.all(:companies, companies_query)
+    |> Repo.transaction()
+    |> case do
+      {:ok, resp} ->
+        %{
+          orgs: orgs,
+          contracts: contracts,
+          companies: companies
+        } = resp
+
+        current_success_rate = calculate_success_rate(contracts.success_current, contracts.count_current)
+        previous_success_rate = calculate_success_rate(contracts.success_previous, contracts.count_previous)
+
+        {:ok,
+         %{
+           total_companies: orgs.count_all,
+           companies_change: orgs.count_current,
+           companies_trend: calculate_trend(orgs.count_current, orgs.count_previous),
+           active_companies: orgs.active_all,
+           active_change: orgs.active_current,
+           active_trend: calculate_trend(orgs.active_current, orgs.active_previous),
+           # TODO track time when contract is filled
+           avg_time_to_fill: 4.2,
+           time_to_fill_change: -0.8,
+           time_to_fill_trend: :down,
+           contract_success_rate: current_success_rate,
+           previous_contract_success_rate: previous_success_rate,
+           success_rate_change: current_success_rate - previous_success_rate,
+           success_rate_trend: calculate_trend(current_success_rate, previous_success_rate),
+           companies:
+             Enum.map(companies, fn company ->
+               Map.merge(company, %{
+                 success_rate: calculate_success_rate(company.successful_contracts, company.total_contracts),
+                 status: if(company.successful_contracts > 0, do: :active, else: :inactive)
+               })
+             end)
+         }}
+
+      {:error, reason} ->
+        {:error, reason}
+    end
   end
 
-  def get_funnel_data(_period \\ "30d") do
+  def get_funnel_data(_period \\ "30d", _from \\ DateTime.utc_now()) do
     # Mock funnel data
     %{
       registered: 100,
@@ -34,19 +132,10 @@ defmodule Algora.Analytics do
     }
   end
 
-  defp mock_companies do
-    [
-      %{
-        name: "TechCorp",
-        handle: "techcorp",
-        avatar_url: "https://example.com/avatar1.jpg",
-        joined_at: ~U[2024-01-15 00:00:00Z],
-        status: :active,
-        total_contracts: 12,
-        success_rate: 95,
-        last_active_at: ~U[2024-03-18 14:30:00Z]
-      }
-      # Add more mock companies...
-    ]
-  end
+  defp calculate_success_rate(successful, total) when successful == 0 or total == 0, do: 0.0
+  defp calculate_success_rate(successful, total), do: Float.ceil(successful / total * 100, 0)
+
+  defp calculate_trend(a, b) when a > b, do: :up
+  defp calculate_trend(a, b) when a < b, do: :down
+  defp calculate_trend(a, b) when a == b, do: :same
 end
diff --git a/lib/algora_web/live/admin/company_analytics_live.ex b/lib/algora_web/live/admin/company_analytics_live.ex
@@ -5,7 +5,7 @@ defmodule AlgoraWeb.Admin.CompanyAnalyticsLive do
   alias Algora.Analytics
 
   def mount(_params, _session, socket) do
-    analytics = Analytics.get_company_analytics()
+    {:ok, analytics} = Analytics.get_company_analytics()
     funnel_data = Analytics.get_funnel_data()
 
     {:ok,
@@ -134,7 +134,7 @@ defmodule AlgoraWeb.Admin.CompanyAnalyticsLive do
   def status_color(_), do: "secondary"
 
   def handle_event("select_period", %{"period" => period}, socket) do
-    analytics = Analytics.get_company_analytics(period)
+    {:ok, analytics} = Analytics.get_company_analytics(period)
     funnel_data = Analytics.get_funnel_data(period)
 
     {:noreply,
diff --git a/test/algora/analytics_test.exs b/test/algora/analytics_test.exs
@@ -0,0 +1,97 @@
+defmodule Algora.AnalyticsTest do
+  use Algora.DataCase
+
+  import Algora.Factory
+
+  alias Algora.Analytics
+
+  setup do
+    now = DateTime.utc_now()
+    last_month = DateTime.add(now, -40 * 24 * 3600)
+
+    Enum.reduce(1..100, now, fn _n, date ->
+      insert(:organization, %{inserted_at: date, seeded: false, activated: false})
+      DateTime.add(date, -1 * 24 * 3600)
+    end)
+
+    Enum.reduce(1..100, now, fn _n, date ->
+      org = insert(:organization, %{inserted_at: date, seeded: true, activated: true})
+      insert_list(2, :contract, %{client_id: org.id, status: :active})
+      insert_list(1, :contract, %{client_id: org.id, status: :paid})
+      insert_list(3, :contract, %{client_id: org.id, status: :cancelled})
+      insert_list(1, :contract, %{inserted_at: last_month, client_id: org.id, status: :paid})
+      insert_list(3, :contract, %{inserted_at: last_month, client_id: org.id, status: :cancelled})
+      DateTime.add(date, -1 * 24 * 3600)
+    end)
+
+    :ok
+  end
+
+  describe "analytics" do
+    test "get_company_analytics 30d" do
+      {:ok, resp} = Analytics.get_company_analytics("30d")
+      assert resp.total_companies == 200
+      assert resp.active_companies == 100
+      assert resp.companies_change == 60
+      assert resp.active_change == 30
+      assert resp.companies_trend == :same
+      assert resp.active_trend == :same
+      assert resp.contract_success_rate == 50.0
+      assert resp.success_rate_change == 25.0
+      assert resp.success_rate_trend == :up
+
+      assert length(resp.companies) > 0
+
+      assert %{total_contracts: 6, successful_contracts: 3, success_rate: 50.0, last_active_at: last_active_at} =
+               List.first(resp.companies)
+
+      assert DateTime.before?(last_active_at, DateTime.utc_now())
+
+      now = DateTime.utc_now()
+      last_month = DateTime.add(now, -40 * 24 * 3600)
+      insert(:organization, %{inserted_at: last_month, seeded: true, activated: true})
+
+      {:ok, resp} = Analytics.get_company_analytics("30d")
+      assert resp.total_companies == 201
+      assert resp.active_companies == 101
+      assert resp.companies_change == 60
+      assert resp.active_change == 30
+      assert resp.companies_trend == :down
+      assert resp.active_trend == :down
+
+      insert(:organization, %{seeded: true, activated: true})
+      insert(:organization, %{seeded: true, activated: true})
+      insert(:organization, %{seeded: false, activated: false})
+
+      {:ok, resp} = Analytics.get_company_analytics("30d")
+
+      assert resp.total_companies == 204
+      assert resp.active_companies == 103
+      assert resp.companies_change == 63
+      assert resp.active_change == 32
+      assert resp.companies_trend == :up
+      assert resp.active_trend == :up
+    end
+
+    test "get_company_analytics 356d" do
+      {:ok, resp} = Analytics.get_company_analytics("365d")
+      assert resp.total_companies == 200
+      assert resp.active_companies == 100
+      assert resp.companies_change == 200
+      assert resp.active_change == 100
+      assert resp.companies_trend == :up
+      assert resp.active_trend == :up
+    end
+
+    test "get_company_analytics 7d" do
+      insert(:organization, %{seeded: true, activated: true})
+      {:ok, resp} = Analytics.get_company_analytics("7d")
+      assert resp.total_companies == 201
+      assert resp.active_companies == 101
+      assert resp.companies_change == 15
+      assert resp.active_change == 8
+      assert resp.companies_trend == :up
+      assert resp.active_trend == :up
+    end
+  end
+end
