Merge branch 'main' into activity-notifications

Author: lastcanal

config/config.exs

@@ -32,6 +32,7 @@ config :algora, Oban,
     comment_consumers: 1,
     github_og_image: 5,
     notify_bounty: 1,
+    notify_tip_intent: 1,
     activity_notifier: 1,
     activity_mailer: 1
   ]

lib/algora/bounties/bounties.ex

@@ -126,9 +126,47 @@ defmodule Algora.Bounties do
     |> Oban.insert()
   end
 
-  @spec create_tip(%{creator: User.t(), owner: User.t(), recipient: User.t(), amount: Money.t()}) ::
+  @spec create_tip_intent(
+          %{
+            recipient: String.t(),
+            amount: Money.t(),
+            ticket_ref: %{owner: String.t(), repo: String.t(), number: integer()}
+          },
+          opts :: [installation_id: integer()]
+        ) ::
+          {:ok, String.t()} | {:error, atom()}
+  def create_tip_intent(
+        %{recipient: recipient, amount: amount, ticket_ref: %{owner: owner, repo: repo, number: number}},
+        opts \\ []
+      ) do
+    query =
+      URI.encode_query(
+        amount: Money.to_decimal(amount),
+        recipient: recipient,
+        owner: owner,
+        repo: repo,
+        number: number
+      )
+
+    url = AlgoraWeb.Endpoint.url() <> "/tip" <> "?" <> query
+
+    %{
+      url: url,
+      ticket_ref: %{owner: owner, repo: repo, number: number},
+      installation_id: opts[:installation_id]
+    }
+    |> Jobs.NotifyTipIntent.new()
+    |> Oban.insert()
+  end
+
+  @spec create_tip(
+          %{creator: User.t(), owner: User.t(), recipient: User.t(), amount: Money.t()},
+          opts :: [ticket_ref: %{owner: String.t(), repo: String.t(), number: integer()}]
+        ) ::
           {:ok, String.t()} | {:error, atom()}
-  def create_tip(%{creator: creator, owner: owner, recipient: recipient, amount: amount}) do
+  def create_tip(%{creator: creator, owner: owner, recipient: recipient, amount: amount}, opts \\ []) do
+    ticket_ref = opts[:ticket_ref]
+
     changeset =
       Tip.changeset(%Tip{}, %{
         amount: amount,
@@ -162,7 +200,11 @@ defmodule Algora.Bounties do
           product_data: %{
             name: "Payment to @#{recipient.provider_login}",
             # TODO:
-            # description: nil,
+            description:
+              if(ticket_ref,
+                do: "#{ticket_ref[:owner]}/#{ticket_ref[:repo]}##{ticket_ref[:number]}",
+                else: "Tip to @#{recipient.provider_login}"
+              ),
             images: [recipient.avatar_url]
           }
         },

lib/algora/bounties/jobs/notify_tip_intent.ex

@@ -0,0 +1,47 @@
+defmodule Algora.Bounties.Jobs.NotifyTipIntent do
+  @moduledoc false
+  use Oban.Worker, queue: :notify_tip_intent
+
+  alias Algora.Github
+
+  require Logger
+
+  @impl Oban.Worker
+  def perform(%Oban.Job{args: %{"url" => url, "ticket_ref" => ticket_ref, "installation_id" => nil}}) do
+    body = get_body(url)
+
+    if Github.pat_enabled() do
+      Github.create_issue_comment(
+        Github.pat(),
+        ticket_ref["owner"],
+        ticket_ref["repo"],
+        ticket_ref["number"],
+        body
+      )
+    else
+      Logger.info("""
+      Github.create_issue_comment(Github.pat(), "#{ticket_ref["owner"]}", "#{ticket_ref["repo"]}", #{ticket_ref["number"]},
+             \"\"\"
+             #{body}
+             \"\"\")
+      """)
+    end
+  end
+
+  @impl Oban.Worker
+  def perform(%Oban.Job{args: %{"url" => url, "ticket_ref" => ticket_ref, "installation_id" => installation_id}}) do
+    with {:ok, token} <- Github.get_installation_token(installation_id) do
+      body = get_body(url)
+
+      Github.create_issue_comment(
+        token,
+        ticket_ref["owner"],
+        ticket_ref["repo"],
+        ticket_ref["number"],
+        body
+      )
+    end
+  end
+
+  defp get_body(url), do: "Please visit [Algora](#{url}) to complete your tip via Stripe."
+end

lib/algora/integrations/github/poller/comment_consumer.ex

@@ -4,7 +4,6 @@ defmodule Algora.Github.Poller.CommentConsumer do
 
   alias Algora.Accounts
   alias Algora.Bounties
-  alias Algora.Github
   alias Algora.Util
 
   require Logger
@@ -25,40 +24,23 @@ defmodule Algora.Github.Poller.CommentConsumer do
   end
 
   defp run_command({:tip, args}, ticket_ref, _comment) do
-    amount = Keyword.get(args, :amount)
-    recipient = Keyword.get(args, :recipient)
-    owner = Keyword.get(ticket_ref, :owner)
-    repo = Keyword.get(ticket_ref, :repo)
-    number = Keyword.get(ticket_ref, :number)
-
-    query = URI.encode_query(amount: Money.to_decimal(amount), recipient: recipient)
-    url = AlgoraWeb.Endpoint.url() <> "/tip" <> "?" <> query
-    body = "Please visit [Algora](#{url}) to complete your tip via Stripe."
-
-    if Github.pat_enabled() do
-      Github.create_issue_comment(Github.pat(), owner, repo, number, body)
-    else
-      Logger.info("""
-      Github.create_issue_comment(Github.pat(), "#{owner}", "#{repo}", #{number},
-             \"\"\"
-             #{body}
-             \"\"\")
-      """)
-
-      :ok
-    end
+    Bounties.create_tip_intent(%{
+      recipient: args[:recipient],
+      amount: args[:amount],
+      ticket_ref: %{owner: ticket_ref[:owner], repo: ticket_ref[:repo], number: ticket_ref[:number]}
+    })
   end
 
   defp run_command({:bounty, args}, ticket_ref, comment) do
-    with {:ok, user} <- Accounts.fetch_user_by(provider_id: to_string(comment["user"]["id"])),
-         {:ok, amount} <- Keyword.fetch(args, :amount) do
-      Bounties.create_bounty(%{
-        creator: user,
-        owner: user,
-        amount: amount,
-        ticket_ref: %{owner: ticket_ref[:owner], repo: ticket_ref[:repo], number: ticket_ref[:number]}
-      })
-    else
+    case Accounts.fetch_user_by(provider_id: to_string(comment["user"]["id"])) do
+      {:ok, user} ->
+        Bounties.create_bounty(%{
+          creator: user,
+          owner: user,
+          amount: args[:amount],
+          ticket_ref: %{owner: ticket_ref[:owner], repo: ticket_ref[:repo], number: ticket_ref[:number]}
+        })
+
       {:error, _reason} = error ->
         Logger.error("Failed to create bounty: #{inspect(error)}")
         error

lib/algora_web/controllers/tip_controller.ex

@@ -6,18 +6,23 @@ defmodule AlgoraWeb.TipController do
   alias Algora.Workspace
   alias AlgoraWeb.UserAuth
 
-  def create(conn, %{"amount" => amount, "recipient" => recipient} = _params) do
+  def create(conn, %{"amount" => amount, "recipient" => recipient} = params) do
+    ticket_ref = extract_ticket_ref(params)
+
     with {:ok, current_user} <- get_current_user(conn),
          %Money{} = amount <- Money.new(:USD, amount),
          {:ok, token} <- Accounts.get_access_token(current_user),
          {:ok, recipient_user} <- Workspace.ensure_user(token, recipient),
          {:ok, checkout_url} <-
-           Bounties.create_tip(%{
-             creator: current_user,
-             owner: current_user,
-             recipient: recipient_user,
-             amount: amount
-           }) do
+           Bounties.create_tip(
+             %{
+               creator: current_user,
+               owner: current_user,
+               recipient: recipient_user,
+               amount: amount
+             },
+             if(ticket_ref, do: [ticket_ref: ticket_ref], else: [])
+           ) do
       redirect(conn, external: checkout_url)
     else
       # TODO: just use a plug
@@ -40,6 +45,15 @@ defmodule AlgoraWeb.TipController do
     |> redirect(to: UserAuth.signed_in_path(conn))
   end
 
+  defp extract_ticket_ref(%{"owner" => owner, "repo" => repo, "number" => number}) do
+    case Integer.parse(number) do
+      {number, ""} -> [owner: owner, repo: repo, number: number]
+      _ -> nil
+    end
+  end
+
+  defp extract_ticket_ref(_), do: nil
+
   defp get_current_user(conn) do
     case conn.assigns.current_user do
       nil -> {:error, :unauthorized}

lib/algora_web/controllers/webhooks/github_controller.ex

@@ -57,6 +57,7 @@ defmodule AlgoraWeb.Webhooks.GithubController do
     issue = params["issue"]
     installation_id = params["installation"]["id"]
 
+    # TODO: community bounties?
     with {:ok, "admin"} <- get_permissions(author, params),
          {:ok, token} <- Github.get_installation_token(installation_id),
          {:ok, installation} <-
@@ -81,11 +82,35 @@ defmodule AlgoraWeb.Webhooks.GithubController do
     end
   end
 
-  defp execute_command({:tip, args}, _author, _params) when not is_nil(args) do
-    amount = Keyword.get(args, :amount)
-    recipient = Keyword.get(args, :username)
+  defp execute_command({:tip, args}, author, params) when not is_nil(args) do
+    amount = args[:amount]
+    recipient = args[:recipient]
+    repo = params["repository"]
+    issue = params["issue"]
+    installation_id = params["installation"]["id"]
+
+    # TODO: handle missing amount
+    # TODO: handle missing recipient
+    # TODO: handle tip to self
+    # TODO: handle autopay with cooldown
+    # TODO: community tips?
+    case get_permissions(author, params) do
+      {:ok, "admin"} ->
+        Bounties.create_tip_intent(
+          %{
+            recipient: recipient,
+            amount: amount,
+            ticket_ref: %{owner: repo["owner"]["login"], repo: repo["name"], number: issue["number"]}
+          },
+          installation_id: installation_id
+        )
 
-    Logger.info("Tip #{amount} to #{recipient}")
+      {:ok, _permission} ->
+        {:error, :unauthorized}
+
+      {:error, _reason} = error ->
+        error
+    end
   end
 
   defp execute_command({:claim, args}, _author, _params) when not is_nil(args) do