add follow relationships

Author: zcesur

lib/algora/accounts/schemas/follow.ex

@@ -0,0 +1,38 @@
+defmodule Algora.Accounts.Follow do
+  @moduledoc false
+  use Algora.Schema
+
+  alias Algora.Accounts.User
+
+  typed_schema "follows" do
+    belongs_to :follower, User, foreign_key: :follower_id, type: :string
+    belongs_to :followed, User, foreign_key: :followed_id, type: :string
+
+    field :provider, :string, default: "github"
+    field :provider_created_at, :utc_datetime_usec
+
+    timestamps()
+  end
+
+  def changeset(follow, attrs) do
+    follow
+    |> cast(attrs, [:follower_id, :followed_id, :provider, :provider_created_at])
+    |> validate_required([:follower_id, :followed_id, :provider])
+    |> generate_id()
+    |> unique_constraint([:follower_id, :followed_id], name: :follows_follower_id_followed_id_index)
+    |> foreign_key_constraint(:follower_id)
+    |> foreign_key_constraint(:followed_id)
+    |> validate_not_self_follow()
+  end
+
+  defp validate_not_self_follow(changeset) do
+    follower_id = get_field(changeset, :follower_id)
+    followed_id = get_field(changeset, :followed_id)
+
+    if follower_id && followed_id && follower_id == followed_id do
+      add_error(changeset, :followed_id, "cannot follow yourself")
+    else
+      changeset
+    end
+  end
+end

lib/algora/accounts/schemas/user.ex

@@ -2,6 +2,7 @@ defmodule Algora.Accounts.User do
   @moduledoc false
   use Algora.Schema
 
+  alias Algora.Accounts.Follow
   alias Algora.Accounts.Identity
   alias Algora.Accounts.User
   alias Algora.Accounts.UserMedia
@@ -37,6 +38,8 @@ defmodule Algora.Accounts.User do
     field :country, :string
     field :timezone, :string
     field :stargazers_count, :integer, default: 0
+    field :followers_count, :integer, default: 0
+    field :following_count, :integer, default: 0
     field :domain, :string
     field :tech_stack, {:array, :string}, default: []
     field :discovery_tech_stack, {:array, :string}, default: []
@@ -170,6 +173,11 @@ defmodule Algora.Accounts.User do
     has_many :media, UserMedia
     has_many :job_matches, Algora.Matches.JobMatch, foreign_key: :user_id
 
+    has_many :following_relationships, Follow, foreign_key: :follower_id
+    has_many :following, through: [:following_relationships, :followed]
+    has_many :follower_relationships, Follow, foreign_key: :followed_id
+    has_many :followers, through: [:follower_relationships, :follower]
+
     timestamps()
   end
 

lib/algora/integrations/github/behaviour.ex

@@ -38,4 +38,6 @@ defmodule Algora.Github.Behaviour do
   @callback remove_label(token(), String.t(), String.t(), String.t()) :: {:ok, map()} | {:error, String.t()}
   @callback remove_label_from_issue(token(), String.t(), String.t(), integer(), String.t()) ::
               {:ok, map()} | {:error, String.t()}
+  @callback list_user_followers(token(), String.t(), keyword()) :: {:ok, [map()]} | {:error, String.t()}
+  @callback list_user_following(token(), String.t(), keyword()) :: {:ok, [map()]} | {:error, String.t()}
 end

lib/algora/integrations/github/client.ex

@@ -329,4 +329,14 @@ defmodule Algora.Github.Client do
         res
     end
   end
+
+  @impl true
+  def list_user_followers(access_token, username, opts \\ []) do
+    fetch(access_token, "/users/#{username}/followers#{build_query(opts)}")
+  end
+
+  @impl true
+  def list_user_following(access_token, username, opts \\ []) do
+    fetch(access_token, "/users/#{username}/following#{build_query(opts)}")
+  end
 end

lib/algora/integrations/github/github.ex

@@ -164,4 +164,10 @@ defmodule Algora.Github do
   @impl true
   def remove_label_from_issue(token, owner, repo, number, label),
     do: client().remove_label_from_issue(token, owner, repo, number, label)
+
+  @impl true
+  def list_user_followers(token, username, opts \\ []), do: client().list_user_followers(token, username, opts)
+
+  @impl true
+  def list_user_following(token, username, opts \\ []), do: client().list_user_following(token, username, opts)
 end

priv/repo/migrations/20250818113456_create_follows.exs

@@ -0,0 +1,19 @@
+defmodule Algora.Repo.Migrations.CreateFollows do
+  use Ecto.Migration
+
+  def change do
+    create table(:follows, primary_key: false) do
+      add :id, :string, primary_key: true
+      add :follower_id, references(:users, on_delete: :delete_all, type: :string), null: false
+      add :followed_id, references(:users, on_delete: :delete_all, type: :string), null: false
+      add :provider, :string, null: false, default: "github"
+      add :provider_created_at, :utc_datetime_usec
+
+      timestamps()
+    end
+
+    create unique_index(:follows, [:follower_id, :followed_id])
+    create index(:follows, [:follower_id])
+    create index(:follows, [:followed_id])
+  end
+end

priv/repo/migrations/20250818143308_add_followers_following_to_users.exs

@@ -0,0 +1,10 @@
+defmodule Algora.Repo.Migrations.AddFollowersFollowingToUsers do
+  use Ecto.Migration
+
+  def change do
+    alter table(:users) do
+      add :followers_count, :integer, default: 0
+      add :following_count, :integer, default: 0
+    end
+  end
+end