PascalType.Tables.OpenType.HVAR.pas

unit PascalType.Tables.OpenType.HVAR;

////////////////////////////////////////////////////////////////////////////////
//                                                                            //
//  Version: MPL 1.1 or LGPL 2.1 with linking exception                       //
//                                                                            //
//  The contents of this file are subject to the Mozilla Public License       //
//  Version 1.1 (the "License"); you may not use this file except in          //
//  compliance with the License. You may obtain a copy of the License at      //
//  http://www.mozilla.org/MPL/                                               //
//                                                                            //
//  Software distributed under the License is distributed on an "AS IS"       //
//  basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See the   //
//  License for the specific language governing rights and limitations under  //
//  the License.                                                              //
//                                                                            //
//  Alternatively, the contents of this file may be used under the terms of   //
//  the Free Pascal modified version of the GNU Lesser General Public         //
//  License Version 2.1 (the "FPC modified LGPL License"), in which case the  //
//  provisions of this license are applicable instead of those above.         //
//  Please see the file LICENSE.txt for additional information concerning     //
//  this license.                                                             //
//                                                                            //
//  The code is part of the PascalType Project                                //
//                                                                            //
//  The initial developer of this code is Anders Melander                     //
//                                                                            //
//  Portions created by Anders Melander are Copyright (C) 2025-2026           //
//  by Anders Melander. All Rights Reserved.                                  //
//                                                                            //
////////////////////////////////////////////////////////////////////////////////

interface

{$I PT_Compiler.inc}

uses
  Classes,
  SysUtils,
  Generics.Collections,
  PascalType.Types,
  PascalType.Classes,
  PascalType.Tables,
  PascalType.Tables.OpenType.Common.Variation;

type
  TPascalTypeHorizontalMetricsVariationTable = class(TCustomPascalTypeNamedTable)
  private
    FMajorVersion: Word;
    FMinorVersion: Word;
    FItemVariationStore: TItemVariationStore;
    FAdvanceWidthMap: TDeltaSetIndexMap;
    FLSBMap: TDeltaSetIndexMap;
    FRSBMap: TDeltaSetIndexMap;
  public
    constructor Create(AParent: TCustomPascalTypeTable); override;
    destructor Destroy; override;

    class function GetTableType: TTableType; override;

    procedure LoadFromStream(Stream: TStream; Size: Cardinal = 0); override;
    procedure SaveToStream(Stream: TStream); override;

    function GetAdvanceWidthDelta(GlyphIndex: Word; const NormalizedCoords: TArray<TFixedPoint>): Single;
    function GetLSBDelta(GlyphIndex: Word; const NormalizedCoords: TArray<TFixedPoint>): Single;
    function GetRSBDelta(GlyphIndex: Word; const NormalizedCoords: TArray<TFixedPoint>): Single;

    property ItemVariationStore: TItemVariationStore read FItemVariationStore;
  end;

implementation

uses
  PascalType.ResourceStrings;

{ TPascalTypeHorizontalMetricsVariationTable }

constructor TPascalTypeHorizontalMetricsVariationTable.Create(AParent: TCustomPascalTypeTable);
begin
  inherited;
  FItemVariationStore := TItemVariationStore.Create(Self);
end;

destructor TPascalTypeHorizontalMetricsVariationTable.Destroy;
begin
  FItemVariationStore.Free;
  FAdvanceWidthMap.Free;
  FLSBMap.Free;
  FRSBMap.Free;
  inherited;
end;

class function TPascalTypeHorizontalMetricsVariationTable.GetTableType: TTableType;
begin
  Result.AsAnsiChar := 'HVAR';
end;

procedure TPascalTypeHorizontalMetricsVariationTable.LoadFromStream(Stream: TStream; Size: Cardinal);
begin
  var StartPos := Stream.Position;

  FMajorVersion := BigEndianValue.ReadWord(Stream);
  FMinorVersion := BigEndianValue.ReadWord(Stream);
  var ItemVariationStoreOffset := BigEndianValue.ReadCardinal(Stream);
  var AdvanceWidthMapOffset := BigEndianValue.ReadCardinal(Stream);
  var LSBMapOffset := BigEndianValue.ReadCardinal(Stream);
  var RSBMapOffset := BigEndianValue.ReadCardinal(Stream);

  if ItemVariationStoreOffset <> 0 then
  begin
    Stream.Position := StartPos + ItemVariationStoreOffset;
    FItemVariationStore.LoadFromStream(Stream);
  end;

  if AdvanceWidthMapOffset <> 0 then
  begin
    Stream.Position := StartPos + AdvanceWidthMapOffset;
    FAdvanceWidthMap := TDeltaSetIndexMap.Create(Self);
    FAdvanceWidthMap.LoadFromStream(Stream, Size - AdvanceWidthMapOffset); // Not the actual size, but better than no size
  end;

  if LSBMapOffset <> 0 then
  begin
    Stream.Position := StartPos + LSBMapOffset;
    FLSBMap := TDeltaSetIndexMap.Create(Self);
    FLSBMap.LoadFromStream(Stream, Size - LSBMapOffset);
  end;

  if RSBMapOffset <> 0 then
  begin
    Stream.Position := StartPos + RSBMapOffset;
    FRSBMap := TDeltaSetIndexMap.Create(Self);
    FRSBMap.LoadFromStream(Stream, Size - RSBMapOffset);
  end;
end;

procedure TPascalTypeHorizontalMetricsVariationTable.SaveToStream(Stream: TStream);
begin
  raise EPascalTypeNotImplemented.Create(RCStrNotImplemented);
end;

function TPascalTypeHorizontalMetricsVariationTable.GetAdvanceWidthDelta(GlyphIndex: Word; const NormalizedCoords: TArray<TFixedPoint>): Single;
begin
  Result := 0;
  if (FAdvanceWidthMap <> nil) then
  begin
    var Outer, Inner: Word;
    if FAdvanceWidthMap.GetIndex(GlyphIndex, Outer, Inner) then
      Result := FItemVariationStore.GetDelta(Outer, Inner, NormalizedCoords);
  end else
    Result := FItemVariationStore.GetDelta(0, GlyphIndex, NormalizedCoords);
end;

function TPascalTypeHorizontalMetricsVariationTable.GetLSBDelta(GlyphIndex: Word; const NormalizedCoords: TArray<TFixedPoint>): Single;
begin
  Result := 0;
  if (FLSBMap <> nil) then
  begin
    var Outer, Inner: Word;
    if FLSBMap.GetIndex(GlyphIndex, Outer, Inner) then
      Result := FItemVariationStore.GetDelta(Outer, Inner, NormalizedCoords);
  end;
end;

function TPascalTypeHorizontalMetricsVariationTable.GetRSBDelta(GlyphIndex: Word; const NormalizedCoords: TArray<TFixedPoint>): Single;
begin
  Result := 0;
  if (FRSBMap <> nil) then
  begin
    var Outer, Inner: Word;
    if FRSBMap.GetIndex(GlyphIndex, Outer, Inner) then
      Result := FItemVariationStore.GetDelta(Outer, Inner, NormalizedCoords);
  end;
end;

initialization

  PascalTypeTableClasses.RegisterTables([TPascalTypeHorizontalMetricsVariationTable]);

end.