PascalType.Tables.OpenType.MVAR.pas

unit PascalType.Tables.OpenType.MVAR;

////////////////////////////////////////////////////////////////////////////////
//                                                                            //
//  Version: MPL 1.1 or LGPL 2.1 with linking exception                       //
//                                                                            //
//  The contents of this file are subject to the Mozilla Public License       //
//  Version 1.1 (the "License"); you may not use this file except in          //
//  compliance with the License. You may obtain a copy of the License at      //
//  http://www.mozilla.org/MPL/                                               //
//                                                                            //
//  Software distributed under the License is distributed on an "AS IS"       //
//  basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See the   //
//  License for the specific language governing rights and limitations under  //
//  the License.                                                              //
//                                                                            //
//  Alternatively, the contents of this file may be used under the terms of   //
//  the Free Pascal modified version of the GNU Lesser General Public         //
//  License Version 2.1 (the "FPC modified LGPL License"), in which case the  //
//  provisions of this license are applicable instead of those above.         //
//  Please see the file LICENSE.txt for additional information concerning     //
//  this license.                                                             //
//                                                                            //
//  The code is part of the PascalType Project                                //
//                                                                            //
//  The initial developer of this code is Anders Melander                     //
//                                                                            //
//  Portions created by Anders Melander are Copyright (C) 2025-2026           //
//  by Anders Melander. All Rights Reserved.                                  //
//                                                                            //
////////////////////////////////////////////////////////////////////////////////

interface

{$I PT_Compiler.inc}

uses
  Classes,
  SysUtils,
  Generics.Collections,
  Generics.Defaults,
  PascalType.Types,
  PascalType.Classes,
  PascalType.Tables,
  PascalType.Tables.OpenType.Common.Variation;

type
  TValueRecord = record
    ValueTag: TTableType;
    DeltaSetOuterIndex: Word;
    DeltaSetInnerIndex: Word;
  end;

  TPascalTypeMetricsVariationTable = class(TCustomPascalTypeNamedTable)
  private class var
    FValueRecordComparer: IComparer<TValueRecord>;

  private
    class destructor Destroy;

  private
    FMajorVersion: Word;
    FMinorVersion: Word;
    FReserved: Word;
    FValueRecordSize: Word;
    FValueRecords: TArray<TValueRecord>;
    FItemVariationStore: TItemVariationStore;

  public
    constructor Create(AParent: TCustomPascalTypeTable); override;
    destructor Destroy; override;

    class function GetTableType: TTableType; override;

    procedure LoadFromStream(Stream: TStream; Size: Cardinal = 0); override;
    procedure SaveToStream(Stream: TStream); override;

    function GetMetricDelta(Tag: TTableType; const NormalizedCoords: TArray<TFixedPoint>): Single;

    property ItemVariationStore: TItemVariationStore read FItemVariationStore;
  end;

implementation

uses
  PascalType.ResourceStrings;

{ TPascalTypeMetricsVariationTable }

constructor TPascalTypeMetricsVariationTable.Create(AParent: TCustomPascalTypeTable);
begin
  inherited;
  FItemVariationStore := TItemVariationStore.Create(Self);
end;

destructor TPascalTypeMetricsVariationTable.Destroy;
begin
  FItemVariationStore.Free;
  inherited;
end;

class destructor TPascalTypeMetricsVariationTable.Destroy;
begin
  FValueRecordComparer := nil;
end;

class function TPascalTypeMetricsVariationTable.GetTableType: TTableType;
begin
  Result.AsAnsiChar := 'MVAR';
end;

procedure TPascalTypeMetricsVariationTable.LoadFromStream(Stream: TStream; Size: Cardinal);
begin
  var StartPos := Stream.Position;

  FMajorVersion := BigEndianValue.ReadWord(Stream);
  FMinorVersion := BigEndianValue.ReadWord(Stream);
  FReserved := BigEndianValue.ReadWord(Stream);
  FValueRecordSize := BigEndianValue.ReadWord(Stream);
  var ValueRecordCount := BigEndianValue.ReadWord(Stream);
  var ItemVariationStoreOffset := BigEndianValue.ReadWord(Stream);

  SetLength(FValueRecords, ValueRecordCount);
  for var i := 0 to ValueRecordCount - 1 do
  begin
    Stream.Read(FValueRecords[i].ValueTag, 4);
    FValueRecords[i].DeltaSetOuterIndex := BigEndianValue.ReadWord(Stream);
    FValueRecords[i].DeltaSetInnerIndex := BigEndianValue.ReadWord(Stream);
    if FValueRecordSize > 8 then
      Stream.Seek(FValueRecordSize - 8, soFromCurrent);
  end;

  if ItemVariationStoreOffset <> 0 then
  begin
    Stream.Position := StartPos + ItemVariationStoreOffset;
    FItemVariationStore.LoadFromStream(Stream);
  end;
end;

procedure TPascalTypeMetricsVariationTable.SaveToStream(Stream: TStream);
begin
  raise EPascalTypeNotImplemented.Create(RCStrNotImplemented);
end;

function TPascalTypeMetricsVariationTable.GetMetricDelta(Tag: TTableType; const NormalizedCoords: TArray<TFixedPoint>): Single;
begin
  var Index: integer;
  var ValueRecord: TValueRecord;
  ValueRecord.ValueTag := Tag;

  if (FValueRecordComparer = nil) then
    FValueRecordComparer := TComparer<TValueRecord>.Construct(
      function(const A, B: TValueRecord): integer
      begin
        Result := BinaryCompare(@A.ValueTag, @B.ValueTag, SizeOf(TTableType));
      end);

  if (TArray.BinarySearch<TValueRecord>(FValueRecords, ValueRecord, Index, FValueRecordComparer)) then
    Result := FItemVariationStore.GetDelta(FValueRecords[Index].DeltaSetOuterIndex, FValueRecords[Index].DeltaSetInnerIndex, NormalizedCoords)
  else
    Result := 0;
end;

initialization

  PascalTypeTableClasses.RegisterTables([TPascalTypeMetricsVariationTable]);

end.