Fix maven apk source collection.

Use an aspect to ensure collected source is only from axt.

PiperOrigin-RevId: 542923868

Author: brettchabot

.github/workflows/ci.yml

@@ -9,7 +9,7 @@ on:
 jobs:
   build:
     runs-on: ubuntu-latest
-    timeout-minutes: 15
+    timeout-minutes: 20
     steps:
       - name: Check out repository code
         uses: actions/checkout@v3

build_extensions/maven/axt_maven_apk.bzl

@@ -1,29 +1,20 @@
 """Generate AXT android archive (aar)."""
 
 load("//build_extensions/maven:combine_jars.bzl", "combine_jars")
-load("//build_extensions/maven:maven_info.bzl", "MavenFilesInfo", "MavenInfo")
+load("//build_extensions/maven:maven_info.bzl", "MavenFilesInfo", "MavenInfo", "collect_maven_apk_info")
 
 def _axt_maven_apk_impl(ctx):
     # produce src jar
-    # hack - exclude source jars from external maven artifacts
-    # TODO(b/283992063): use an aspect to gather this info
-    axt_jars = [jar for jar in ctx.attr.included_dep[JavaInfo].transitive_source_jars.to_list() if "maven.org" not in jar.path]
     combine_jars(
         ctx = ctx,
-        input_jars_deps = axt_jars,
+        input_jars_deps = ctx.attr.included_dep[MavenInfo].transitive_included_src_jars,
         output = ctx.outputs.src_jar,
     )
 
-    maven_info = MavenInfo(
-        artifact = ctx.attr.artifact,
-        is_compileOnly = False,
-        is_shaded = False,
-        transitive_included_runtime_jars = depset(),
-        transitive_included_src_jars = depset(),
-        transitive_maven_direct_deps = depset(ctx.attr.maven_deps),
-    )
-
-    return [maven_info, MavenFilesInfo(runtime = ctx.attr.included_dep[ApkInfo].signed_apk, src_jar = ctx.outputs.src_jar, validation = None)]
+    return [
+        ctx.attr.included_dep[MavenInfo],
+        MavenFilesInfo(runtime = ctx.attr.included_dep[ApkInfo].signed_apk, src_jar = ctx.outputs.src_jar, validation = None),
+    ]
 
 axt_maven_apk = rule(
     implementation = _axt_maven_apk_impl,
@@ -32,13 +23,7 @@ axt_maven_apk = rule(
             doc = "The android_binary to publish",
             mandatory = True,
             providers = [JavaInfo, ApkInfo],
-        ),
-        "artifact": attr.string(
-            doc = "the maven coordinates of the apk",
-            mandatory = True,
-        ),
-        "maven_deps": attr.string_list(
-            doc = "the maven coordinates of the runtime dependencies of the apk",
+            aspects = [collect_maven_apk_info],
         ),
         "_combine_jars_java": attr.label(
             executable = True,

build_extensions/maven/maven_info.bzl

@@ -17,7 +17,7 @@
 
 load("//build_extensions/maven:kotlin_info.bzl", "is_kotlin")
 load("//build_extensions:axt_versions.bzl", "KOTLIN_VERSION")
-load("//build_extensions/maven:maven_registry.bzl", "get_artifact_from_label", "is_shaded_from_label")
+load("//build_extensions/maven:maven_registry.bzl", "get_artifact_from_label", "get_maven_apk_deps", "is_axt_label", "is_shaded_from_label")
 
 # logic here largely inspired from https://github.com/google/dagger/blob/master/tools/maven_info.bzl
 
@@ -163,3 +163,47 @@ collect_maven_info = aspect(
     """,
     implementation = _collect_maven_info_impl,
 )
+
+def _collect_maven_apk_info_impl(target, ctx):
+    neverlink = getattr(ctx.rule.attr, "neverlink", False)
+    deps = getattr(ctx.rule.attr, "deps", [])
+    exports = getattr(ctx.rule.attr, "exports", [])
+
+    # ignore non-runtime or non-java dependencies eg proto_library or non-axt-labels
+    if neverlink or JavaInfo not in target or not is_axt_label(target.label):
+        return MavenInfo(
+            artifact = None,
+            is_compileOnly = True,
+            is_shaded = False,
+            transitive_included_runtime_jars = depset(),
+            transitive_included_src_jars = depset(),
+            transitive_maven_direct_deps = depset(),
+        )
+
+    artifact = get_artifact_from_label(target.label)
+    included_src_jars = target[JavaInfo].source_jars
+    transitive_included_src_jars = []
+
+    for dep in (deps + exports):
+        transitive_included_src_jars.append(dep[MavenInfo].transitive_included_src_jars)
+
+    maven_deps = get_maven_apk_deps(artifact)
+    return [MavenInfo(
+        artifact = artifact,
+        is_compileOnly = False,
+        is_shaded = False,
+        transitive_included_runtime_jars = depset(),
+        transitive_included_src_jars = depset(included_src_jars, transitive = transitive_included_src_jars),
+        transitive_maven_direct_deps = depset(maven_deps),
+    )]
+
+collect_maven_apk_info = aspect(
+    attr_aspects = [
+        "deps",
+        "exports",
+    ],
+    doc = """
+    Collects the Maven apk information for targets, their dependencies, and their transitive exports.
+    """,
+    implementation = _collect_maven_apk_info_impl,
+)

build_extensions/maven/maven_registry.bzl

@@ -45,6 +45,8 @@ _TARGET_TO_MAVEN_ARTIFACT = {
 
     # services/events/java gets built into both androidx.test.runner as well as orchestrator v2
     "//services/events/java/": "androidx.test:runner:%s" % RUNNER_VERSION,
+    "//services:test_services": "androidx.test.services:test-services:%s" % SERVICES_VERSION,
+    "//runner/android_test_orchestrator/stubapp:stubapp": "androidx.test:orchestrator:%s" % ORCHESTRATOR_VERSION,
 }
 
 _SHADED_TARGETS = [
@@ -74,6 +76,34 @@ def get_artifact_from_label(label):
 
     return result
 
+def is_axt_label(label):
+    """Determine if given target label is from androidx_test.
+
+    Args:
+      label: the target label
+
+    Returns:
+      True if the label is in a recognized androidx_test maven artifact
+    """
+    label_string = str(label)
+    for path in _TARGET_TO_MAVEN_ARTIFACT.keys():
+        if path in label_string:
+            return True
+
+    # special case the apk source dirs
+    if "//services" in label_string:
+        return True
+    if "//runner/android_test_orchestrator" in label_string:
+        return True
+    return False
+
+def get_maven_apk_deps(artifact):
+    # TODO: don't hardcode this, instead try to obtain from build rule
+    if artifact == ORCHESTRATOR_ARTIFACT:
+        return [SERVICES_APK_ARTIFACT]
+    else:
+        return []
+
 def is_shaded_from_label(label):
     """Returns true if given target should be shaded.
 

runner/android_test_orchestrator/stubapp/BUILD

@@ -1,7 +1,6 @@
 load("@build_bazel_rules_android//android:rules.bzl", "android_binary")
 load("//build_extensions/maven:maven_artifact.bzl", "maven_artifact")
 load("//build_extensions/maven:axt_maven_apk.bzl", "axt_maven_apk")
-load("//build_extensions:axt_versions.bzl", "ORCHESTRATOR_ARTIFACT", "SERVICES_APK_ARTIFACT")
 
 licenses(["notice"])
 
@@ -33,11 +32,7 @@ android_binary(
 
 axt_maven_apk(
     name = "orchestrator_release_apk",
-    artifact = ORCHESTRATOR_ARTIFACT,
     included_dep = ":stubapp",
-    maven_deps = [
-        SERVICES_APK_ARTIFACT,
-    ],
 )
 
 maven_artifact(

services/BUILD

@@ -1,7 +1,6 @@
 load("@rules_license//rules:license.bzl", "license")
 load("@build_bazel_rules_android//android:rules.bzl", "android_binary")
 load("//build_extensions/maven:maven_artifact.bzl", "maven_artifact")
-load("//build_extensions:axt_versions.bzl", "SERVICES_APK_ARTIFACT")
 load("//build_extensions/maven:axt_maven_apk.bzl", "axt_maven_apk")
 
 # Description:
@@ -45,7 +44,6 @@ android_binary(
 
 axt_maven_apk(
     name = "test_services_release_apk",
-    artifact = SERVICES_APK_ARTIFACT,
     included_dep = ":test_services",
 )