Issue #10034. Show warning if feature doesn't exist (#10053)

* Show warning when creating an application with a specified feature that doesn't exist

* cleanup

Author: jameskleeh

grails-shell/src/main/groovy/org/grails/cli/profile/commands/CreateAppCommand.groovy

@@ -314,10 +314,22 @@ class CreateAppCommand extends ArgumentCompletingCommand implements ProfileRepos
     }
 
     protected Iterable<Feature> evaluateFeatures(Profile profile, CommandLine commandLine) {
-        def requestedFeatures = commandLine.optionValue("features")?.toString()?.split(',')
+        String[] requestedFeatures = commandLine.optionValue("features")?.toString()?.split(',')
         if(requestedFeatures) {
-            def featureNames = Arrays.asList(requestedFeatures)
-            return (profile.features.findAll() { Feature f -> featureNames.contains(f.name)} + profile.requiredFeatures).unique()
+            List<String> requestedFeaturesList = requestedFeatures.toList()
+            List<String> allFeatureNames = profile.features*.name
+            List<String> validFeatureNames = requestedFeaturesList.intersect(allFeatureNames)
+            requestedFeaturesList.removeAll(allFeatureNames)
+            requestedFeaturesList.each { String invalidFeature ->
+                List possibleSolutions = allFeatureNames.findAll { it.substring(0, 2) == invalidFeature.substring(0, 2) }
+                StringBuilder warning = new StringBuilder("Feature ${invalidFeature} does not exist in the profile ${profile.name}!")
+                if (possibleSolutions) {
+                    warning.append(" Possible solutions: ")
+                    warning.append(possibleSolutions.join(", "))
+                }
+                GrailsConsole.getInstance().warn(warning.toString())
+            }
+            return (profile.features.findAll() { Feature f -> validFeatureNames.contains(f.name) } + profile.requiredFeatures).unique()
         }
         else {
             return (profile.defaultFeatures + profile.requiredFeatures).unique()

grails-shell/src/test/groovy/org/grails/cli/profile/commands/CreateAppCommandSpec.groovy

@@ -0,0 +1,110 @@
+package org.grails.cli.profile.commands
+
+import grails.build.logging.GrailsConsole
+import org.grails.build.parsing.CommandLine
+import org.grails.build.parsing.DefaultCommandLine
+import org.grails.cli.profile.Feature
+import org.grails.cli.profile.Profile
+import org.spockframework.util.StringMessagePrintStream
+import spock.lang.Shared
+import spock.lang.Specification
+
+/**
+ * Created by Jim on 7/18/2016.
+ */
+class CreateAppCommandSpec extends Specification {
+
+    @Shared
+    StringPrintStream sps
+
+    PrintStream originalOut
+
+    void setup() {
+        originalOut = GrailsConsole.instance.out
+        sps = new StringPrintStream()
+        GrailsConsole.instance.out = sps
+    }
+
+    void cleanup() {
+        GrailsConsole.instance.out = originalOut
+    }
+
+    void "test evaluateFeatures - multiple, some valid"() {
+        given:
+        Feature bar = Mock(Feature) {
+            2 * getName() >> "bar"
+        }
+        Profile profile = Mock(Profile) {
+            1 * getName() >> "web"
+            2 * getFeatures() >> [bar]
+            1 * getRequiredFeatures() >> []
+        }
+        CommandLine commandLine = new DefaultCommandLine().parseNew(["create-app", "foo", "-features=foo,bar"] as String[])
+
+        when:
+        Iterable<Feature> features = new CreateAppCommand().evaluateFeatures(profile, commandLine)
+
+        then:
+        features.size() == 1
+        features[0] == bar
+        sps.toString() == "Warning |\nFeature foo does not exist in the profile web!\n"
+    }
+
+    void "test evaluateFeatures - multiple, all valid"() {
+        given:
+        Feature foo = Mock(Feature) {
+            2 * getName() >> "foo"
+        }
+        Feature bar = Mock(Feature) {
+            2 * getName() >> "bar"
+        }
+        Profile profile = Mock(Profile) {
+            0 * getName()
+            2 * getFeatures() >> [foo, bar]
+            1 * getRequiredFeatures() >> []
+        }
+        CommandLine commandLine = new DefaultCommandLine().parseNew(["create-app", "foo", "-features=foo,bar"] as String[])
+
+        when:
+        Iterable<Feature> features = new CreateAppCommand().evaluateFeatures(profile, commandLine)
+
+        then:
+        features.size() == 2
+        features[0] == foo
+        features[1] == bar
+        sps.toString() == ""
+    }
+
+    void "test evaluateFeatures fat finger"() {
+        given:
+        Feature bar = Mock(Feature) {
+            2 * getName() >> "mongodb"
+        }
+        Profile profile = Mock(Profile) {
+            1 * getName() >> "web"
+            2 * getFeatures() >> [bar]
+            1 * getRequiredFeatures() >> []
+        }
+        CommandLine commandLine = new DefaultCommandLine().parseNew(["create-app", "foo", "-features=mongo"] as String[])
+
+        when:
+        Iterable<Feature> features = new CreateAppCommand().evaluateFeatures(profile, commandLine)
+
+
+        then:
+        features.size() == 0
+        sps.toString() == "Warning |\nFeature mongo does not exist in the profile web! Possible solutions: mongodb\n"
+    }
+
+    class StringPrintStream extends StringMessagePrintStream {
+        StringBuilder stringBuilder = new StringBuilder()
+        @Override
+        protected void printed(String message) {
+            stringBuilder.append(message)
+        }
+
+        String toString() {
+            stringBuilder.toString()
+        }
+    }
+}