GRAILS-6250 created HibernateTransactionManager subclass to set the session's flush mode to manual for read-only transactions

Author: burtbeckwith

src/java/org/codehaus/groovy/grails/orm/hibernate/GrailsHibernateTransactionManager.groovy

@@ -0,0 +1,39 @@
+/*
+ * Copyright 2004-2010 the original author or authors.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+package org.codehaus.groovy.grails.orm.hibernate
+
+import org.hibernate.FlushMode
+import org.hibernate.Session
+import org.springframework.orm.hibernate3.HibernateTransactionManager
+import org.springframework.transaction.TransactionDefinition
+
+/**
+ * Extends the standard class to always set the flush mode to manual when in a read-only transaction.
+ *
+ * @author Burt Beckwith
+ */
+class GrailsHibernateTransactionManager extends HibernateTransactionManager {
+
+	@Override
+	protected void doBegin(Object transaction, TransactionDefinition definition) {
+		super.doBegin transaction, definition
+
+		if (definition.isReadOnly()) {
+			// always set to manual; the base class doesn't because the OSIVI has already registered a session
+			transaction.sessionHolder.session.flushMode = FlushMode.MANUAL
+		}
+	}
+}

src/java/org/codehaus/groovy/grails/orm/hibernate/cfg/GORMSessionFactoryDefinitionParser.java

@@ -24,6 +24,7 @@
 import org.codehaus.groovy.grails.commons.DomainClassArtefactHandler;
 import org.codehaus.groovy.grails.commons.GrailsApplication;
 import org.codehaus.groovy.grails.orm.hibernate.ConfigurableLocalSessionFactoryBean;
+import org.codehaus.groovy.grails.orm.hibernate.GrailsHibernateTransactionManager;
 import org.codehaus.groovy.grails.orm.hibernate.support.SpringLobHandlerDetectorFactoryBean;
 import org.codehaus.groovy.grails.orm.hibernate.validation.HibernateDomainClassValidator;
 import org.springframework.beans.MutablePropertyValues;
@@ -44,7 +45,6 @@
 import org.springframework.beans.factory.xml.XmlReaderContext;
 import org.springframework.context.annotation.ClassPathBeanDefinitionScanner;
 import org.springframework.core.type.filter.AnnotationTypeFilter;
-import org.springframework.orm.hibernate3.HibernateTransactionManager;
 import org.springframework.util.StringUtils;
 import org.w3c.dom.Element;
 
@@ -215,7 +215,7 @@ private AbstractBeanDefinition parseSessionFactory(Element element, String dataS
         }
         else {
             GenericBeanDefinition transactionManagerBean = new GenericBeanDefinition();
-            transactionManagerBean.setBeanClass(HibernateTransactionManager.class);
+            transactionManagerBean.setBeanClass(GrailsHibernateTransactionManager.class);
             transactionManagerBean.getPropertyValues().addPropertyValue("sessionFactory", new RuntimeBeanReference(sessionFactoryId));
 
             targetRegistry.registerBeanDefinition("transactionManager", transactionManagerBean);

src/java/org/codehaus/groovy/grails/plugins/orm/hibernate/HibernatePluginSupport.groovy

@@ -35,13 +35,14 @@ import org.codehaus.groovy.grails.commons.spring.GrailsRuntimeConfigurator
 import org.codehaus.groovy.grails.commons.spring.RuntimeSpringConfiguration
 import org.codehaus.groovy.grails.exceptions.GrailsDomainException
 import org.codehaus.groovy.grails.orm.hibernate.ConfigurableLocalSessionFactoryBean
+import org.codehaus.groovy.grails.orm.hibernate.GrailsHibernateTransactionManager
 import org.codehaus.groovy.grails.orm.hibernate.cfg.GrailsDomainBinder
 import org.codehaus.groovy.grails.orm.hibernate.cfg.GrailsHibernateUtil
 import org.codehaus.groovy.grails.orm.hibernate.cfg.HibernateNamedQueriesBuilder
 import org.codehaus.groovy.grails.orm.hibernate.events.PatchedDefaultFlushEventListener
 import org.codehaus.groovy.grails.orm.hibernate.metaclass.*
 import org.codehaus.groovy.grails.orm.hibernate.support.*
-import org.codehaus.groovy.grails.orm.hibernate.proxy.HibernateProxyHandler;
+import org.codehaus.groovy.grails.orm.hibernate.proxy.HibernateProxyHandler
 import org.codehaus.groovy.grails.orm.hibernate.validation.HibernateDomainClassValidator
 import org.codehaus.groovy.grails.orm.hibernate.validation.PersistentConstraintFactory
 import org.codehaus.groovy.grails.orm.hibernate.validation.UniqueConstraint
@@ -220,7 +221,7 @@ Using Grails' default naming strategy: '${GrailsDomainBinder.namingStrategy.getC
                                   'post-delete':eventTriggeringInterceptor]
             }
 
-            transactionManager(HibernateTransactionManager) {
+            transactionManager(GrailsHibernateTransactionManager) {
                 sessionFactory = sessionFactory
             }
             persistenceInterceptor(HibernatePersistenceContextInterceptor) {

src/test/org/codehaus/groovy/grails/orm/hibernate/ReadOnlyTransactionTests.groovy

@@ -0,0 +1,39 @@
+package org.codehaus.groovy.grails.orm.hibernate
+
+class ReadOnlyTransactionTests extends AbstractGrailsHibernateTests {
+
+	protected void onSetUp() {
+		gcl.parseClass '''
+class Gorpledanger {
+    Long id
+    Long version
+    String name
+}
+
+class GorpledangerService {
+    static transactional = false
+
+    @org.springframework.transaction.annotation.Transactional(readOnly=true)
+    void doNotModify(thing) {
+        thing.name += 'wahoo'
+    }
+}
+'''
+	}
+
+	void testReadOnlyAnnotation() {
+		def clazz = ga.getDomainClass('Gorpledanger').clazz
+		def instance = clazz.newInstance()
+		instance.name = 'foo'
+		assertNotNull instance.save(flush: true)
+		session.clear()
+
+		instance = clazz.get(instance.id)
+		def service = appCtx.gorpledangerService
+		service.doNotModify instance
+		session.clear()
+
+		instance = clazz.get(instance.id)
+		assertEquals 'foo', instance.name
+	}
+}