improve date binding with @BindingFormat

Because SimpleDateFormat defaults to lenient=true, when binding to a
Date that is marked with @BindingFormat, bogus values result if the
supplied date doesn’t match format specified in @BindingFormat.  This
change makes the formatter be not lenient so a binding error will now
result.

Fixes #9667

Author: jeffscottbrown

grails-databinding/src/main/groovy/org/grails/databinding/converters/FormattedDateValueConverter.groovy

@@ -30,7 +30,9 @@ class FormattedDateValueConverter implements FormattedValueConverter {
         if(value instanceof Date) {
             return value
         }
-        new SimpleDateFormat(format).parse((String)value)
+        def fmt = new SimpleDateFormat(format)
+        fmt.lenient = false
+        fmt.parse((String) value)
     }
 
     Class<?> getTargetType() {

grails-databinding/src/test/groovy/grails/databinding/BindingFormatSpec.groovy

@@ -0,0 +1,60 @@
+package grails.databinding
+
+import grails.databinding.errors.BindingError
+import grails.databinding.events.DataBindingListenerAdapter
+import spock.lang.Specification
+
+import java.text.ParseException
+
+class BindingFormatSpec extends Specification {
+
+	void 'bind to a date'() {
+		given:
+		def binder = new SimpleDataBinder()
+		def obj = new SomeWidget()
+		def listener = new DateBindingListener()
+
+		when:
+		binder.bind obj, [birthDate: '11/15/1969'] as SimpleMapDataBindingSource, listener
+		def cal = Calendar.getInstance()
+		cal.time = obj.birthDate
+
+		then:
+		!listener.bindingErrors
+		cal.get(Calendar.MONTH) == Calendar.NOVEMBER
+		cal.get(Calendar.YEAR) == 1969
+		cal.get(Calendar.DATE) == 15
+
+		when:
+		obj = new SomeWidget()
+		binder.bind obj, [birthDate: '1969/11/15'] as SimpleMapDataBindingSource, listener
+
+		then:
+		!obj.birthDate
+		listener.bindingErrors
+		listener.bindingErrors.size() == 1
+
+		when:
+		def error = listener.bindingErrors[0]
+
+		then:
+		error.rejectedValue == '1969/11/15'
+		error.propertyName == 'birthDate'
+		error.cause instanceof ParseException
+		error.cause.message == 'Unparseable date: "1969/11/15"'
+	}
+}
+
+class SomeWidget {
+	@BindingFormat('MM/dd/yyyy')
+	Date birthDate
+}
+
+class DateBindingListener extends DataBindingListenerAdapter {
+
+	def bindingErrors = []
+
+	void bindingError(BindingError error, errors) {
+		bindingErrors << error
+	}
+}