Add cpr dependency for rest catalog client

Author: WillAyd

meson.build

@@ -21,7 +21,13 @@ project(
     version: '0.2.0',
     license: 'Apache-2.0',
     meson_version: '>=1.3.0',
-    default_options: ['cpp_std=c++23,c++latest', 'warning_level=2'],
+    default_options: [
+        'cpp_std=c++23,c++latest',
+        'warning_level=2',
+        # Don't build any tests for curl
+        'curl:tests=disabled',
+        'curl:unittests=disabled',
+    ],
 )
 
 subdir('src')

meson.options

@@ -15,4 +15,5 @@
 # specific language governing permissions and limitations
 # under the License.
 
+option('rest', type: 'feature', description: 'Build rest catalog client', value: 'enabled')
 option('tests', type: 'feature', description: 'Build tests', value: 'enabled')

src/iceberg/catalog/meson.build

@@ -16,3 +16,7 @@
 # under the License.
 
 install_headers(['in_memory_catalog.h'], subdir: 'iceberg/catalog')
+
+if get_option('rest').enabled()
+    subdir('rest')
+endif

src/iceberg/catalog/rest/iceberg_rest_export.h

@@ -0,0 +1,34 @@
+/*
+ * Licensed to the Apache Software Foundation (ASF) under one
+ * or more contributor license agreements.  See the NOTICE file
+ * distributed with this work for additional information
+ * regarding copyright ownership.  The ASF licenses this file
+ * to you under the Apache License, Version 2.0 (the
+ * "License"); you may not use this file except in compliance
+ * with the License.  You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing,
+ * software distributed under the License is distributed on an
+ * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+ * KIND, either express or implied.  See the License for the
+ * specific language governing permissions and limitations
+ * under the License.
+ */
+
+#pragma once
+
+#if defined(_WIN32) || defined(__CYGWIN__)
+#  ifdef ICEBERG_REST_STATIC
+#    define ICEBERG_REST_EXPORT
+#  elif defined(ICEBERG_REST_EXPORTING)
+#    define ICEBERG_REST_EXPORT __declspec(dllexport)
+#  else
+#    define ICEBERG_REST_EXPORT __declspec(dllimport)
+#  endif
+#else  // Not Windows
+#  ifndef ICEBERG_REST_EXPORT
+#    define ICEBERG_REST_EXPORT __attribute__((visibility("default")))
+#  endif
+#endif

src/iceberg/catalog/rest/meson.build

@@ -0,0 +1,49 @@
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements.  See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership.  The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License.  You may obtain a copy of the License at
+#
+#   http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied.  See the License for the
+# specific language governing permissions and limitations
+# under the License.
+
+iceberg_rest_sources = files('rest_catalog.cc')
+# cpr does not export symbols, so on Windows it must
+# be used as a static lib
+cpr_needs_static = (
+    get_option('default_library') == 'static' or
+    host_machine.system() == 'windows'
+)
+cpr_dep = dependency('cpr', static: cpr_needs_static)
+
+iceberg_rest_build_deps = [iceberg_dep, cpr_dep]
+iceberg_rest_lib = library(
+    'iceberg_rest',
+    sources: iceberg_rest_sources,
+    dependencies: iceberg_rest_build_deps,
+    gnu_symbol_visibility: 'hidden',
+    cpp_shared_args: ['-DICEBERG_REST_EXPORTING'],
+    cpp_static_args: ['-DICEBERG_REST_STATIC'],
+)
+
+iceberg_rest_compile_args = []
+if get_option('default_library') == 'static'
+    iceberg_rest_compile_args += ['-DICEBERG_REST_STATIC']
+endif
+iceberg_rest_dep = declare_dependency(
+    link_with: [iceberg_rest_lib],
+    dependencies: iceberg_rest_build_deps,
+    compile_args: iceberg_rest_compile_args,
+)
+meson.override_dependency('iceberg-rest', iceberg_rest_dep)
+pkg.generate(iceberg_rest_lib)
+
+install_headers(['rest_catalog.h'], subdir: 'iceberg/catalog/rest')

subprojects/cpr.wrap

@@ -0,0 +1,13 @@
+[wrap-file]
+directory = cpr-1.12.0
+source_url = https://github.com/libcpr/cpr/archive/1.12.0.tar.gz
+source_filename = cpr-1.12.0.tar.gz
+source_hash = f64b501de66e163d6a278fbb6a95f395ee873b7a66c905dd785eae107266a709
+patch_filename = cpr_1.12.0-1_patch.zip
+patch_url = https://wrapdb.mesonbuild.com/v2/cpr_1.12.0-1/get_patch
+patch_hash = 16404431dd8b2dbb49afc78a07b3bbe3c84c9f83ce1f45c3510934fadab99e72
+source_fallback_url = https://github.com/mesonbuild/wrapdb/releases/download/cpr_1.12.0-1/cpr-1.12.0.tar.gz
+wrapdb_version = 1.12.0-1
+
+[provide]
+cpr = cpr_dep

subprojects/curl.wrap

@@ -0,0 +1,13 @@
+[wrap-file]
+directory = curl-8.10.1
+source_url = https://github.com/curl/curl/releases/download/curl-8_10_1/curl-8.10.1.tar.xz
+source_fallback_url = https://github.com/mesonbuild/wrapdb/releases/download/curl_8.10.1-1/curl-8.10.1.tar.xz
+source_filename = curl-8.10.1.tar.xz
+source_hash = 73a4b0e99596a09fa5924a4fb7e4b995a85fda0d18a2c02ab9cf134bebce04ee
+patch_filename = curl_8.10.1-1_patch.zip
+patch_url = https://wrapdb.mesonbuild.com/v2/curl_8.10.1-1/get_patch
+patch_hash = 707c28f35fc9b0e8d68c0c2800712007612f922a31da9637ce706a2159f3ddd8
+wrapdb_version = 8.10.1-1
+
+[provide]
+dependency_names = libcurl