Add IRQ INPUTS examples

Author: manchoz

examples/Basic/IRQCounter/IRQCounter.ino

@@ -0,0 +1,56 @@
+/*
+    Testing strategy: alternatively create a short-time connection between
+    WAKEUP 1-6 and any of the +BAT_ext pins (the row above the WAKUP ones).
+
+    Check IRQChannelMap for advanced C++ implementation.
+*/
+
+#include <Arduino_EdgeControl.h>
+
+volatile int irqCounts[6] { };
+
+enum IRQChannelsIndex {
+    irqChannel1 = 0,
+    irqChannel2,
+    irqChannel3,
+    irqChannel4,
+    irqChannel5,
+    irqChannel6
+};
+
+
+void setup()
+{
+    EdgeControl.begin();
+    
+    Serial.begin(115200);
+
+    // Wait for Serial Monitor or start after 2.5s
+    for (const auto timeout = millis() + 2500; millis() < timeout && !Serial; delay(250));
+
+    // Init IRQ INPUT pins
+    for (auto pin = IRQ_CH1; pin <= IRQ_CH6; pin++)
+        pinMode(pin, INPUT);
+
+    // Attach callbacks to IRQ pins
+    attachInterrupt(digitalPinToInterrupt(IRQ_CH1), []{ irqCounts[irqChannel1]++; }, CHANGE);
+    attachInterrupt(digitalPinToInterrupt(IRQ_CH2), []{ irqCounts[irqChannel2]++; }, CHANGE);
+    attachInterrupt(digitalPinToInterrupt(IRQ_CH3), []{ irqCounts[irqChannel3]++; }, CHANGE);
+    attachInterrupt(digitalPinToInterrupt(IRQ_CH4), []{ irqCounts[irqChannel4]++; }, CHANGE);
+    attachInterrupt(digitalPinToInterrupt(IRQ_CH5), []{ irqCounts[irqChannel5]++; }, CHANGE);
+    attachInterrupt(digitalPinToInterrupt(IRQ_CH6), []{ irqCounts[irqChannel6]++; }, CHANGE);
+
+}
+
+void loop()
+{
+    // Check for received IRQ every second.
+    Serial.println("--------");
+    for (auto i = irqChannel1; i <= irqChannel6; i++) { 
+        Serial.print("IRQ Channel: ");
+        Serial.print(i + 1);
+        Serial.print(" - ");
+        Serial.println(irqCounts[i]);
+    }
+    delay(1000);
+}

examples/Basic/IRQCounterMap/IRQCounterMap.ino

@@ -0,0 +1,73 @@
+/*
+    Testing strategy: alternatively create a short-time connection between
+    WAKEUP 1-6 and any of the +BAT_ext pins (the row above the WAKUP ones).
+
+    Check IRQChannel for a simpler implementation.
+*/
+
+#include <Arduino_EdgeControl.h>
+
+#include <map>
+
+// Use a map to collect IRQ counts
+std::map<const pin_size_t, volatile unsigned int> irqCounts {
+    { IRQ_CH1, 0 },
+    { IRQ_CH2, 0 },
+    { IRQ_CH3, 0 },
+    { IRQ_CH4, 0 },
+    { IRQ_CH5, 0 },
+    { IRQ_CH6, 0 }
+};
+
+// Map pin numbers to pin names for pretty printing
+std::map<pin_size_t, const char*> irqNames {
+#define NE(IRQ) { IRQ, #IRQ }
+    NE(IRQ_CH1),
+    NE(IRQ_CH2),
+    NE(IRQ_CH3),
+    NE(IRQ_CH4),
+    NE(IRQ_CH5),
+    NE(IRQ_CH6),
+};
+
+void setup()
+{
+    EdgeControl.begin();
+
+    Serial.begin(115200);
+
+    // Wait for Serial Monitor or start after 2.5s
+    for (const auto timeout = millis() + 2500; millis() < timeout && !Serial; delay(250))
+        ;
+
+    // Init IRQ pins and attach callbacks
+    // NOTE: .first holds the channel pin and .second holds the counter
+    for (const auto& irq : irqCounts) {
+        // Init pins
+        pinMode(irq.first, INPUT);
+
+        // Create a type alias helper
+        using IrqCount = std::pair<const pin_size_t, volatile unsigned int>;
+
+        // Define the IRQ callback as lambda function
+        // Will receive an entry from the irqCounts map:
+        auto isr = [](void* arg) { IrqCount * ic = (IrqCount *)arg; (*ic).second++; };
+
+        // attach the callback passing the current map entry as parameter
+        attachInterruptParam(
+            digitalPinToInterrupt(irq.first), isr, RISING, (void*)&irq);
+    }
+}
+
+void loop()
+{
+    // Print counters every second.
+    Serial.println("--------");
+    for (const auto& irq : irqCounts) {
+        Serial.print("IRQ Channel: ");
+        Serial.print(irqNames[irq.first]);
+        Serial.print(" - Counts: ");
+        Serial.println(irq.second);
+    }
+    delay(1000);
+}