GPS.begin() works only with serial port connected

[kekko7072]

Hey I am currently working on a tracking device with LiPo battery and BLE, I fount that if the device is not booted using the USB connected as serial port the GPS shield attacked to a Arduino MKR 1010 Wifi will not work. After hours of debugging I found that the problem was created by GPS.begin() , but if I use it as shield it won't crash:

if (!GPS.begin(GPS_MODE_SHIELD)) {
      Serial.println("Failed to initialize GPS!");
    while (1)
      ;
  }

Any ideas?

[per1234]

Hi @kekko7072. Please provide a minimal sketch that can be used to reproduce the bug.

[kekko7072]

All the gps example, like this if you boot and attach a battery, then connect the usb and t then the battery and try to restart using the battery it will not work

/*
  GPS Location Standy

  This sketch uses the GPS to determine the location of the board
  and prints it to the Serial monitor.

  It puts the GPS to in standby mode every 10 seconds, then wakes it up.

  Circuit:
   - MKR board
   - MKR GPS attached via I2C cable

  This example code is in the public domain.
*/

#include <Arduino_MKRGPS.h>

void setup() {
  // initialize serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // If you are using the MKR GPS as shield, change the next line to pass
  // the GPS_MODE_SHIELD parameter to the GPS.begin(...)
  if (!GPS.begin()) {
    Serial.println("Failed to initialize GPS!");
    while (1);
  }
}

void loop() {
  // put the GPS in standby mode
  Serial.println("standby");
  GPS.standby();

  // wait for 10 seconds
  Serial.print("delay ");
  for (int i = 0; i < 10; i++) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println();

  // wake up the GPS
  Serial.println("wakeup");
  GPS.wakeup();

  Serial.print("wait location ... ");

  // wait for new GPS data to become available
  unsigned long startMillis = millis();
  while (!GPS.available());
  unsigned long endMillis = millis();

  Serial.print(endMillis - startMillis);
  Serial.println(" ms");

  // read GPS values
  float latitude   = GPS.latitude();
  float longitude  = GPS.longitude();
  float altitude   = GPS.altitude();
  int   satellites = GPS.satellites();

  // print GPS values
  Serial.println();
  Serial.print("Location: ");
  Serial.print(latitude, 7);
  Serial.print(", ");
  Serial.println(longitude, 7);

  Serial.print("Altitude: ");
  Serial.print(altitude);
  Serial.println("m");

  Serial.print("Number of satellites: ");
  Serial.println(satellites);

  Serial.println();
}

[per1234]

Thanks. This is the reason:

  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

This will make your code stay in an infinite loop until the serial port is opened in Serial Monitor. The reason that is useful is because on native USB boards like the MKR WiFi 1010, the board is not reset when you open the Serial Monitor. That means any serial output printed between the time the program starts running and you get the Serial Monitor open will be lost.

However, if you are wanting to run your program when the board is not connected to Serial Monitor, you must remove that while loop to allow it to run.

[kekko7072]

@per1234 pleas reopen the issue, was my mistake on posting this replay,

The issue is not that loop. My issue is with GPS.begin() starting without serial port connected. Please give it a try with a battery using the procedure I give you:

1. Use a ARDUINO MKR 1010 Wifi (or other MKR) with GPS connected using I2C And a 3.7 V battery attached.
2. Run the code below.
3. Disconnect the cable for serial port
4. Disconnect the battery
5. Await some seconds
6. Reconnect the battery

You will see that the Led will not blink it means that gps.begin failed and code crashed.

In fact the expected behaviour of the code below is that the led blink after the setup(){} the led blink, but it will not blink if you disconnect the battery from your board and reconnect it without having the cable for the serial port connected.

CODE:

#include <Arduino_MKRGPS.h>

void setup() {
  // initialize serial communications and wait for port to open:
  Serial.begin(9600);
  pinMode(LED_BUILTIN, OUTPUT);  // initialize the built-in LED pin to indicate when a central is connected

  // If you are using the MKR GPS as shield, change the next line to pass
  // the GPS_MODE_SHIELD parameter to the GPS.begin(...)
  if (!GPS.begin()) {
    Serial.println("Failed to initialize GPS!");
    while (1)
      ;
  }
}

void loop() {
  // put the GPS in standby mode
  Serial.println("standby");
  GPS.standby();

  // wait for 10 seconds
  Serial.print("delay ");
  for (int i = 0; i < 10; i++) {
    digitalWrite(LED_BUILTIN, HIGH);
    delay(500);
    Serial.print(".");
    digitalWrite(LED_BUILTIN, LOW);
    delay(500);
  }
  Serial.println();

  // wake up the GPS
  Serial.println("wakeup");
  GPS.wakeup();

  Serial.print("wait location ... ");

  // wait for new GPS data to become available
  unsigned long startMillis = millis();
  /*while (!GPS.available())
    ;*/
  unsigned long endMillis = millis();

  Serial.print(endMillis - startMillis);
  Serial.println(" ms");


  Serial.println();
  delay(5000);
}