Merge pull request #49 from agdl/WiFiSleep

WiFi sleep

Author: agdl

examples/WiFiSleepingWebClient/WiFiSleepingWebClient.ino

@@ -0,0 +1,155 @@
+/*
+
+  This example makes an http request every 10s
+  and puts in sleep mode WiFi in the meanwhile
+
+  Circuit:
+   WiFi shield 101 attached to an Arduino/Genuino board
+   or Arduino/Genuino MKR1000 board
+
+  https://www.arduino.cc/en/Tutorial/Wifi101WiFiSleepingWebClient
+
+  created 18 Mar 2016
+  by Arturo Guadalupi
+*/
+
+#include <SPI.h>
+#include <WiFi101.h>
+
+char ssid[] = "yourNetwork";     //  your network SSID (name)
+char pass[] = "yourPassword";    // your network password
+int status = WL_IDLE_STATUS;     // the Wifi radio's status
+
+WiFiSSLClient client;
+
+// server address:
+char server[] = "www.arduino.cc";
+
+void setup() {
+  //Initialize Serial and wait for port to open:
+  Serial.begin(9600);
+
+  // check for the presence of the shield:
+  if (WiFi.status() == WL_NO_SHIELD) {
+    Serial.println("WiFi shield not present");
+    // don't continue:
+    while (true);
+  }
+  // attempt to connect to WiFi network:
+
+  while ( status != WL_CONNECTED) {
+    Serial.print("Attempting to connect to WPA SSID: ");
+    Serial.println(ssid);
+    // Connect to WPA/WPA2 network:
+    status = WiFi.begin(ssid, pass);
+
+    // wait 10 seconds for connection:
+    delay(10000);
+  }
+
+  // you're connected now, so print out the data:
+  Serial.print("You're connected to the network");
+  printCurrentNet();
+  printWifiData();
+
+  Serial.println("Sleeping...");
+  WiFi.sleepFor(10000); //Sleep for 10s
+}
+
+void loop() {
+  if (WiFi.isAwake()) {
+    Serial.println("Awake!");
+    httpRequest();
+    listenToClient();
+    WiFi.sleepFor(10000); //Sleep for 10s
+    Serial.println("Sleeping");
+  }
+}
+
+void printWifiData() {
+  // print your WiFi shield's IP address:
+  IPAddress ip = WiFi.localIP();
+  Serial.print("IP Address: ");
+  Serial.println(ip);
+
+  // print your MAC address:
+  byte mac[6];
+  WiFi.macAddress(mac);
+  Serial.print("MAC address: ");
+  Serial.print(mac[5], HEX);
+  Serial.print(": ");
+  Serial.print(mac[4], HEX);
+  Serial.print(": ");
+  Serial.print(mac[3], HEX);
+  Serial.print(": ");
+  Serial.print(mac[2], HEX);
+  Serial.print(": ");
+  Serial.print(mac[1], HEX);
+  Serial.print(": ");
+  Serial.println(mac[0], HEX);
+
+}
+
+void printCurrentNet() {
+  // print the SSID of the network you're attached to:
+  Serial.print("SSID: ");
+  Serial.println(WiFi.SSID());
+
+  // print the MAC address of the router you're attached to:
+  byte bssid[6];
+  WiFi.BSSID(bssid);
+  Serial.print("BSSID: ");
+  Serial.print(bssid[5], HEX);
+  Serial.print(": ");
+  Serial.print(bssid[4], HEX);
+  Serial.print(": ");
+  Serial.print(bssid[3], HEX);
+  Serial.print(": ");
+  Serial.print(bssid[2], HEX);
+  Serial.print(": ");
+  Serial.print(bssid[1], HEX);
+  Serial.print(": ");
+  Serial.println(bssid[0], HEX);
+
+  // print the received signal strength:
+  long rssi = WiFi.RSSI();
+  Serial.print("signal strength (RSSI): ");
+  Serial.println(rssi);
+
+  // print the encryption type:
+  byte encryption = WiFi.encryptionType();
+  Serial.print("Encryption Type: ");
+  Serial.println(encryption, HEX);
+  Serial.println();
+}
+
+void httpRequest() {
+
+  if (client.connect(server, 443)) {
+    // Make a HTTP request:
+    client.println("GET /asciilogo.txt HTTP/1.1");
+    client.println("Host: arduino.cc");
+    client.println("Connection: close");
+    client.println();
+  }
+  else {
+    Serial.println("connection failed");
+  }
+}
+
+void listenToClient()
+{
+  unsigned long startTime = millis();
+  bool received = false;
+
+  while ((millis() - startTime < 10000) && !received) { //try to listen for 10 seconds
+    while (client.available()) {
+      received = true;
+      char c = client.read();
+      Serial.write(c);
+    }
+  }
+  client.stop();
+  Serial.println();
+}
+

keywords.txt

@@ -44,6 +44,12 @@ WiFiServer	KEYWORD2
 WiFiSSLClient	KEYWORD2
 WiFiMDNSResponder	KEYWORD2
 
+lowPowerMode	KEYWORD2
+maxLowPowerMode	KEYWORD2
+noLowPowerMode	KEYWORD2
+sleepFor	KEYWORD2
+isAwake	KEYWORD2
+
 #######################################
 # Constants (LITERAL1)
 #######################################

src/WiFi.cpp

@@ -177,6 +177,7 @@ WiFiClass::WiFiClass()
 	_mode = WL_RESET_MODE;
 	_status = WL_NO_SHIELD;
 	_init = 0;
+	_wakeUpMillis = 0;
 }
 
 void WiFiClass::setPins(int8_t cs, int8_t irq, int8_t rst, int8_t en)
@@ -776,6 +777,33 @@ void WiFiClass::refresh(void)
 	m2m_wifi_handle_events(NULL);
 }
 
+void WiFiClass::lowPowerMode(void)
+{
+	m2m_wifi_set_sleep_mode(M2M_PS_H_AUTOMATIC, true);
+}
+
+void WiFiClass::maxLowPowerMode(void)
+{
+	m2m_wifi_set_sleep_mode(M2M_PS_DEEP_AUTOMATIC, true);
+}
+
+void WiFiClass::noLowPowerMode(void)
+{
+	m2m_wifi_set_sleep_mode(M2M_NO_PS, false);
+}
+
+void WiFiClass::sleepFor(uint32_t thisTime)
+{
+	m2m_wifi_set_sleep_mode(M2M_PS_MANUAL, false);
+	_wakeUpMillis = millis() + thisTime + 150; //150 ms must elapse for complete awakening
+	m2m_wifi_request_sleep(thisTime);
+}
+
+bool WiFiClass::isAwake(void)
+{
+	return (millis() > _wakeUpMillis);
+}
+
 uint8_t WiFiClass::ping(const char* hostname, uint8_t ttl)
 {
 	IPAddress ip;

src/WiFi101.h

@@ -154,12 +154,21 @@ class WiFiClass
 	uint8_t ping(const char* hostname, uint8_t ttl = 128);
 	uint8_t ping(const String &hostname, uint8_t ttl = 128);
 	uint8_t ping(IPAddress host, uint8_t ttl = 128);
-	
+
 	void refresh(void);
 
+	void lowPowerMode(void);
+	void maxLowPowerMode(void);
+	void noLowPowerMode(void);
+	void sleepFor(uint32_t thisTime);
+	bool isAwake(void);
+
 private:
 	int _init;
 	char _version[9];
+
+	uint32_t _wakeUpMillis;
+
 	uint8_t startConnect(const char *ssid, uint8_t u8SecType, const void *pvAuthInfo);
 	uint8_t startAP(const char *ssid, uint8_t u8SecType, const void *pvAuthInfo, uint8_t channel);
 };