Add new LED example

Author: sandeepmistry

libraries/CurieBle/examples/LED/LED.ino

@@ -0,0 +1,78 @@
+/*
+   Copyright (c) 2015 Intel Corporation.  All rights reserved.
+
+   This library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   This library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with this library; if not, write to the Free Software
+   Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
+*/
+#include <CurieBle.h>
+
+/* BLE Peripheral (this Intel Curie device) */
+BlePeripheral blePeripheral;
+
+/* BLE LED Service */
+BleService ledService("19B10000-E8F2-537E-4F6C-D104768A1214");
+
+/* BLE Switch Characteristic - custom 128-bit UUID, read and writable by central */
+BleUnsignedCharCharacteristic switchCharacteristic("19B10000E8F2537E4F6CD104768A1214", BleRead | BleWrite);
+
+const int ledPin = 13; // pin to use for the LED
+
+void setup() {
+  Serial.begin(9600);
+
+  // set LED pin to output mode
+  pinMode(ledPin, OUTPUT);
+
+  // set advertised local name and service UUID
+  blePeripheral.setLocalName("LED");
+  blePeripheral.setAdvertisedServiceUuid(ledService.uuid());
+
+  // add service and characteristic
+  blePeripheral.addAttribute(ledService);
+  blePeripheral.addAttribute(switchCharacteristic);
+
+  // begin initialization
+  blePeripheral.begin();
+
+  Serial.println(F("BLE LED Peripheral"));
+}
+
+void loop() {
+  BleCentral central = blePeripheral.central();
+
+  if (central) {
+    // central connected to peripheral
+    Serial.print(F("Connected to central: "));
+    Serial.println(central.address());
+
+    while (central.connected()) {
+      // central still connected to peripheral
+      if (switchCharacteristic.written()) {
+        // central wrote new value to characteristic, update LED
+        if (switchCharacteristic.value()) {
+          Serial.println(F("LED on"));
+          digitalWrite(ledPin, HIGH);
+        } else {
+          Serial.println(F("LED off"));
+          digitalWrite(ledPin, LOW);
+        }
+      }
+    }
+
+    // central disconnected
+    Serial.print(F("Disconnected from central: "));
+    Serial.println(central.address());
+  }
+}
+