DOC: Update meson and f2py for automated wrappers

Author: HaoZeke

doc/source/f2py/buildtools/index.rst

@@ -1,3 +1,5 @@
+.. _f2py-bldsys:
+
 =======================
 F2PY and Build Systems
 =======================

doc/source/f2py/buildtools/meson.rst

@@ -82,6 +82,30 @@ possible. The easiest way to solve this is to let ``f2py`` deal with it:
    python -c 'import fib2'
 
 
+Automating wrapper generation
+^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
+
+A major pain point in the workflow defined above, is the manual tracking of
+inputs. Although it would require more effort to figure out the actual outputs
+for reasons discussed in :ref:`f2py-bldsys`.
+
+However, we can augment our workflow in a straightforward to take into account
+files for which the outputs are known when the build system is set up.
+
+.. literalinclude:: ./../code/meson_upd.build
+    :language: meson
+
+This can be compiled and run as before.
+
+.. code-block:: bash
+
+    rm -rf builddir
+    meson setup builddir
+    meson compile -C builddir
+    cd builddir
+    python -c "import numpy as np; import fibby; a = np.zeros(9); fibby.fib(a); print (a)"
+    # [ 0.  1.  1.  2.  3.  5.  8. 13. 21.]
+
 Salient points
 ===============
 

doc/source/f2py/code/meson.build

@@ -5,8 +5,10 @@ project('f2py_examples', 'c',
 add_languages('fortran')
 
 py_mod = import('python')
-py3 = py_mod.find_installation()
+py3 = py_mod.find_installation('python3')
 py3_dep = py3.dependency()
+message(py3.path())
+message(py3.get_install_dir())
 
 incdir_numpy = run_command(py3,
   ['-c', 'import os; os.chdir(".."); import numpy; print(numpy.get_include())'],
@@ -18,13 +20,19 @@ incdir_f2py = run_command(py3,
     check : true
 ).stdout().strip()
 
+fibby_source = custom_target('fibbymodule.c',
+                            input : ['fib1.f'],
+                            output : ['fibbymodule.c'],
+                            command : [ py3, '-m', 'numpy.f2py', '@INPUT@',
+                            '-m', 'fibby', '--lower' ]
+                            )
+
 inc_np = include_directories(incdir_numpy, incdir_f2py)
 
-py3.extension_module('fib2',
+py3.extension_module('fibby',
            'fib1.f',
-           'fib2module.c',
+           fibby_source,
            incdir_f2py+'/fortranobject.c',
            include_directories: inc_np,
            dependencies : py3_dep,
            install : true)
-

doc/source/f2py/code/meson_upd.build

@@ -0,0 +1,37 @@
+project('f2py_examples', 'c',
+  version : '0.1',
+  default_options : ['warning_level=2'])
+
+add_languages('fortran')
+
+py_mod = import('python')
+py3 = py_mod.find_installation('python3')
+py3_dep = py3.dependency()
+message(py3.path())
+message(py3.get_install_dir())
+
+incdir_numpy = run_command(py3,
+  ['-c', 'import os; os.chdir(".."); import numpy; print(numpy.get_include())'],
+  check : true
+).stdout().strip()
+
+incdir_f2py = run_command(py3,
+    ['-c', 'import os; os.chdir(".."); import numpy.f2py; print(numpy.f2py.get_include())'],
+    check : true
+).stdout().strip()
+
+fibby_source = custom_target('fibbymodule.c',
+                            input : ['fib1.f'],
+                            output : ['fibbymodule.c'],
+                            command : [ py3, '-m', 'numpy.f2py', '@INPUT@',
+                            '-m', 'fibby', '--lower' ])
+
+inc_np = include_directories(incdir_numpy, incdir_f2py)
+
+py3.extension_module('fibby',
+           'fib1.f',
+           fibby_source,
+           incdir_f2py+'/fortranobject.c',
+           include_directories: inc_np,
+           dependencies : py3_dep,
+           install : true)