Support env argument in macroexpand-1 and store ctx during macro invocation

macroexpand-1 now accepts an optional env map as first argument (like
cljs.analyzer/macroexpand-1). Locals in the env shadow macro names,
matching CLJS behavior.

During macro invocation, the current analysis context is now stored
via ctx-store, so that macroexpand-1 called from within macro bodies
sees the correct bindings. This enables riddley's macroexpand-all to
discover outer locals in bb, similar to how it reads Compiler/LOCAL_ENV
on JVM.

Author: borkdude

CHANGELOG.md

@@ -16,6 +16,8 @@ SCI is used in [babashka](https://github.com/babashka/babashka),
 - `case` now macroexpands to JVM-compatible `case*` format, enabling tools like riddley and cloverage to work with SCI
 - Fix `.method` on class objects (e.g. `(.getDeclaredField String "value")`) routing to static instead of instance method path
 - `macroexpand-1` of `(.method ClassName)` now wraps class targets in `identity`, matching Clojure behavior
+- `macroexpand-1` now accepts an optional env map as first argument, like `cljs.analyzer/macroexpand-1`
+- Store current analysis context during macro invocation, enabling tools like riddley to access outer locals
 - Support [#564](https://github.com/babashka/sci/issues/564): `this-as` in ClojureScript
 
 ## 0.12.51 (2025-02-07)

src/sci/impl/analyzer.cljc

@@ -23,6 +23,7 @@
     [ana-macros constant? macro? rethrow-with-location-of-node
      set-namespace! recur special-syms]]
    [sci.impl.vars :as vars]
+   [sci.ctx-store :as store]
    [sci.lang])
   #?(:cljs
      (:require-macros
@@ -1625,7 +1626,8 @@
                                                @f
                                                f)
                                            f (or (.-afn ^js f) f)])
-                                v (apply f expr (:bindings ctx) (rest expr))
+                                v (store/with-ctx ctx
+                                    (apply f expr (:bindings ctx) (rest expr)))
                                 v (if (seq? v)
                                     (with-meta v (merge m (meta v)))
                                     v)

src/sci/impl/namespaces.cljc

@@ -790,11 +790,21 @@
 
 ;;;; Macroexpand
 
-(defn macroexpand* [expr]
-  (mexpand/macroexpand (store/get-ctx) expr))
-
-(defn macroexpand-1* [expr]
-  (mexpand/macroexpand-1 (store/get-ctx) expr))
+(defn macroexpand*
+  ([expr]
+   (mexpand/macroexpand (store/get-ctx) expr))
+  ([env expr]
+   (mexpand/macroexpand (cond-> (store/get-ctx)
+                          env (update :bindings merge env))
+                        expr)))
+
+(defn macroexpand-1*
+  ([expr]
+   (mexpand/macroexpand-1 (store/get-ctx) expr))
+  ([env expr]
+   (mexpand/macroexpand-1 (cond-> (store/get-ctx)
+                            env (update :bindings merge env))
+                          expr)))
 
 ;;;;
 

test/sci/core_test.cljc

@@ -1121,7 +1121,13 @@
             (is (= '(. (clojure.core/identity String) getDeclaredFields)
                    (eval* "(macroexpand-1 '(.getDeclaredFields String))")))
             (is (= '(. "foo" length)
-                   (eval* "(macroexpand-1 '(.length \"foo\"))"))))))
+                   (eval* "(macroexpand-1 '(.length \"foo\"))")))))
+  #?(:clj (testing "macroexpand-1 accepts env as first argument"
+            (is (= '(if 1 1 (clojure.core/cond))
+                   (eval* "(macroexpand-1 {'a 1} '(cond 1 1))")))
+            (is (= '(cond 1 1)
+                   (eval* "(macroexpand-1 {'cond 1} '(cond 1 1))"))
+                "local shadows macro"))))
 
 (deftest macroexpand-call-test
   (is (= [1 1] (eval* "(defmacro foo [x] `(bar ~x)) (defmacro bar [x] [x x]) (macroexpand '(foo 1))")))