basilisp.pprint/print-table function (#983)

Peeling away parts of #513

Author: chrisrink10

CHANGELOG.md

@@ -7,6 +7,7 @@ and this project adheres to [Semantic Versioning](https://semver.org/spec/v2.0.0
 ## [Unreleased]
 ### Added
  * Added the `CollReduce` and `KVReduce` protocols in `basilisp.core.protocols` and implemented `reduce` in terms of those protocols (#927)
+ * Added `basilisp.pprint/print-table` function (#983)
 
 ### Changed
  * Improved on the nREPL server exception messages by matching that of the REPL user friendly format (#968)

docs/differencesfromclojure.rst

@@ -223,6 +223,7 @@ Basilisp includes ports of some of the standard libraries from Clojure which sho
 * :lpy:ns:`basilisp.io` is a port of ``clojure.java.io``
 * :lpy:ns:`basilisp.set` is a port of ``clojure.set``
 * :lpy:ns:`basilisp.shell` is a port of ``clojure.java.shell``
+* :lpy:ns:`basilisp.stacktrace` is a port of ``clojure.stacktrace``
 * :lpy:ns:`basilisp.string` is a port of ``clojure.string``
 * :lpy:ns:`basilisp.test` is a port of ``clojure.test``
 * :lpy:ns:`basilisp.walk` is a port of ``clojure.walk``

src/basilisp/lang/compiler/generator.py

@@ -3049,7 +3049,7 @@ def _local_sym_to_py_ast(
     assert node.op == NodeOp.LOCAL
 
     sym_entry = ctx.symbol_table.find_symbol(sym.symbol(node.name))
-    assert sym_entry is not None
+    assert sym_entry is not None, f"Expected symbol {sym.symbol(node.name)}"
 
     if node.local == LocalType.FIELD:
         this_entry = ctx.symbol_table.find_symbol(ctx.current_this)

src/basilisp/pprint.lpy

@@ -0,0 +1,46 @@
+(ns basilisp.pprint
+  (:require [basilisp.string :as str]))
+
+(defn print-table
+  "Print a collection of maps as a table to the buffer currently bound to
+  :lpy:var:`basilisp.core/*out*`.
+
+  If there is at least one element in ``rows``, a header row will be printed
+  followed by a single divider row followed by a line for each element in ``rows``.
+
+  If no keys are given (as ``ks``), then use the keys returned from the first
+  element in ``rows`` (as by ``(keys (first rows))``). Note that in this case,
+  the order of headers in the resulting table is based on the order of keys
+  returned by :lpy:fn:`basilisp.core/keys`."
+  ([rows]
+   (when (seq rows)
+     (print-table (keys (first rows)) rows)))
+  ([ks rows]
+   (when (seq rows)
+     (let [widths (persistent!
+                   (reduce (fn [counts row]
+                             (reduce (fn [counts [k col]]
+                                       (if-let [cnt (get counts k)]
+                                         (->> (max cnt (count (str col)))
+                                              (assoc! counts k))
+                                         counts))
+                                     counts
+                                     row))
+                           (->> ks
+                                (map (comp count str))
+                                (zipmap ks)
+                                transient)
+                           rows))]
+       (letfn [(fmt-row [start end joiner elems]
+                 (as-> elems $
+                   (str/join joiner $)
+                   (str start $ end)))
+               (row-str [row]
+                 (->> (map #(str/lpad (str (get row %)) (get widths %)) ks)
+                      (fmt-row "| " " |" " | ")))]
+         (println (row-str (zipmap ks ks)))
+         (->> (map #(apply str (repeat (get widths %) "-")) ks)
+              (fmt-row "+-" "-+" "-+-")
+              (println))
+         (doseq [row rows]
+           (println (row-str row))))))))

tests/basilisp/test_pprint.lpy

@@ -0,0 +1,54 @@
+(ns tests.basilisp.test-pprint
+  (:require
+   [basilisp.pprint :as pprint]
+   [basilisp.string :as str]
+   [basilisp.test :refer [deftest are is testing]])
+  (:import os textwrap))
+
+(defn trim-newlines-and-dedent
+  [s]
+  (-> (textwrap/dedent s)
+      (str/ltrim)
+      (str/replace "\n" os/linesep)))
+
+(deftest print-table-test
+  (is (= "" (with-out-str (pprint/print-table []))))
+  (is (= "" (with-out-str (pprint/print-table [:a :b :c] []))))
+
+  (is (= (trim-newlines-and-dedent
+          "
+          |     :a |
+          +--------+
+          |      1 |
+          |      b |
+          | :horse |
+          ")
+         (with-out-str (pprint/print-table [{:a 1} {:a "b"} {:a :horse}]))))
+
+  (is (= (trim-newlines-and-dedent
+          "
+          |  :a | :b |                 :c |
+          +-----+----+--------------------+
+          |   1 |  2 |                  3 |
+          |   7 |  5 | catdogbirdsquirrel |
+          | 432 |  f |                    |
+          ")
+         (with-out-str
+           (pprint/print-table [:a :b :c]
+                               [{:a 1 :b 2 :c 3}
+                                {:b 5 :a 7 :c "catdogbirdsquirrel"}
+                                {:a 432 :b "f"}]))))
+
+  (is (= (trim-newlines-and-dedent
+          "
+          |  :a | :b |                 :c | :d |
+          +-----+----+--------------------+----+
+          |   1 |  2 |                  3 |    |
+          |   7 |  5 | catdogbirdsquirrel |    |
+          | 432 |  f |                    |    |
+          ")
+         (with-out-str
+           (pprint/print-table [:a :b :c :d]
+                               [{:a 1 :b 2 :c 3}
+                                {:b 5 :a 7 :c "catdogbirdsquirrel"}
+                                {:a 432 :b "f"}])))))