|
| 1 | +"""Resource set definitions for build actions""" |
| 2 | + |
| 3 | +load("@bazel_lib//lib:resource_sets.bzl", "resource_set_for") |
| 4 | +load("@bazel_skylib//rules:common_settings.bzl", "BuildSettingInfo", "int_flag", "string_flag") |
| 5 | + |
| 6 | +_DEFAULT_SIZE = "default" |
| 7 | +_SIZES = { |
| 8 | + "enormous": { |
| 9 | + "cpu": 16, |
| 10 | + "mem": 2048, |
| 11 | + }, |
| 12 | + "large": { |
| 13 | + "cpu": 8, |
| 14 | + "mem": 1024, |
| 15 | + }, |
| 16 | + "medium": { |
| 17 | + "cpu": 4, |
| 18 | + "mem": 500, |
| 19 | + }, |
| 20 | + "small": { |
| 21 | + "cpu": 2, |
| 22 | + "mem": 250, |
| 23 | + }, |
| 24 | + "tiny": { |
| 25 | + "cpu": 1, |
| 26 | + "mem": 250, |
| 27 | + }, |
| 28 | +} |
| 29 | + |
| 30 | +def _setting(size, resource, mode): |
| 31 | + if size == _DEFAULT_SIZE: |
| 32 | + short_name = _DEFAULT_SIZE |
| 33 | + else: |
| 34 | + short_name = "{}_{}".format(size, resource) |
| 35 | + |
| 36 | + if mode == "key": |
| 37 | + return "_size_config_" + short_name |
| 38 | + elif mode == "label": |
| 39 | + return "//foreign_cc/settings:size_" + short_name |
| 40 | + else: |
| 41 | + fail("unknown mode", mode) |
| 42 | + |
| 43 | +def create_settings(): |
| 44 | + """create the settings that configure these functions.""" |
| 45 | + string_flag( |
| 46 | + name = "size_default", |
| 47 | + build_setting_default = _DEFAULT_SIZE, |
| 48 | + values = _SIZES.keys() + [_DEFAULT_SIZE], |
| 49 | + visibility = ["//visibility:public"], |
| 50 | + ) |
| 51 | + |
| 52 | + for size, cfg in _SIZES.items(): |
| 53 | + if cfg == None: |
| 54 | + continue |
| 55 | + |
| 56 | + # keep this in sync with the docs and the above helper! |
| 57 | + int_flag( |
| 58 | + name = "size_{}_cpu".format(size), |
| 59 | + build_setting_default = _SIZES[size]["cpu"], |
| 60 | + visibility = ["//visibility:public"], |
| 61 | + ) |
| 62 | + |
| 63 | + int_flag( |
| 64 | + name = "size_{}_mem".format(size), |
| 65 | + build_setting_default = _SIZES[size]["mem"], |
| 66 | + visibility = ["//visibility:public"], |
| 67 | + ) |
| 68 | + |
| 69 | +SIZE_ATTRIBUTES = { |
| 70 | + "resource_size": attr.string( |
| 71 | + values = _SIZES.keys() + [_DEFAULT_SIZE], |
| 72 | + default = _DEFAULT_SIZE, |
| 73 | + mandatory = False, |
| 74 | + doc = ( |
| 75 | + "Set the approximate size of this build. This does two things:" + |
| 76 | + "1. Sets the environment variables to tell the underlying build system " + |
| 77 | + " the requested parallelization; examples are CMAKE_BUILD_PARALLEL_LEVEL " + |
| 78 | + " for cmake or MAKEFLAGS for autotools. " + |
| 79 | + "2. Sets the resource_set attribute on the action to tell bazel how many cores " + |
| 80 | + " are being used, so it schedules appropriately." + |
| 81 | + "The sizes map to labels, which can be used to override the meaning of the sizes. See " + |
| 82 | + "@rules_foreign_cc//foreign_cc/settings:size_{size}_{cpu|mem}" |
| 83 | + ), |
| 84 | + ), |
| 85 | +} | { |
| 86 | + _setting(size = size, resource = resource, mode = "key"): attr.label( |
| 87 | + default = _setting(size, resource, mode = "label"), |
| 88 | + providers = [BuildSettingInfo], |
| 89 | + ) |
| 90 | + for size in _SIZES.keys() |
| 91 | + for resource in ["cpu", "mem"] |
| 92 | +} | { |
| 93 | + _setting(size = _DEFAULT_SIZE, resource = None, mode = "key"): attr.label( |
| 94 | + default = _setting(size = _DEFAULT_SIZE, resource = None, mode = "label"), |
| 95 | + providers = [BuildSettingInfo], |
| 96 | + ), |
| 97 | +} |
| 98 | + |
| 99 | +def _get_size_config(attr, size, resource): |
| 100 | + name = _setting(size = size, resource = resource, mode = "key") |
| 101 | + s = getattr(attr, name, None) |
| 102 | + |
| 103 | + if s == None: |
| 104 | + fail("unknown size: ", size) |
| 105 | + |
| 106 | + return s[BuildSettingInfo].value |
| 107 | + |
| 108 | +def get_resource_set(attr): |
| 109 | + """ get the resource set as configured by the settings and attrs |
| 110 | +
|
| 111 | + Args: |
| 112 | + attr: the ctx.attr associated with the target |
| 113 | + Returns: |
| 114 | + A tuple of: |
| 115 | + - the resource_set, or None if it's the bazel default |
| 116 | + - cpu_cores, or 0 if it's the bazel default |
| 117 | + - mem in MB, or 0 if it's the bazel default |
| 118 | + """ |
| 119 | + size = _DEFAULT_SIZE |
| 120 | + if attr.resource_size != _DEFAULT_SIZE: |
| 121 | + size = attr.resource_size |
| 122 | + else: |
| 123 | + size = _get_size_config(attr, _DEFAULT_SIZE, None) |
| 124 | + |
| 125 | + if size == _DEFAULT_SIZE: |
| 126 | + return None, 0, 0 |
| 127 | + |
| 128 | + cpu_value = _get_size_config(attr, size, "cpu") |
| 129 | + mem_value = _get_size_config(attr, size, "mem") |
| 130 | + |
| 131 | + if cpu_value < 0: |
| 132 | + fail("cpu must be >= 0") |
| 133 | + |
| 134 | + if mem_value < 0: |
| 135 | + fail("mem must be >= 0") |
| 136 | + |
| 137 | + resource_set = resource_set_for( |
| 138 | + cpu_cores = cpu_value, |
| 139 | + mem_mb = mem_value, |
| 140 | + ) |
| 141 | + |
| 142 | + if resource_set: |
| 143 | + actual_resources = resource_set("", "") |
| 144 | + actual_cpu = actual_resources.get("cpu", 0) |
| 145 | + actual_mem = actual_resources.get("mem", 0) |
| 146 | + else: |
| 147 | + actual_cpu = 0 |
| 148 | + actual_mem = 0 |
| 149 | + |
| 150 | + return resource_set, actual_cpu, actual_mem |
0 commit comments