|
| 1 | +# Copyright 2024 The Bazel Authors. All rights reserved. |
| 2 | +# |
| 3 | +# Licensed under the Apache License, Version 2.0 (the "License"); |
| 4 | +# you may not use this file except in compliance with the License. |
| 5 | +# You may obtain a copy of the License at |
| 6 | +# |
| 7 | +# http://www.apache.org/licenses/LICENSE-2.0 |
| 8 | +# |
| 9 | +# Unless required by applicable law or agreed to in writing, software |
| 10 | +# distributed under the License is distributed on an "AS IS" BASIS, |
| 11 | +# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. |
| 12 | +# See the License for the specific language governing permissions and |
| 13 | +# limitations under the License. |
| 14 | +"""Builders to make building complex objects easier.""" |
| 15 | + |
| 16 | +load("@bazel_skylib//lib:types.bzl", "types") |
| 17 | + |
| 18 | +def _DepsetBuilder(): |
| 19 | + """Create a builder for a depset.""" |
| 20 | + |
| 21 | + # buildifier: disable=uninitialized |
| 22 | + self = struct( |
| 23 | + _order = [None], |
| 24 | + add = lambda *a, **k: _DepsetBuilder_add(self, *a, **k), |
| 25 | + build = lambda *a, **k: _DepsetBuilder_build(self, *a, **k), |
| 26 | + direct = [], |
| 27 | + get_order = lambda *a, **k: _DepsetBuilder_get_order(self, *a, **k), |
| 28 | + set_order = lambda *a, **k: _DepsetBuilder_set_order(self, *a, **k), |
| 29 | + transitive = [], |
| 30 | + ) |
| 31 | + return self |
| 32 | + |
| 33 | +def _DepsetBuilder_add(self, *values): |
| 34 | + """Add value to the depset. |
| 35 | +
|
| 36 | + Args: |
| 37 | + self: {type}`DepsetBuilder` implicitly added. |
| 38 | + *values: {type}`depset | list | object` Values to add to the depset. |
| 39 | + The values can be a depset, the non-depset value to add, or |
| 40 | + a list of such values to add. |
| 41 | +
|
| 42 | + Returns: |
| 43 | + {type}`DepsetBuilder` |
| 44 | + """ |
| 45 | + for value in values: |
| 46 | + if types.is_list(value): |
| 47 | + for sub_value in value: |
| 48 | + if types.is_depset(sub_value): |
| 49 | + self.transitive.append(sub_value) |
| 50 | + else: |
| 51 | + self.direct.append(sub_value) |
| 52 | + elif types.is_depset(value): |
| 53 | + self.transitive.append(value) |
| 54 | + else: |
| 55 | + self.direct.append(value) |
| 56 | + return self |
| 57 | + |
| 58 | +def _DepsetBuilder_set_order(self, order): |
| 59 | + """Sets the order to use. |
| 60 | +
|
| 61 | + Args: |
| 62 | + self: {type}`DepsetBuilder` implicitly added. |
| 63 | + order: {type}`str` One of the {obj}`depset` `order` values. |
| 64 | +
|
| 65 | + Returns: |
| 66 | + {type}`DepsetBuilder` |
| 67 | + """ |
| 68 | + self._order[0] = order |
| 69 | + return self |
| 70 | + |
| 71 | +def _DepsetBuilder_get_order(self): |
| 72 | + """Gets the depset order that will be used. |
| 73 | +
|
| 74 | + Args: |
| 75 | + self: {type}`DepsetBuilder` implicitly added. |
| 76 | +
|
| 77 | + Returns: |
| 78 | + {type}`str | None` If not previously set, `None` is returned. |
| 79 | + """ |
| 80 | + return self._order[0] |
| 81 | + |
| 82 | +def _DepsetBuilder_build(self): |
| 83 | + """Creates a {obj}`depset` from the accumulated values. |
| 84 | +
|
| 85 | + Args: |
| 86 | + self: {type}`DepsetBuilder` implicitly added. |
| 87 | +
|
| 88 | + Returns: |
| 89 | + {type}`depset` |
| 90 | + """ |
| 91 | + if not self.direct and len(self.transitive) == 1 and self._order[0] == None: |
| 92 | + return self.transitive[0] |
| 93 | + else: |
| 94 | + kwargs = {} |
| 95 | + if self._order[0] != None: |
| 96 | + kwargs["order"] = self._order[0] |
| 97 | + return depset(direct = self.direct, transitive = self.transitive, **kwargs) |
| 98 | + |
| 99 | +def _RunfilesBuilder(): |
| 100 | + """Creates a `RunfilesBuilder`. |
| 101 | +
|
| 102 | + Returns: |
| 103 | + {type}`RunfilesBuilder` |
| 104 | + """ |
| 105 | + |
| 106 | + # buildifier: disable=uninitialized |
| 107 | + self = struct( |
| 108 | + add = lambda *a, **k: _RunfilesBuilder_add(self, *a, **k), |
| 109 | + add_targets = lambda *a, **k: _RunfilesBuilder_add_targets(self, *a, **k), |
| 110 | + build = lambda *a, **k: _RunfilesBuilder_build(self, *a, **k), |
| 111 | + files = _DepsetBuilder(), |
| 112 | + root_symlinks = {}, |
| 113 | + runfiles = [], |
| 114 | + symlinks = {}, |
| 115 | + ) |
| 116 | + return self |
| 117 | + |
| 118 | +def _RunfilesBuilder_add(self, *values): |
| 119 | + """Adds a value to the runfiles. |
| 120 | +
|
| 121 | + Args: |
| 122 | + self: {type}`RunfilesBuilder` implicitly added. |
| 123 | + *values: {type}`File | runfiles | list[File] | depset[File] | list[runfiles]` |
| 124 | + The values to add. |
| 125 | +
|
| 126 | + Returns: |
| 127 | + {type}`RunfilesBuilder` |
| 128 | + """ |
| 129 | + for value in values: |
| 130 | + if types.is_list(value): |
| 131 | + for sub_value in value: |
| 132 | + _RunfilesBuilder_add_internal(self, sub_value) |
| 133 | + else: |
| 134 | + _RunfilesBuilder_add_internal(self, value) |
| 135 | + return self |
| 136 | + |
| 137 | +def _RunfilesBuilder_add_targets(self, targets): |
| 138 | + """Adds runfiles from targets |
| 139 | +
|
| 140 | + Args: |
| 141 | + self: {type}`RunfilesBuilder` implicitly added. |
| 142 | + targets: {type}`list[Target]` targets whose default runfiles |
| 143 | + to add. |
| 144 | +
|
| 145 | + Returns: |
| 146 | + {type}`RunfilesBuilder` |
| 147 | + """ |
| 148 | + for t in targets: |
| 149 | + self.runfiles.append(t[DefaultInfo].default_runfiles) |
| 150 | + return self |
| 151 | + |
| 152 | +def _RunfilesBuilder_add_internal(self, value): |
| 153 | + if _is_file(value): |
| 154 | + self.files.add(value) |
| 155 | + elif types.is_depset(value): |
| 156 | + self.files.add(value) |
| 157 | + elif _is_runfiles(value): |
| 158 | + self.runfiles.append(value) |
| 159 | + else: |
| 160 | + fail("Unhandled value: type {}: {}".format(type(value), value)) |
| 161 | + |
| 162 | +def _RunfilesBuilder_build(self, ctx, **kwargs): |
| 163 | + """Creates a {obj}`runfiles` from the accumulated values. |
| 164 | +
|
| 165 | + Args: |
| 166 | + self: {type}`RunfilesBuilder` implicitly added. |
| 167 | + ctx: {type}`ctx` The rule context to use to create the runfiles object. |
| 168 | + **kwargs: additional args to pass along to {obj}`ctx.runfiles`. |
| 169 | +
|
| 170 | + Returns: |
| 171 | + {type}`runfiles` |
| 172 | + """ |
| 173 | + return ctx.runfiles( |
| 174 | + transitive_files = self.files.build(), |
| 175 | + symlinks = self.symlinks, |
| 176 | + root_symlinks = self.root_symlinks, |
| 177 | + **kwargs |
| 178 | + ).merge_all(self.runfiles) |
| 179 | + |
| 180 | +# Skylib's types module doesn't have is_file, so roll our own |
| 181 | +def _is_file(value): |
| 182 | + return type(value) == "File" |
| 183 | + |
| 184 | +def _is_runfiles(value): |
| 185 | + return type(value) == "runfiles" |
| 186 | + |
| 187 | +builders = struct( |
| 188 | + DepsetBuilder = _DepsetBuilder, |
| 189 | + RunfilesBuilder = _RunfilesBuilder, |
| 190 | +) |
0 commit comments