skip local_toolchains test if before 3.9

Author: rickeylev

tests/integration/local_toolchains/BUILD.bazel

@@ -13,8 +13,30 @@
 # limitations under the License.
 
 load("@rules_python//python:py_test.bzl", "py_test")
+load(":defs.bzl", "toolchain_version_condition")
 
 py_test(
     name = "test",
     srcs = ["test.py"],
+    # Make this test better respect pyenv
+    env_inherit = ["PYENV_VERSION"],
+    # NOTE: This isn't strictly correct because is_toolchain_py39plus
+    # ends up using the config state coming into the target, not from within
+    # the target. There's no transitions going on, though, so it works OK.
+    target_compatible_with = select({
+        # Our RBE's system python is 3.6, which is too old.
+        ":is_toolchain_py39plus": [],
+        "//conditions:default": ["@platforms//:incompatible"],
+    }),
+)
+
+config_setting(
+    name = "is_toolchain_py39plus",
+    flag_values = {
+        ":toolchain_py39plus_flag": "yes",
+    },
+)
+
+toolchain_version_condition(
+    name = "toolchain_py39plus_flag",
 )

tests/integration/local_toolchains/MODULE.bazel

@@ -14,6 +14,8 @@
 module(name = "module_under_test")
 
 bazel_dep(name = "rules_python", version = "0.0.0")
+bazel_dep(name = "platforms", version = "0.0.11")
+
 local_path_override(
     module_name = "rules_python",
     path = "../../..",

tests/integration/local_toolchains/defs.bzl

@@ -0,0 +1,13 @@
+def _toolchain_version_condition_impl(ctx):
+    runtime = ctx.toolchains["@rules_python//python:toolchain_type"].py_runtime
+    version = (
+        runtime.interpreter_version_info.major,
+        runtime.interpreter_version_info.minor,
+    )
+    value = "yes" if version >= (3, 9) else "no"
+    return [config_common.FeatureFlagInfo(value = value)]
+
+toolchain_version_condition = rule(
+    implementation = _toolchain_version_condition_impl,
+    toolchains = ["@rules_python//python:toolchain_type"],
+)

tests/integration/local_toolchains/test.py

@@ -47,6 +47,7 @@ def test_python_from_path_used(self):
 realpath base_exe: {os.path.realpath(sys._base_executable)}
 
 from shell resolution:
+which python3: {shell_path=}:
 {shell_exe=}
 {shell_base_exe=}
 realpath exe     : {os.path.realpath(shell_exe)}