feat: allow proto_library as rb_library#dep

Author: alexeagle

MODULE.bazel

@@ -16,6 +16,9 @@ bazel_dep(name = "platforms", version = "0.0.5")
 bazel_dep(name = "rules_cc", version = "0.0.9")
 bazel_dep(name = "rules_java", version = "7.2.0")
 
+# NB: LOWER BOUND on earliest BCR release of protobuf module, to avoid upgrading the root module by accident
+bazel_dep(name = "protobuf", version = "3.19.6")
+
 # Ruleset development dependencies.
 bazel_dep(name = "aspect_bazel_lib", version = "2.21.2", dev_dependency = True)
 bazel_dep(name = "bazel_skylib_gazelle_plugin", version = "1.8.2", dev_dependency = True)

ruby/BUILD

@@ -9,6 +9,11 @@ toolchain_type(
     visibility = ["//visibility:public"],
 )
 
+toolchain_type(
+    name = "ruby_grpc_protoc_plugin.toolchain_type",
+    visibility = ["//visibility:public"],
+)
+
 bzl_library(
     name = "defs",
     srcs = ["defs.bzl"],

ruby/private/library.bzl

@@ -1,5 +1,6 @@
 "Implementation details for rb_library"
 
+load("//ruby/private:proto.bzl", "ruby_proto_aspect")
 load(
     "//ruby/private:providers.bzl",
     "BundlerInfo",
@@ -18,6 +19,8 @@ ATTRS = {
     ),
     "deps": attr.label_list(
         doc = "List of other Ruby libraries the target depends on.",
+        # Convert proto_library deps to provide RubyFilesInfo
+        aspects = [ruby_proto_aspect],
     ),
     "data": attr.label_list(
         allow_files = True,

ruby/private/proto.bzl

@@ -0,0 +1,92 @@
+"""Ruby proto generation aspect for rules_ruby.
+
+This file is loaded by `rules_ruby` (see its `rb_library` implementation) using
+`@@//proto:ruby.bzl`, so it must remain in this workspace at `proto/ruby.bzl`.
+"""
+
+load("@protobuf//bazel/common:proto_info.bzl", "ProtoInfo")
+load("//ruby/private:providers.bzl", "GrpcPluginInfo", "RubyFilesInfo")
+
+def _ruby_grpc_protoc_plugin_toolchain_impl(ctx):
+    return [platform_common.ToolchainInfo(
+        grpc = GrpcPluginInfo(grpc_plugin = ctx.attr.grpc_plugin.files_to_run),
+    )]
+
+ruby_grpc_protoc_plugin_toolchain = rule(
+    implementation = _ruby_grpc_protoc_plugin_toolchain_impl,
+    attrs = {
+        "grpc_plugin": attr.label(
+            mandatory = True,
+            executable = True,
+            cfg = "exec",
+        ),
+    },
+)
+
+GRPC_PLUGIN_TOOLCHAIN = "@rules_ruby//ruby:ruby_grpc_protoc_plugin.toolchain_type"
+PROTO_TOOLCHAIN = "@protobuf//bazel/private:proto_toolchain_type"
+RUBY_OUTPUT_FILE = "{proto_file_basename}_pb.rb"
+RUBY_SERVICE_OUTPUT_FILE = "{proto_file_basename}_services_pb.rb"
+
+def _ruby_proto_aspect_impl(target, ctx):
+    if not ProtoInfo in target:
+        return []
+
+    # Use Bazel 9 feature to have a dynamic dependency graph based on file contents
+    has_services = ctx.actions.declare_directory(target.label.name + ".has_services")
+    ctx.actions.run_shell(
+        # TODO: write a more robust parser maybe with tree-sitter
+        command = "mkdir -p {out_dir}; touch {out_dir}/has_messages; grep -q 'service' {proto_files} && touch {out_dir}/services".format(
+            out_dir = has_services.path,
+            proto_files = " ".join([p.path for p in target[ProtoInfo].direct_sources]),
+        ),
+        inputs = target[ProtoInfo].direct_sources,
+        outputs = [has_services],
+    )
+
+    proto_info = ctx.toolchains[PROTO_TOOLCHAIN].proto
+    grpc_info = ctx.toolchains[GRPC_PLUGIN_TOOLCHAIN].grpc
+    print("grpc_info: %s" % grpc_info.grpc_plugin)
+    print("proto_info: %s" % proto_info.proto_compiler)
+    proto_srcs = target[ProtoInfo].direct_sources
+    proto_deps = target[ProtoInfo].transitive_sources
+    outputs = []
+    for src in proto_srcs:
+        proto_file_basename = src.basename.replace(".proto", "")
+        msg_output = ctx.actions.declare_file(RUBY_OUTPUT_FILE.format(proto_file_basename = proto_file_basename))
+        service_output = ctx.actions.declare_file(RUBY_SERVICE_OUTPUT_FILE.format(proto_file_basename = proto_file_basename))
+        ctx.actions.run_shell(
+            # https://grpc.io/docs/languages/ruby/basics/#generating-client-and-server-code
+            # grpc_tools_ruby_protoc -I ../../protos --ruby_out=../lib --grpc_out=../lib ../../protos/route_guide.proto
+            command = "{protoc} --plugin=protoc-gen-grpc={grpc} --ruby_out={bindir} --grpc_out={bindir} {sources}".format(
+                protoc = proto_info.proto_compiler.executable.path,
+                sources = " ".join([p.path for p in proto_srcs]),
+                grpc = grpc_info.grpc_plugin.executable.path,
+                bindir = ctx.bin_dir.path,
+            ),
+            tools = [grpc_info.grpc_plugin, proto_info.proto_compiler],
+            inputs = depset(proto_srcs + [has_services], transitive = [proto_deps]),
+            outputs = [msg_output, service_output],
+        )
+        outputs.append(msg_output)
+        outputs.append(service_output)
+    return [
+        DefaultInfo(
+            files = depset(
+                outputs,
+            ),
+        ),
+        RubyFilesInfo(
+            transitive_srcs = depset(outputs),
+            transitive_deps = depset(),
+            transitive_data = depset(),
+            bundle_env = {},
+        ),
+    ]
+
+ruby_proto_aspect = aspect(
+    implementation = _ruby_proto_aspect_impl,
+    attr_aspects = ["deps"],
+    required_providers = [ProtoInfo],
+    toolchains = [PROTO_TOOLCHAIN, GRPC_PLUGIN_TOOLCHAIN],
+)

ruby/private/providers.bzl

@@ -29,6 +29,13 @@ GemInfo = provider(
     },
 )
 
+GrpcPluginInfo = provider(
+    doc = "Provider for the gRPC plugin to use for proto services generation.",
+    fields = {
+        "grpc_plugin": "The gRPC plugin executable.",
+    },
+)
+
 # https://bazel.build/rules/depsets
 
 def get_transitive_srcs(srcs, deps):

ruby/proto.bzl

@@ -0,0 +1,16 @@
+load("//ruby/private:proto.bzl", "GRPC_PLUGIN_TOOLCHAIN", "ruby_grpc_protoc_plugin_toolchain")
+
+def rb_grpc_protoc_plugin_toolchain(name, grpc_plugin):
+    concrete_target = name + ".concrete"
+
+    ruby_grpc_protoc_plugin_toolchain(
+        name = concrete_target,
+        grpc_plugin = grpc_plugin,
+    )
+
+    native.toolchain(
+        name = name,
+        toolchain_type = GRPC_PLUGIN_TOOLCHAIN,
+        visibility = ["//visibility:public"],
+        toolchain = concrete_target,
+    )