Extract the cc_static_library rule from @_builtins to @rules_cc

hvadehra · copybara-github · commit 2ba751fe00f8 · 2025-07-24T05:17:16.000-07:00
PiperOrigin-RevId: 786663475
Change-Id: Idaa9ed2db6acfd0c41c27eb117c9ee7afd53c02b
diff --git a/cc/common/cc_helper.bzl b/cc/common/cc_helper.bzl
@@ -20,6 +20,7 @@ load(
     "get_relative_path",
     "is_versioned_shared_library_extension_valid",
     "path_contains_up_level_references",
+    _artifact_category = "artifact_category",
     _package_source_root = "package_source_root",
     _repository_exec_path = "repository_exec_path",
 )
@@ -37,6 +38,8 @@ linker_mode = struct(
 
 # LINT.IfChange(forked_exports)
 
+artifact_category = _artifact_category
+
 def _get_compilation_contexts_from_deps(deps):
     compilation_contexts = []
     for dep in deps:
diff --git a/cc/common/cc_helper_internal.bzl b/cc/common/cc_helper_internal.bzl
@@ -22,6 +22,33 @@ load("@bazel_skylib//lib:paths.bzl", "paths")
 
 # LINT.IfChange(forked_exports)
 
+artifact_category = struct(
+    STATIC_LIBRARY = "STATIC_LIBRARY",
+    ALWAYSLINK_STATIC_LIBRARY = "ALWAYSLINK_STATIC_LIBRARY",
+    DYNAMIC_LIBRARY = "DYNAMIC_LIBRARY",
+    EXECUTABLE = "EXECUTABLE",
+    INTERFACE_LIBRARY = "INTERFACE_LIBRARY",
+    PIC_FILE = "PIC_FILE",
+    INCLUDED_FILE_LIST = "INCLUDED_FILE_LIST",
+    SERIALIZED_DIAGNOSTICS_FILE = "SERIALIZED_DIAGNOSTICS_FILE",
+    OBJECT_FILE = "OBJECT_FILE",
+    PIC_OBJECT_FILE = "PIC_OBJECT_FILE",
+    CPP_MODULE = "CPP_MODULE",
+    CPP_MODULE_GCM = "CPP_MODULE_GCM",
+    CPP_MODULE_IFC = "CPP_MODULE_IFC",
+    CPP_MODULES_INFO = "CPP_MODULES_INFO",
+    CPP_MODULES_DDI = "CPP_MODULES_DDI",
+    CPP_MODULES_MODMAP = "CPP_MODULES_MODMAP",
+    CPP_MODULES_MODMAP_INPUT = "CPP_MODULES_MODMAP_INPUT",
+    GENERATED_ASSEMBLY = "GENERATED_ASSEMBLY",
+    PROCESSED_HEADER = "PROCESSED_HEADER",
+    GENERATED_HEADER = "GENERATED_HEADER",
+    PREPROCESSED_C_SOURCE = "PREPROCESSED_C_SOURCE",
+    PREPROCESSED_CPP_SOURCE = "PREPROCESSED_CPP_SOURCE",
+    COVERAGE_DATA_FILE = "COVERAGE_DATA_FILE",
+    CLIF_OUTPUT_PROTO = "CLIF_OUTPUT_PROTO",
+)
+
 def is_versioned_shared_library_extension_valid(shared_library_name):
     """Validates the name against the regex "^.+\\.((so)|(dylib))(\\.\\d\\w*)+$",
 
diff --git a/cc/private/rules_impl/cc_static_library.bzl b/cc/private/rules_impl/cc_static_library.bzl
@@ -1,4 +1,4 @@
-# Copyright 2025 The Bazel Authors. All rights reserved.
+# Copyright 2024 The Bazel Authors. All rights reserved.
 #
 # Licensed under the Apache License, Version 2.0 (the "License");
 # you may not use this file except in compliance with the License.
@@ -11,6 +11,287 @@
 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 # See the License for the specific language governing permissions and
 # limitations under the License.
-"""cc_static_library rule without a macro"""
+"""This is an experimental implementation of cc_static_library.
 
-cc_static_library = native.cc_static_library
+We may change the implementation at any moment or even delete this file. Do not
+rely on this.
+"""
+
+load("@bazel_skylib//lib:paths.bzl", "paths")
+load("//cc:action_names.bzl", "ACTION_NAMES")
+load("//cc:find_cc_toolchain.bzl", "find_cc_toolchain", "use_cc_toolchain")
+load("//cc/common:cc_common.bzl", "cc_common")
+load("//cc/common:cc_helper.bzl", "artifact_category")
+load("//cc/common:cc_info.bzl", "CcInfo")
+
+def _declare_static_library(*, name, actions, cc_toolchain):
+    basename = paths.basename(name)
+    new_basename = cc_common.get_artifact_name_for_category(
+        cc_toolchain = cc_toolchain,
+        category = artifact_category.STATIC_LIBRARY,
+        output_name = basename,
+    )
+    return actions.declare_file(name.removesuffix(basename) + new_basename)
+
+def _collect_linker_inputs(deps):
+    transitive_linker_inputs = [dep[CcInfo].linking_context.linker_inputs for dep in deps]
+    return depset(transitive = transitive_linker_inputs, order = "topological")
+
+def _flatten_and_get_objects(linker_inputs):
+    # Flattening a depset to get the action inputs.
+    transitive_objects = []
+    for linker_input in linker_inputs.to_list():
+        for lib in linker_input.libraries:
+            if lib._contains_objects:
+                transitive_objects.append(depset(lib.pic_objects))
+                transitive_objects.append(depset(lib.objects))
+
+    return depset(transitive = transitive_objects, order = "topological")
+
+def _archive_objects(*, name, actions, cc_toolchain, feature_configuration, objects):
+    static_library = _declare_static_library(
+        name = name,
+        actions = actions,
+        cc_toolchain = cc_toolchain,
+    )
+
+    archiver_path = cc_common.get_tool_for_action(
+        feature_configuration = feature_configuration,
+        action_name = ACTION_NAMES.cpp_link_static_library,
+    )
+    archiver_variables = cc_common.create_link_variables(
+        cc_toolchain = cc_toolchain,
+        feature_configuration = feature_configuration,
+        output_file = static_library.path,
+        is_using_linker = False,
+    )
+    command_line = cc_common.get_memory_inefficient_command_line(
+        feature_configuration = feature_configuration,
+        action_name = ACTION_NAMES.cpp_link_static_library,
+        variables = archiver_variables,
+    )
+    args = actions.args()
+    args.add_all(command_line)
+    args.add_all(objects)
+
+    if cc_common.is_enabled(
+        feature_configuration = feature_configuration,
+        feature_name = "archive_param_file",
+    ):
+        # TODO: The flag file arg should come from the toolchain instead.
+        args.use_param_file("@%s", use_always = True)
+
+    env = cc_common.get_environment_variables(
+        feature_configuration = feature_configuration,
+        action_name = ACTION_NAMES.cpp_link_static_library,
+        variables = archiver_variables,
+    )
+    execution_requirements_keys = cc_common.get_execution_requirements(
+        feature_configuration = feature_configuration,
+        action_name = ACTION_NAMES.cpp_link_static_library,
+    )
+
+    actions.run(
+        executable = archiver_path,
+        arguments = [args],
+        env = env,
+        execution_requirements = {k: "" for k in execution_requirements_keys},
+        inputs = depset(transitive = [cc_toolchain.all_files, objects]),
+        outputs = [static_library],
+        use_default_shell_env = True,
+        mnemonic = "CppTransitiveArchive",
+        progress_message = "Creating static library %{output}",
+    )
+
+    return static_library
+
+def _validate_static_library(*, name, actions, cc_toolchain, feature_configuration, static_library):
+    if not cc_common.action_is_enabled(
+        feature_configuration = feature_configuration,
+        action_name = ACTION_NAMES.validate_static_library,
+    ):
+        return None
+
+    validation_output = actions.declare_file(name + "_validation_output.txt")
+
+    validator_path = cc_common.get_tool_for_action(
+        feature_configuration = feature_configuration,
+        action_name = ACTION_NAMES.validate_static_library,
+    )
+    args = actions.args()
+    args.add(static_library)
+    args.add(validation_output)
+
+    execution_requirements_keys = cc_common.get_execution_requirements(
+        feature_configuration = feature_configuration,
+        action_name = ACTION_NAMES.validate_static_library,
+    )
+
+    actions.run(
+        executable = validator_path,
+        arguments = [args],
+        execution_requirements = {k: "" for k in execution_requirements_keys},
+        inputs = depset(
+            direct = [static_library],
+            transitive = [cc_toolchain.all_files],
+        ),
+        outputs = [validation_output],
+        use_default_shell_env = True,
+        mnemonic = "ValidateStaticLibrary",
+        progress_message = "Validating static library %{label}",
+    )
+
+    return validation_output
+
+def _pretty_label(label):
+    s = str(label)
+
+    # Emit main repo labels (both with and without --enable_bzlmod) without a
+    # repo prefix.
+    if s.startswith("@@//") or s.startswith("@//"):
+        return s.lstrip("@")
+    return s
+
+def _linkdeps_map_each(linker_input):
+    has_library = False
+    for lib in linker_input.libraries:
+        if lib._contains_objects:
+            # Has been added to the archive.
+            return None
+        if lib.pic_static_library != None or lib.static_library != None or lib.dynamic_library != None or lib.interface_library != None:
+            has_library = True
+    if not has_library:
+        # Does not provide any linkable artifact. May still contribute to linkopts.
+        return None
+
+    return _pretty_label(linker_input.owner)
+
+def _linkopts_map_each(linker_input):
+    return linker_input.user_link_flags
+
+def _format_linker_inputs(*, actions, name, linker_inputs, map_each):
+    file = actions.declare_file(name)
+    args = actions.args().add_all(linker_inputs, map_each = map_each)
+    actions.write(output = file, content = args)
+    return file
+
+def _cc_static_library_impl(ctx):
+    cc_toolchain = find_cc_toolchain(ctx)
+    feature_configuration = cc_common.configure_features(
+        ctx = ctx,
+        cc_toolchain = cc_toolchain,
+        requested_features = ctx.features + ["symbol_check"],
+        unsupported_features = ctx.disabled_features,
+    )
+
+    linker_inputs = _collect_linker_inputs(ctx.attr.deps)
+
+    static_library = _archive_objects(
+        name = ctx.label.name,
+        actions = ctx.actions,
+        cc_toolchain = cc_toolchain,
+        feature_configuration = feature_configuration,
+        objects = _flatten_and_get_objects(linker_inputs),
+    )
+
+    linkdeps_file = _format_linker_inputs(
+        actions = ctx.actions,
+        name = ctx.label.name + "_linkdeps.txt",
+        linker_inputs = linker_inputs,
+        map_each = _linkdeps_map_each,
+    )
+
+    linkopts_file = _format_linker_inputs(
+        actions = ctx.actions,
+        name = ctx.label.name + "_linkopts.txt",
+        linker_inputs = linker_inputs,
+        map_each = _linkopts_map_each,
+    )
+
+    validation_output = _validate_static_library(
+        name = ctx.label.name,
+        actions = ctx.actions,
+        cc_toolchain = cc_toolchain,
+        feature_configuration = feature_configuration,
+        static_library = static_library,
+    )
+
+    output_groups = {
+        "linkdeps": depset([linkdeps_file]),
+        "linkopts": depset([linkopts_file]),
+    }
+    if validation_output:
+        output_groups["_validation"] = depset([validation_output])
+
+    runfiles = ctx.runfiles().merge_all([
+        dep[DefaultInfo].default_runfiles
+        for dep in ctx.attr.deps
+    ])
+
+    return [
+        DefaultInfo(
+            files = depset([static_library]),
+            runfiles = runfiles,
+        ),
+        OutputGroupInfo(**output_groups),
+    ]
+
+cc_static_library = rule(
+    implementation = _cc_static_library_impl,
+    doc = """
+Produces a static library from a list of targets and their transitive dependencies.
+
+<p>The resulting static library contains the object files of the targets listed in
+<code>deps</code> as well as their transitive dependencies, with preference given to
+<code>PIC</code> objects.</p>
+
+<h4 id="cc_static_library_output_groups">Output groups</h4>
+
+<h5><code>linkdeps</code></h5>
+<p>A text file containing the labels of those transitive dependencies of targets listed in
+<code>deps</code> that did not contribute any object files to the static library, but do
+provide at least one static, dynamic or interface library. The resulting static library
+may require these libraries to be available at link time.</p>
+
+<h5><code>linkopts</code></h5>
+<p>A text file containing the user-provided <code>linkopts</code> of all transitive
+dependencies of targets listed in <code>deps</code>.
+
+<h4 id="cc_static_library_symbol_check">Duplicate symbols</h4>
+<p>By default, the <code>cc_static_library</code> rule checks that the resulting static
+library does not contain any duplicate symbols. If it does, the build fails with an error
+message that lists the duplicate symbols and the object files containing them.</p>
+
+<p>This check can be disabled per target or per package by setting
+<code>features = ["-symbol_check"]</code> or globally via
+<code>--features=-symbol_check</code>.</p>
+
+<h5 id="cc_static_library_symbol_check_toolchain">Toolchain support for <code>symbol_check</code></h5>
+<p>The auto-configured C++ toolchains shipped with Bazel support the
+<code>symbol_check</code> feature on all platforms. Custom toolchains can add support for
+it in one of two ways:</p>
+<ul>
+  <li>Implementing the <code>ACTION_NAMES.validate_static_library</code> action and
+  enabling it with the <code>symbol_check</code> feature. The tool set in the action is
+  invoked with two arguments, the static library to check for duplicate symbols and the
+  path of a file that must be created if the check passes.</li>
+  <li>Having the <code>symbol_check</code> feature add archiver flags that cause the
+  action creating the static library to fail on duplicate symbols.</li>
+</ul>
+""",
+    attrs = {
+        "deps": attr.label_list(
+            providers = [CcInfo],
+            doc = """
+The list of targets to combine into a static library, including all their transitive
+dependencies.
+
+<p>Dependencies that do not provide any object files are not included in the static
+library, but their labels are collected in the file provided by the
+<code>linkdeps</code> output group.</p>
+""",
+        ),
+    },
+    toolchains = use_cc_toolchain(),
+    fragments = ["cpp"],
+)
