Add support for collecting a target's cfg flags into CrateInfo. (#3603)

This change add a new `cfgs` field to `CrateInfo`. When setting
`//rust/settings:collect_cfgs` is set, all cfg flags for a target will
be collected into the `cfgs` field.

Author: bmoxb

rust/private/providers.bzl

@@ -46,6 +46,10 @@ CrateInfo = provider(
             "str, optional: The original crate type for targets generated using a previously defined " +
             "crate (typically tests using the `rust_test::crate` attribute)"
         ),
+        "cfgs": (
+            "List[str]: The set of enabled cfgs for this crate. Note that this field is populated only " +
+            "when @rules_rust//rust/settings:collect_cfgs is set."
+        ),
     },
 )
 

rust/private/rust.bzl

@@ -15,6 +15,7 @@
 """Rust rule implementations"""
 
 load("@bazel_skylib//lib:paths.bzl", "paths")
+load("@bazel_skylib//rules:common_settings.bzl", "BuildSettingInfo")
 load("@rules_cc//cc/common:cc_info.bzl", "CcInfo")
 load("//rust/private:common.bzl", "COMMON_PROVIDERS", "rust_common")
 load(
@@ -24,7 +25,7 @@ load(
     "BuildInfo",
     "LintsInfo",
 )
-load("//rust/private:rustc.bzl", "rustc_compile_action")
+load("//rust/private:rustc.bzl", "collect_extra_rustc_flags", "is_no_std", "rustc_compile_action")
 load(
     "//rust/private:utils.bzl",
     "can_build_metadata",
@@ -224,6 +225,7 @@ def _rust_library_common(ctx, crate_type):
             compile_data = depset(compile_data),
             compile_data_targets = depset(ctx.attr.compile_data),
             owner = ctx.label,
+            cfgs = _collect_cfgs(ctx, toolchain, crate_root, crate_type, crate_is_test = False),
         ),
     )
 
@@ -287,6 +289,7 @@ def _rust_binary_impl(ctx):
             compile_data = depset(compile_data),
             compile_data_targets = depset(ctx.attr.compile_data),
             owner = ctx.label,
+            cfgs = _collect_cfgs(ctx, toolchain, crate_root, ctx.attr.crate_type, crate_is_test = False),
         ),
     )
 
@@ -413,6 +416,7 @@ def _rust_test_impl(ctx):
             compile_data_targets = compile_data_targets,
             wrapped_crate_type = crate.type,
             owner = ctx.label,
+            cfgs = _collect_cfgs(ctx, toolchain, crate_root, crate_type, crate_is_test = True),
         )
     else:
         crate_name = compute_crate_name(ctx.workspace_name, ctx.label, toolchain, ctx.attr.crate_name)
@@ -475,6 +479,7 @@ def _rust_test_impl(ctx):
             compile_data = depset(compile_data),
             compile_data_targets = depset(ctx.attr.compile_data),
             owner = ctx.label,
+            cfgs = _collect_cfgs(ctx, toolchain, crate_root, crate_type, crate_is_test = True),
         )
 
     providers = rustc_compile_action(
@@ -798,6 +803,10 @@ _common_attrs = {
         doc = "A setting used to determine whether or not the `--stamp` flag is enabled",
         default = Label("//rust/private:stamp"),
     ),
+    "_collect_cfgs": attr.label(
+        doc = "Enable collection of cfg flags with results stored in CrateInfo.cfgs.",
+        default = Label("//rust/settings:collect_cfgs"),
+    ),
 } | RUSTC_ATTRS | _rustc_allocator_libraries_attrs
 
 _coverage_attrs = {
@@ -1706,3 +1715,34 @@ def _replace_illlegal_chars(name):
     for illegal_char in ["-", "/", "."]:
         name = name.replace(illegal_char, "_")
     return name
+
+def _collect_cfgs(ctx, toolchain, crate_root, crate_type, crate_is_test):
+    """Collect all cfg flags for a crate but only when @rules_rust//rust/settings:collect_cfgs is set.
+
+    Cfgs are gathered from the target's own attributes (e.g., rustc_flags, crate_featues, etc.), as
+    well as from the toolchain (e.g., toolchain.extra_rustc_flags).
+
+    Args:
+        ctx (ctx): The current rule's context object.
+        toolchain (rust_toolchain): The current Rust toolchain.
+        crate_root (File): The root file of the crate.
+        crate_type (str): The crate type.
+        crate_is_test (bool): Whether the crate is a test target or not.
+
+    Returns:
+        List[str]: All cfg flags for the target (or empty list if build setting is unset).
+    """
+
+    if not (hasattr(ctx.attr, "_collect_cfgs") and ctx.attr._collect_cfgs[BuildSettingInfo].value):
+        return []
+
+    cfgs = {'feature="{}"'.format(feature): True for feature in getattr(ctx.attr, "crate_features", [])}
+
+    if is_no_std(ctx, toolchain, crate_is_test):
+        cfgs['feature="no_std"'] = True
+
+    rustc_flags = getattr(ctx.attr, "rustc_flags", []) + collect_extra_rustc_flags(ctx, toolchain, crate_root, crate_type)
+    cfgs |= {flag.removeprefix("--cfg="): True for flag in rustc_flags if flag.startswith("--cfg=")}
+    cfgs |= {value: True for (flag, value) in zip(rustc_flags[:-1], rustc_flags[1:]) if flag == "--cfg"}
+
+    return list(cfgs)

rust/private/rustc.bzl

@@ -1115,39 +1115,16 @@ def construct_arguments(
     if toolchain._rename_first_party_crates:
         env["RULES_RUST_THIRD_PARTY_DIR"] = toolchain._third_party_dir
 
-    if crate_info.type in toolchain.extra_rustc_flags_for_crate_types.keys():
-        rustc_flags.add_all(toolchain.extra_rustc_flags_for_crate_types[crate_info.type], map_each = map_flag)
-
-    if is_exec_configuration(ctx):
-        rustc_flags.add_all(toolchain.extra_exec_rustc_flags, map_each = map_flag)
-    else:
-        rustc_flags.add_all(toolchain.extra_rustc_flags, map_each = map_flag)
-
     # extra_rustc_env applies to the target configuration, not the exec configuration.
     if hasattr(ctx.attr, "_extra_rustc_env") and not is_exec_configuration(ctx):
         env.update(ctx.attr._extra_rustc_env[ExtraRustcEnvInfo].extra_rustc_env)
 
-    # extra_rustc_flags apply to the target configuration, not the exec configuration.
-    if hasattr(ctx.attr, "_extra_rustc_flags") and not is_exec_configuration(ctx):
-        rustc_flags.add_all(ctx.attr._extra_rustc_flags[ExtraRustcFlagsInfo].extra_rustc_flags, map_each = map_flag)
-
-    if hasattr(ctx.attr, "_extra_rustc_flag") and not is_exec_configuration(ctx):
-        rustc_flags.add_all(ctx.attr._extra_rustc_flag[ExtraRustcFlagsInfo].extra_rustc_flags, map_each = map_flag)
-
-    if hasattr(ctx.attr, "_per_crate_rustc_flag") and not is_exec_configuration(ctx):
-        per_crate_rustc_flags = ctx.attr._per_crate_rustc_flag[PerCrateRustcFlagsInfo].per_crate_rustc_flags
-        _add_per_crate_rustc_flags(ctx, rustc_flags, map_flag, crate_info, per_crate_rustc_flags)
-
     if hasattr(ctx.attr, "_extra_exec_rustc_env") and is_exec_configuration(ctx):
         env.update(ctx.attr._extra_exec_rustc_env[ExtraExecRustcEnvInfo].extra_exec_rustc_env)
 
-    if hasattr(ctx.attr, "_extra_exec_rustc_flags") and is_exec_configuration(ctx):
-        rustc_flags.add_all(ctx.attr._extra_exec_rustc_flags[ExtraExecRustcFlagsInfo].extra_exec_rustc_flags, map_each = map_flag)
-
-    if hasattr(ctx.attr, "_extra_exec_rustc_flag") and is_exec_configuration(ctx):
-        rustc_flags.add_all(ctx.attr._extra_exec_rustc_flag[ExtraExecRustcFlagsInfo].extra_exec_rustc_flags, map_each = map_flag)
+    rustc_flags.add_all(collect_extra_rustc_flags(ctx, toolchain, crate_info.root, crate_info.type), map_each = map_flag)
 
-    if _is_no_std(ctx, toolchain, crate_info):
+    if is_no_std(ctx, toolchain, crate_info.is_test):
         rustc_flags.add('--cfg=feature="no_std"')
 
     # Add target specific flags last, so they can override previous flags
@@ -1175,6 +1152,45 @@ def construct_arguments(
 
     return args, env
 
+def collect_extra_rustc_flags(ctx, toolchain, crate_root, crate_type):
+    """Gather all 'extra' rustc flags from the target's attributes and toolchain.
+
+    Args:
+        ctx (ctx): The current rule's context object.
+        toolchain (rust_toolchain): The current Rust toolchain.
+        crate_root (File): The root file of the crate.
+        crate_type (str): The crate type.
+
+    Returns:
+        List[str]: Extra rustc flags.
+    """
+    flags = []
+
+    if crate_type in toolchain.extra_rustc_flags_for_crate_types.keys():
+        flags.extend(toolchain.extra_rustc_flags_for_crate_types[crate_type])
+
+    is_exec = is_exec_configuration(ctx)
+
+    flags.extend(toolchain.extra_exec_rustc_flags if is_exec else toolchain.extra_rustc_flags)
+
+    if hasattr(ctx.attr, "_extra_rustc_flags") and not is_exec:
+        flags.extend(ctx.attr._extra_rustc_flags[ExtraRustcFlagsInfo].extra_rustc_flags)
+
+    if hasattr(ctx.attr, "_extra_rustc_flag") and not is_exec:
+        flags.extend(ctx.attr._extra_rustc_flag[ExtraRustcFlagsInfo].extra_rustc_flags)
+
+    if hasattr(ctx.attr, "_per_crate_rustc_flag") and not is_exec:
+        per_crate_rustc_flags = ctx.attr._per_crate_rustc_flag[PerCrateRustcFlagsInfo].per_crate_rustc_flags
+        flags.extend(_collect_per_crate_rustc_flags(ctx, crate_root, per_crate_rustc_flags))
+
+    if hasattr(ctx.attr, "_extra_exec_rustc_flags") and is_exec:
+        flags.extend(ctx.attr._extra_exec_rustc_flags[ExtraExecRustcFlagsInfo].extra_exec_rustc_flags)
+
+    if hasattr(ctx.attr, "_extra_exec_rustc_flag") and is_exec:
+        flags.extend(ctx.attr._extra_exec_rustc_flag[ExtraExecRustcFlagsInfo].extra_exec_rustc_flags)
+
+    return flags
+
 def rustc_compile_action(
         *,
         ctx,
@@ -1635,12 +1651,8 @@ def rustc_compile_action(
 
     return providers
 
-def _is_no_std(ctx, toolchain, crate_info):
-    if is_exec_configuration(ctx) or crate_info.is_test:
-        return False
-    if toolchain._no_std == "off":
-        return False
-    return True
+def is_no_std(ctx, toolchain, crate_is_test):
+    return not (is_exec_configuration(ctx) or crate_is_test or toolchain._no_std == "off")
 
 def _should_use_rustc_allocator_libraries(toolchain):
     use_or_default = toolchain._experimental_use_allocator_libraries_with_mangled_symbols
@@ -1675,7 +1687,7 @@ def _get_std_and_alloc_info(ctx, toolchain, crate_info):
             return libs.libstd_and_allocator_ccinfo
         return toolchain.libstd_and_allocator_ccinfo
     if toolchain._experimental_use_global_allocator:
-        if _is_no_std(ctx, toolchain, crate_info):
+        if is_no_std(ctx, toolchain, crate_info.is_test):
             if attr_global_allocator_library:
                 return libs.nostd_and_global_allocator_ccinfo
             return toolchain.nostd_and_global_allocator_ccinfo
@@ -2285,16 +2297,20 @@ def _get_dirname(file):
     """
     return file.dirname
 
-def _add_per_crate_rustc_flags(ctx, args, map_flag, crate_info, per_crate_rustc_flags):
-    """Adds matching per-crate rustc flags to `args`.
+def _collect_per_crate_rustc_flags(ctx, crate_root, per_crate_rustc_flags):
+    """Return all matching per-crate rustc flags.
 
     Args:
         ctx (ctx): The source rule's context object
-        args (Args): A reference to an Args object
-        map_flag (function): An optional function to use to map added flags
-        crate_info (CrateInfo): A CrateInfo provider
+        crate_root (File): The root file of the crate
         per_crate_rustc_flags (list): A list of per_crate_rustc_flag values
+
+    Returns:
+        List[str]: matching per-crate rustc flags
     """
+
+    flags = []
+
     for per_crate_rustc_flag in per_crate_rustc_flags:
         at_index = per_crate_rustc_flag.find("@")
         if at_index == -1:
@@ -2312,13 +2328,12 @@ def _add_per_crate_rustc_flags(ctx, args, map_flag, crate_info, per_crate_rustc_
             label = label_string[2:]
         else:
             label = label_string
-        execution_path = crate_info.root.path
+        execution_path = crate_root.path
 
         if label.startswith(prefix_filter) or execution_path.startswith(prefix_filter):
-            if map_flag:
-                flag = map_flag(flag)
-            if flag:
-                args.add(flag)
+            flags.append(flag)
+
+    return flags
 
 def _error_format_impl(ctx):
     """Implementation of the `error_format` rule

rust/settings/BUILD.bazel

@@ -9,6 +9,7 @@ load(
     "clippy_output_diagnostics",
     "clippy_toml",
     "codegen_units",
+    "collect_cfgs",
     "error_format",
     "experimental_link_std_dylib",
     "experimental_per_crate_rustc_flag",
@@ -70,6 +71,8 @@ clippy_toml()
 
 codegen_units()
 
+collect_cfgs()
+
 error_format()
 
 clippy_error_format()

rust/settings/settings.bzl

@@ -490,3 +490,12 @@ def codegen_units():
         name = "codegen_units",
         build_setting_default = -1,
     )
+
+# buildifier: disable=unnamed-macro
+def collect_cfgs():
+    """Enable collection of cfg flags with results stored in CrateInfo.cfgs.
+    """
+    bool_flag(
+        name = "collect_cfgs",
+        build_setting_default = False,
+    )

test/unit/collect_cfgs/BUILD.bazel

@@ -0,0 +1,5 @@
+load(":collect_cfgs_test.bzl", "collect_cfgs_test_suite")
+
+collect_cfgs_test_suite(
+    name = "collect_cfgs_test_suite",
+)