Do not use runfiles.collect_data (#3531)

Before this PR, Rust rules merge data_runfiles of dependencies into its
default_runfiles (because we used
`[collect_data=True](https://bazel.build/versions/7.1.0/rules/lib/builtins/ctx#runfiles)`).
`cc_libraries` put shared libraries to data_runfiles even when
`cc_library` has a static library equivalent and Bazel is linking
statically. This becomes problematic when packaging binaries - we end up
putting unnecessary shared libraries into the package.

Therefore, this PR removes the use of `collect_data`, and refactors our
runfiles logic to follow the [latest
guidance](https://bazel.build/versions/7.1.0/extending/rules#runfiles).
While at it, I made sure to only put transitive shared libraries to
runfiles when building a binary-like target (bin, staticlib, cdylib).
This way we avoid depset flattenning in libraries.

Added a little regression test.

Author: hlopko

rust/private/rustc.bzl

@@ -1503,23 +1503,33 @@ def rustc_compile_action(
 
     experimental_use_coverage_metadata_files = toolchain._experimental_use_coverage_metadata_files
 
-    dynamic_libraries = [
-        library_to_link.dynamic_library
-        for dep in getattr(ctx.attr, "deps", [])
-        if CcInfo in dep
-        for linker_input in dep[CcInfo].linking_context.linker_inputs.to_list()
-        for library_to_link in linker_input.libraries
-        if _is_dylib(library_to_link)
-    ]
     runfiles = ctx.runfiles(
         files = getattr(ctx.files, "data", []) +
-                ([] if experimental_use_coverage_metadata_files else coverage_runfiles) +
-                dynamic_libraries,
-        collect_data = True,
+                ([] if experimental_use_coverage_metadata_files else coverage_runfiles),
     )
-    if getattr(ctx.attr, "crate", None):
-        runfiles = runfiles.merge(ctx.attr.crate[DefaultInfo].default_runfiles)
-        runfiles = runfiles.merge(ctx.attr.crate[DefaultInfo].data_runfiles)
+    transitive_runfiles = []
+    crate_attr = getattr(ctx.attr, "crate", None)
+    for runfiles_attr in (
+        getattr(ctx.attr, "srcs", []),
+        getattr(ctx.attr, "deps", []),
+        getattr(ctx.attr, "data", []),
+        [crate_attr] if crate_attr else [],
+    ):
+        if not runfiles_attr:
+            continue
+        for target in runfiles_attr:
+            transitive_runfiles.append(target[DefaultInfo].default_runfiles)
+    if crate_info.type in ["bin", "cdylib", "staticlib"]:
+        dynamic_libraries = ctx.runfiles(files = [
+            library_to_link.dynamic_library
+            for dep in getattr(ctx.attr, "deps", [])
+            if CcInfo in dep
+            for linker_input in dep[CcInfo].linking_context.linker_inputs.to_list()
+            for library_to_link in linker_input.libraries
+            if _is_dylib(library_to_link)
+        ])
+        transitive_runfiles.append(dynamic_libraries)
+    runfiles = runfiles.merge_all(transitive_runfiles)
 
     # TODO: Remove after some resolution to
     # https://github.com/bazelbuild/rules_rust/issues/771

test/unit/check_runfiles/check_runfiles_test.bzl

@@ -2,6 +2,7 @@
 
 load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
 load("@rules_cc//cc:cc_binary.bzl", "cc_binary")
+load("@rules_cc//cc:cc_library.bzl", "cc_library")
 load(
     "//rust:defs.bzl",
     "rust_binary",
@@ -17,6 +18,11 @@ def _check_runfiles_test_impl(ctx):
 
     asserts.true(env, _is_in_runfiles("libbar.so", runfiles))
 
+    # cc_libraries put shared libs to data runfiles even when linking statically
+    # and there is a static library alternative. We must be careful not to put
+    # these shared libs to default runfiles.
+    asserts.false(env, _is_in_runfiles("libtest_Sunit_Scheck_Urunfiles_Slibcc_Ulib.so", runfiles))
+
     return analysistest.end(env)
 
 def _is_in_runfiles(name, runfiles):
@@ -28,11 +34,15 @@ def _is_in_runfiles(name, runfiles):
 check_runfiles_test = analysistest.make(_check_runfiles_test_impl)
 
 def _check_runfiles_test():
+    cc_library(
+        name = "cc_lib",
+        srcs = ["bar.cc"],
+    )
     rust_library(
         name = "foo_lib",
         srcs = ["foo.rs"],
         edition = "2018",
-        deps = [":libbar.so"],
+        deps = [":libbar.so", ":cc_lib"],
     )
 
     rust_binary(