Traverse CrateGroupInfo when gathering CcInfo linking_context entries for use_cc_common_link

Certain code written before crate groups were introduced wasn't adjusted to traverse
groups, specifically code that traverses crate deps to discover cc_info. collect_deps
properly does flatten crate_groups, so this moves the code for flattening a list of
DepVariantInfo into a utility function, 'flatten_crate_groups'.

This fixes rust_library_group and rust_prost_library for experimental_use_cc_common_link.

Author: ObsidianMinor

rust/private/rustc.bzl

@@ -218,6 +218,17 @@ def _should_use_pic(cc_toolchain, feature_configuration, crate_type, compilation
 def _is_proc_macro(crate_info):
     return "proc-macro" in (crate_info.type, crate_info.wrapped_crate_type)
 
+def flatten_crate_groups(deps):
+    """Given a list of DepVariantInfo (like crate_info.deps), flatten any crate_group_info into the rest of the list"""
+    crate_deps = []
+    for dep in deps:
+        crate_group = getattr(dep, "crate_group_info", None)
+        if crate_group:
+            crate_deps.extend(crate_group.dep_variant_infos.to_list())
+        else:
+            crate_deps.append(dep)
+    return crate_deps
+
 def collect_deps(
         deps,
         proc_macro_deps,
@@ -260,13 +271,7 @@ def collect_deps(
     direct_metadata_outputs = []
     transitive_metadata_outputs = []
 
-    crate_deps = []
-    for dep in deps + proc_macro_deps:
-        crate_group = getattr(dep, "crate_group_info", None)
-        if crate_group:
-            crate_deps.extend(crate_group.dep_variant_infos.to_list())
-        else:
-            crate_deps.append(dep)
+    crate_deps = flatten_crate_groups(deps + proc_macro_deps)
 
     aliases = {k.label: v for k, v in aliases.items()}
     for dep in crate_deps:
@@ -1580,9 +1585,11 @@ def rustc_compile_action(
             toolchain.stdlib_linkflags.linking_context,
         ]
 
-        for dep in crate_info.deps.to_list():
-            if dep.cc_info:
-                linking_contexts.append(dep.cc_info.linking_context)
+        linking_contexts += [
+            dep.cc_info.linking_context
+            for dep in flatten_crate_groups(crate_info.deps.to_list())
+            if dep.cc_info
+        ]
 
         # In the cc_common.link action we need to pass the name of the final
         # binary (output) relative to the package of this target.
@@ -1958,7 +1965,7 @@ def establish_cc_info(ctx, attr, crate_info, toolchain, cc_toolchain, feature_co
     ]
 
     # Flattening is okay since crate_info.deps only records direct deps.
-    for dep in crate_info.deps.to_list():
+    for dep in flatten_crate_groups(crate_info.deps.to_list()):
         if dep.cc_info:
             # A Rust staticlib or shared library doesn't need to propagate linker inputs
             # of its dependencies, except for shared libraries.

test/integration/cc_common_link/BUILD.bazel

@@ -4,6 +4,7 @@ load(
     "rust_binary",
     "rust_library",
     "rust_shared_library",
+    "rust_library_group",
     "rust_test",
 )
 
@@ -12,6 +13,35 @@ cc_library(
     linkstamp = "cclinkstampdep.cc",
 )
 
+rust_library(
+    name = "deep_dep",
+    srcs = ["deep_dep.rs"],
+    edition = "2021",
+)
+
+rust_library_group(
+    name = "dep_group",
+    deps = [":deep_dep"],
+)
+
+rust_library(
+    name = "very_nested_dep",
+    srcs = ["very_nested_dep.rs"],
+    edition = "2021",
+)
+
+rust_library_group(
+    name = "nested_dep_group",
+    deps = [":very_nested_dep"],
+)
+
+rust_library(
+    name = "nesting_dep",
+    srcs = ["nesting_dep.rs"],
+    deps = [":nested_dep_group"],
+    edition = "2021",
+)
+
 rust_library(
     name = "rdep",
     srcs = ["rdep.rs"],
@@ -25,6 +55,8 @@ rust_binary(
     deps = [
         ":cclinkstampdep",
         ":rdep",
+        ":dep_group",
+        ":nesting_dep",
     ],
 )
 

test/integration/cc_common_link/bin.rs

@@ -6,5 +6,7 @@ extern "C" {
 
 fn main() {
     println!("bin rdep: {}", rdep::rdep());
+    println!("bin deep_dep: {}", deep_dep::deep_dep());
+    println!("bin nesting_dep: {}", nesting_dep::nesting_dep());
     println!("cclinkstampdep: {}", unsafe { cclinkstampdep() });
 }

test/integration/cc_common_link/deep_dep.rs

@@ -0,0 +1,3 @@
+pub fn deep_dep() -> i32 {
+    0xcf
+}

test/integration/cc_common_link/nesting_dep.rs

@@ -0,0 +1,3 @@
+pub fn nesting_dep() -> i32 {
+    very_nested_dep::very_nested_dep()
+}

test/integration/cc_common_link/very_nested_dep.rs

@@ -0,0 +1,3 @@
+pub fn very_nested_dep() -> i32 {
+    0xaf
+}