improve language injections (nushell#211)

- refactor: simplify queries and reformat
- allow additional formatting with `@string.code`

Author: Bahex

queries/nu/highlights.scm

@@ -276,26 +276,32 @@ key: (identifier) @property
 (parameter
   (comment) @comment.documentation @spell)
 
-((command
-    head: ((cmd_identifier) @_cmd (#any-of? @_cmd
-        "find"
-        "parse"
-        "split"
-        "str"
-        " find"
-        " parse"
-        " split"
-        " str"
-    ))
-    flag: [
-        (short_flag name: (_) @_sflag (#eq? @_sflag "r"))
-        (long_flag name: (_) @_lflag (#eq? @_lflag "regex"))
-    ]
-    .
-    arg: (_ (string_content) @string.regexp)
-))
-
-((_
-    opr: ["=~" "!~" "like" "not-like"]
-    rhs: (_ (string_content) @string.regexp)
-))
+(command
+  head: ((cmd_identifier) @_cmd
+    (#match? @_cmd "^\\s*(find|parse|split|str)$"))
+  flag: (_
+    name: (_) @_flag
+    (#any-of? @_flag "r" "regex"))
+  .
+  arg: (_
+    (string_content) @string.regexp))
+
+(_
+  opr: [
+    "=~"
+    "!~"
+    "like"
+    "not-like"
+  ]
+  rhs: (_
+    (string_content) @string.regexp))
+
+(command
+  head: ((_) @_cmd
+    (#any-of? @_cmd "nu" "$nu.current-exe"))
+  flag: (_
+    name: (_) @_flag
+    (#any-of? @_flag "c" "e" "commands" "execute"))
+  .
+  arg: (_
+    (string_content) @string.code))

queries/nu/injections.scm

@@ -1,39 +1,35 @@
 ((comment) @injection.content
- (#set! injection.language "comment"))
+  (#set! injection.language "comment"))
 
-((command
- head: ((cmd_identifier) @_cmd (#any-of? @_cmd
-  "find"
-  "parse"
-  "split"
-  "str"
-  " find"
-  " parse"
-  " split"
-  " str"
- ))
- flag: [
-  (short_flag name: (_) @_sflag (#eq? @_sflag "r"))
-  (long_flag name: (_) @_lflag (#eq? @_lflag "regex"))
- ]
- .
- arg: (_ (string_content) @injection.content)
- (#set! injection.language "regex")
-))
+(command
+  head: ((cmd_identifier) @_cmd
+    (#match? @_cmd "^\\s*(find|parse|split|str)$"))
+  flag: (_
+    name: (_) @_flag
+    (#any-of? @_flag "r" "regex"))
+  .
+  arg: (_
+    (string_content) @injection.content
+    (#set! injection.language "regex")))
 
-((_
- opr: ["=~" "!~" "like" "not-like"]
- rhs: (_ (string_content) @injection.content)
- (#set! injection.language "regex")
-))
+(_
+  opr: [
+    "=~"
+    "!~"
+    "like"
+    "not-like"
+  ]
+  rhs: (_
+    (string_content) @injection.content
+    (#set! injection.language "regex")))
 
-((command
- head: (_) @_cmd (#any-of? @_cmd "nu" "$nu.current-exe")
- flag: [
-  (short_flag name: (_) @_sflag (#any-of? @_sflag "c" "e"))
-  (long_flag name: (_) @_lflag (#any-of? @_lflag "commands" "execute"))
- ]
- .
- arg: (_ (string_content) @injection.content)
- (#set! injection.language "nu")
-))
+(command
+  head: (_) @_cmd
+  (#any-of? @_cmd "nu" "$nu.current-exe")
+  flag: (_
+    name: (_) @_flag
+    (#any-of? @_flag "c" "e" "commands" "execute"))
+  .
+  arg: (_
+    (string_content) @injection.content
+    (#set! injection.language "nu")))