Improve POST parameters processing

Use enum to ensure unique identification of each HTTP POST parameter key and consistence across functions. Each web page is also identified using enum.

Author: budulinek

arduino-modbus-rtu-tcp-gateway/04-webserver.ino

@@ -16,24 +16,67 @@
 
    ***************************************************************** */
 
-
-const byte pagesCnt = 5;                   // number of consecutive pages ("1.htm", "2.htm"....) served by the server, maximum is 9
 const byte webInBufferSize = 128;      // size of web server read buffer (reads a complete line), 128 bytes necessary for POST data
 const byte smallbuffersize = 32;       // a smaller buffer for uri
 
 // Actions that need to be taken after saving configuration.
-// Order of these actions must correspond to POST param values of buttons on the "Tools" web page (e.g. "value=1" for Restore factory defaults, etc.)
+// These actions are also used by buttons on the Tools page.
 enum action_type : byte
 {
-  NONE, FACTORY, MAC, REBOOT, ETH_SOFT, SERIAL_SOFT, SCAN, WEB
+  NONE,
+  FACTORY,          // Restore factory settings (but keep MAC address)
+  MAC,              // Generate new random MAC
+  REBOOT,           // Reboot the microcontroller
+  ETH_SOFT,         // Ethernet software reset
+  SERIAL_SOFT,      // Serial software reset
+  SCAN,             // Initialize RS485 scan
+  WEB               // Restart webserver
 };
 enum action_type action;
 
+// Pages served by the webserver. Order of elements defines the order in the left menu of the web UI.
+// URL of the page (*.htm) contains number corresponding to its position in this array.
+// The following enum array can have a maximum of 10 elements (incl. PAGE_NONE and PAGE_WAIT)
+enum page : byte
+{
+  PAGE_NONE,            // reserved for NULL
+  PAGE_STATUS,
+  PAGE_IP,
+  PAGE_TCP,
+  PAGE_RTU,
+  PAGE_TOOLS,
+  PAGE_WAIT            // page with "Reloading. Please wait..." message. Must be the last element within this enum!!
+};
+
+// Keys for POST parameters, used in web forms and processed by processPost() function.
+// Using enum ensures unique identification of each POST parameter key and consistence across functions.
+// In HTML code, each element will apear as number corresponding to its position in this array.
+enum post_key : byte
+{
+  POST_NONE,                                                    // reserved for NULL
+  POST_DHCP,                                                    // enable DHCP
+  POST_IP, POST_IP_1, POST_IP_2, POST_IP_3,                     // IP address         || Each part of an IP address has its own POST parameter.     ||
+  POST_SUBNET, POST_SUBNET_1, POST_SUBNET_2, POST_SUBNET_3,     // subnet             || Because HTML code for IP, subnet, gateway and DNS          ||
+  POST_GATEWAY, POST_GATEWAY_1, POST_GATEWAY_2, POST_GATEWAY_3, // gateway            || is generated through one (nested) for-loop,                ||
+  POST_DNS, POST_DNS_1, POST_DNS_2, POST_DNS_3,                 // DNS                || all these 16 enum elements must be listed in succession!!  ||
+  POST_TCP,            // TCP port                  || Because HTML code for these 3 ports              ||
+  POST_UDP,            // UDP port                  || is generated through one for-loop,               ||
+  POST_WEB,            // web UI port               || these 3 elements must be listed in succession!!  ||
+  POST_RTU_OVER,       // RTU over TCP/UDP
+  POST_BAUD,           // baud rate
+  POST_DATA,           // data bits
+  POST_PARITY,         // parity
+  POST_STOP,           // stop bits
+  POST_TIMEOUT,        // response timeout
+  POST_RETRY,          // retry attempts
+  POST_ACTION          // actions on Tools page
+};
+
 void recvWeb()
 {
   EthernetClient client = webServer.available();
   if (client) {
-    dbg(F("[web] Data from client "));
+    dbg(F("[web in] Data from client "));
 
     char uri[smallbuffersize];                   // the requested page
     // char requestParameter[smallbuffersize];      // parameter appended to the URI after a ?
@@ -54,13 +97,13 @@ void recvWeb()
         {
           if (status == REQUEST)         // read the first line
           {
-            dbg(F("[web] webInBuffer=")); dbgln(webInBuffer);
+            dbg(F("[web in] webInBuffer=")); dbgln(webInBuffer);
             // now split the input
             char *ptr;
             ptr = strtok(webInBuffer, " ");       // strtok willdestroy the newRequest
             ptr = strtok(NULL, " ");
             strlcpy(uri, ptr, sizeof(uri));  // enthält noch evtl. parameter
-            dbg(F("[web] uri=")); dbgln(uri);
+            dbg(F("[web in] uri=")); dbgln(uri);
             status = EMPTY_LINE;                   // jump to next status
           }
           else if (status > REQUEST && i < 2)      // check if we have an empty line
@@ -92,24 +135,35 @@ void recvWeb()
       }
       if (status == BODY)      // status 3 could end without linefeed, therefore we takeover here also
       {
-        dbg(F("[web] POST data=")); dbgln(webInBuffer);
+        dbg(F("[web in] POST data=")); dbgln(webInBuffer);
         if (webInBuffer[0] != '\0') {
           processPost(webInBuffer);
         }
       }
     }
 
-    // send back a response
-    // Get number of the requested page
+    // Get number of the requested page from URI
     byte reqPage = 0;      //requested page
-    if ((uri[0] == '/') && !strcmp(uri + 2, ".htm")) {
-      reqPage = uri[1] - 48;                // Convert ASCII to byte
+    if (!strcmp(uri, "/"))        // the homepage Current Status
+      reqPage = PAGE_STATUS;
+    else if ((uri[0] == '/') && !strcmp(uri + 2, ".htm")) {
+      reqPage = (byte)(uri[1] - 48);                // Convert single ASCII char to byte
     }
-
     // Actions that require "please wait" page
     if (action == WEB || action == REBOOT || action == ETH_SOFT || action == FACTORY || action == MAC) {
-      sendPage(client, 0xFF);                                 // Send "please wait" page
-      // Do all actions before the "please wait" redirects (5s delay at the moment)
+      reqPage = PAGE_WAIT;
+    }
+
+    // Send page
+    if ((reqPage > 0) && (reqPage <= PAGE_WAIT))
+      sendPage(client, reqPage);
+    else if (!strcmp(uri, "/favicon.ico"))     // a favicon
+      send204(client);                         // if you don't have a favicon, send 204
+    else                                       // if the page is unknown, HTTP response code 404
+      send404(client);                         // defaults to 404 error
+
+    // Do all actions before the "please wait" redirects (5s delay at the moment)
+    if (reqPage == PAGE_WAIT) {
       for (byte n = 0; n < maxSockNum; n++) {
         // in case of webserver restart, stop only clients from old webserver (clients with port different from current settings)
         EthernetClient clientTemp = EthernetClient(n);
@@ -119,7 +173,6 @@ void recvWeb()
           clientTemp.stop();
         }
       }
-
       switch (action) {
         case WEB:
           webServer = EthernetServer(localConfig.webPort);
@@ -136,20 +189,10 @@ void recvWeb()
           break;
       }
     }
-    else if (!strcmp(uri, "/") || !strcmp(uri, "/index.htm"))        // the homepage Current Status
-      sendPage(client, 1);
-    else if ((reqPage > 0) && (reqPage <= pagesCnt))
-      sendPage(client, reqPage);
-    else if (!strcmp(uri, "/favicon.ico"))     // a favicon
-      send204(client);                         // if you don't have a favicon, send 204
-    else                                       // if the page is unknown, HTTP response code 404
-      send404(client);
     action = NONE;
-    dbg(F("[web] Stop client "));
   }
 }
 
-
 // This function stores POST parameter values in localConfig.
 // Most changes are saved and applied immediatelly, some changes (IP settings, web server port, actions in "Tools" page) are saved but applied later after "please wait" page is sent.
 void processPost(char postParameter[]) {
@@ -161,134 +204,108 @@ void processPost(char postParameter[]) {
     char *paramValue;
     char *sav2 = NULL;            // for inner strtok_r
     paramKey = strtok_r(point, "=", &sav2);   // inner strtok_r, use sav2
+    paramValue = strtok_r(NULL, "=", &sav2);
+    if (!paramValue) continue;
+    byte paramKeyByte = atoi(paramKey);
+    unsigned long paramValueUlong = atol(paramValue);
 
-    switch (paramKey[0]) {
-      case 'i':                               // processing IP Settings
-        {
-          paramValue = strtok_r(NULL, "=", &sav2);
-          int paramValueInt = atoi(paramValue);
-          if (paramValue && (paramValueInt >= 0 && paramValueInt <= 255)) {
-            byte j = atoi(paramKey + 1);
-            if (j <= 0);           // do nothing
-            else if (j == 1) {       // Enable DHCP
-              if ((byte)paramValueInt != localConfig.enableDhcp) {
-                action = ETH_SOFT;
-                localConfig.enableDhcp = (byte)paramValueInt;
-              }
-            } else if (j <= 5) {      // IP
-              if ((byte)paramValueInt != localConfig.ip[j - 2]) {
-                action = ETH_SOFT;
-                localConfig.ip[j - 2] = (byte)paramValueInt;
-              }
-            } else if (j <= 9) {      // Subnet
-              if ((byte)paramValueInt != localConfig.subnet[j - 6]) {
-                action = ETH_SOFT;
-                localConfig.subnet[j - 6] = (byte)paramValueInt;
-              }
-            } else if (j <= 13) {      // Gateway
-              if ((byte)paramValueInt != localConfig.gateway[j - 10]) {
-                action = ETH_SOFT;
-                localConfig.gateway[j - 10] = (byte)paramValueInt;
-              }
-            } else if (j <= 17) {      // DNS
-              if ((byte)paramValueInt != localConfig.dns[j - 14]) {
-                action = ETH_SOFT;
-                localConfig.dns[j - 14] = (byte)paramValueInt;
-              }
-            }
-          }
-          break;
+    switch (paramKeyByte) {
+      case POST_NONE:                     // reserved, because atoi / atol returns NULL in case of error
+        break;
+      case POST_DHCP:
+        if ((byte)paramValueUlong != localConfig.enableDhcp) {
+          action = ETH_SOFT;
+          localConfig.enableDhcp = (byte)paramValueUlong;
         }
-      case 't':                               // processing TCP/UDP Settings
-        {
-          paramValue = strtok_r(NULL, "=", &sav2);
-          unsigned int paramValueUint = atoi(paramValue);
-          if (paramValue) {
-            switch (atoi(paramKey + 1)) {
-              case 1:             // TCP port
-                if (localConfig.tcpPort != paramValueUint) {
-                  for (byte i = 0; i < maxSockNum; i++) {
-                    EthernetClient clientTemp = EthernetClient(i);
-                    if (clientTemp.status() != SnSR::UDP && clientTemp.localPort() == localConfig.tcpPort) {
-                      clientTemp.flush();
-                      clientTemp.stop();
-                    }
-                  }
-                  localConfig.tcpPort = paramValueUint;
-                  modbusServer = EthernetServer(localConfig.tcpPort);
-                }
-                break;
-              case 2:             // UDP Port
-                if (localConfig.udpPort != paramValueUint) {
-                  localConfig.udpPort = paramValueUint;
-                  Udp.stop();
-                  Udp.begin(localConfig.udpPort);
-                }
-                break;
-              case 3:             // Web Port
-                if (localConfig.webPort != paramValueUint) {
-                  localConfig.webPort = paramValueUint;
-                  action = WEB;
-                }
-                break;
-              case 4:             // Enable Modbus RTU over TCP/UDP
-                localConfig.enableRtuOverTcp = (byte)paramValueUint;
-                break;
-              default:
-                break;
-            }
-          }
-          break;
+        break;
+      case POST_IP ... POST_IP_3:
+        if ((byte)paramValueUlong != localConfig.ip[paramKeyByte - POST_IP]) {
+          action = ETH_SOFT;
+          localConfig.ip[paramKeyByte - POST_IP] = (byte)paramValueUlong;
         }
-      case 'r':                               // processing RS485 Settings
-        {
-          paramValue = strtok_r(NULL, "=", &sav2);
-          unsigned long paramValueUlong = atol(paramValue);
-          if (paramValue) {
-            switch (atoi(paramKey + 1)) {
-              case 1:             // Baud
-                if (localConfig.baud != paramValueUlong) {
-                  action = SERIAL_SOFT;
-                  localConfig.baud = paramValueUlong;
-                }
-                break;
-              case 2:             // Data Size
-                if ((((localConfig.serialConfig & 0x06) >> 1) + 5) != atoi(paramValue)) {
-                  action = SERIAL_SOFT;
-                  localConfig.serialConfig = (localConfig.serialConfig & 0xF9) | ((atoi(paramValue) - 5) << 1);
-                }
-                break;
-              case 3:             // Parity
-                if (((localConfig.serialConfig & 0x30) >> 4) != atoi(paramValue)) {
-                  action = SERIAL_SOFT;
-                  localConfig.serialConfig = (localConfig.serialConfig & 0xCF) | (atoi(paramValue) << 4);
-                }
-                break;
-              case 4:             // Stop Bits
-                if ((((localConfig.serialConfig & 0x08) >> 3) + 1) != atoi(paramValue)) {
-                  action = SERIAL_SOFT;
-                  localConfig.serialConfig = (localConfig.serialConfig & 0xF7) | ((atoi(paramValue) - 1) << 3);
-                }
-                break;
-              case 5:             // Modbus timeout
-                localConfig.serialTimeout = paramValueUlong;
-                break;
-              case 6:             // Modbus retry
-                localConfig.serialRetry = (byte)paramValueUlong;
-                break;
-              default:
-                break;
+        break;
+      case POST_SUBNET ... POST_SUBNET_3:
+        if ((byte)paramValueUlong != localConfig.subnet[paramKeyByte - POST_SUBNET]) {
+          action = ETH_SOFT;
+          localConfig.subnet[paramKeyByte - POST_SUBNET] = (byte)paramValueUlong;
+        }
+        break;
+      case POST_GATEWAY ... POST_GATEWAY_3:
+        if ((byte)paramValueUlong != localConfig.gateway[paramKeyByte - POST_GATEWAY]) {
+          action = ETH_SOFT;
+          localConfig.gateway[paramKeyByte - POST_GATEWAY] = (byte)paramValueUlong;
+        }
+        break;
+      case POST_DNS ... POST_DNS_3:
+        if ((byte)paramValueUlong != localConfig.dns[paramKeyByte - POST_DNS]) {
+          action = ETH_SOFT;
+          localConfig.dns[paramKeyByte - POST_DNS] = (byte)paramValueUlong;
+        }
+        break;
+      case POST_TCP:
+        if (localConfig.tcpPort != (unsigned int)paramValueUlong) {
+          for (byte i = 0; i < maxSockNum; i++) {
+            EthernetClient clientTemp = EthernetClient(i);
+            if (clientTemp.status() != SnSR::UDP && clientTemp.localPort() == localConfig.tcpPort) {
+              clientTemp.flush();
+              clientTemp.stop();
             }
           }
-          break;
+          localConfig.tcpPort = (unsigned int)paramValueUlong;
+          modbusServer = EthernetServer(localConfig.tcpPort);
         }
-      case 'a':                               // processing Tools buttons
-        {
-          action = (action_type)atoi(strtok_r(NULL, "=", &sav2));
-          break;
-        default:
-          break;
+        break;
+      case POST_UDP:
+        if (localConfig.udpPort != (unsigned int)paramValueUlong) {
+          localConfig.udpPort = (unsigned int)paramValueUlong;
+          Udp.stop();
+          Udp.begin(localConfig.udpPort);
+        }
+        break;
+      case POST_WEB:
+        if (localConfig.webPort != (unsigned int)paramValueUlong) {
+          localConfig.webPort = (unsigned int)paramValueUlong;
+          action = WEB;
+        }
+        break;
+      case POST_RTU_OVER:
+        localConfig.enableRtuOverTcp = (byte)paramValueUlong;
+        break;
+      case POST_BAUD:
+        if (localConfig.baud != paramValueUlong) {
+          action = SERIAL_SOFT;
+          localConfig.baud = paramValueUlong;
+        }
+        break;
+      case  POST_DATA:
+        if ((((localConfig.serialConfig & 0x06) >> 1) + 5) != (byte)paramValueUlong) {
+          action = SERIAL_SOFT;
+          localConfig.serialConfig = (localConfig.serialConfig & 0xF9) | (((byte)paramValueUlong - 5) << 1);
+        }
+        break;
+      case  POST_PARITY:
+        if (((localConfig.serialConfig & 0x30) >> 4) != (byte)paramValueUlong) {
+          action = SERIAL_SOFT;
+          localConfig.serialConfig = (localConfig.serialConfig & 0xCF) | ((byte)paramValueUlong << 4);
         }
+        break;
+      case  POST_STOP:
+        if ((((localConfig.serialConfig & 0x08) >> 3) + 1) != (byte)paramValueUlong) {
+          action = SERIAL_SOFT;
+          localConfig.serialConfig = (localConfig.serialConfig & 0xF7) | (((byte)paramValueUlong - 1) << 3);
+        }
+        break;
+      case  POST_TIMEOUT:
+        localConfig.serialTimeout = paramValueUlong;
+        break;
+      case  POST_RETRY:
+        localConfig.serialRetry = (byte)paramValueUlong;
+        break;
+      case  POST_ACTION:
+        action = (action_type)paramValueUlong;
+        break;
+      default:
+        break;
     }
     point = strtok_r(NULL, "&", &sav1);
   }     // while (point != NULL)