|
| 1 | +/* |
| 2 | + * Copyright (C) 2019 Intel Corporation. All rights reserved. |
| 3 | + * SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception |
| 4 | + */ |
| 5 | + .text |
| 6 | + .align 2 |
| 7 | +#ifndef BH_PLATFORM_DARWIN |
| 8 | + .globl invokeNative |
| 9 | + .type invokeNative, function |
| 10 | +invokeNative: |
| 11 | +#else |
| 12 | + .globl _invokeNative |
| 13 | +_invokeNative: |
| 14 | +#endif /* end of BH_PLATFORM_DARWIN */ |
| 15 | + |
| 16 | + |
| 17 | +/* |
| 18 | + * Arguments passed in: |
| 19 | + * |
| 20 | + * a0 function ptr |
| 21 | + * a1 argv |
| 22 | + * a2 nstacks |
| 23 | + */ |
| 24 | + |
| 25 | +/* |
| 26 | + * sp (stack pointer) |
| 27 | + * |- sw to store 32-bit values from register to memory |
| 28 | + * |- lw to load from stack to register |
| 29 | + * fp/s0 (frame pointer) |
| 30 | + * a0-a7 (8 integer arguments) |
| 31 | + * |- sw to store |
| 32 | + * |- lw to load |
| 33 | + * t0-t6 (temporaries regisgers) |
| 34 | + * |- caller saved |
| 35 | + */ |
| 36 | + |
| 37 | + /* reserve space on stack to save return address and frame pointer */ |
| 38 | + addi sp, sp, -8 |
| 39 | + sw fp, 0(sp) /* save frame pointer */ |
| 40 | + sw ra, 4(sp) /* save return address */ |
| 41 | + |
| 42 | + mv fp, sp /* set frame pointer to bottom of fixed frame */ |
| 43 | + |
| 44 | + /* save function ptr, argv & nstacks */ |
| 45 | + mv t0, a0 /* t0 = function ptr */ |
| 46 | + mv t1, a1 /* t1 = argv array address */ |
| 47 | + mv t2, a2 /* t2 = nstack */ |
| 48 | + |
| 49 | + /* fill in a0-7 integer-registers */ |
| 50 | + lw a0, 0(t1) /* a0 = argv[0] */ |
| 51 | + lw a1, 4(t1) /* a1 = argv[1] */ |
| 52 | + lw a2, 8(t1) /* a2 = argv[2] */ |
| 53 | + lw a3, 12(t1) /* a3 = argv[3] */ |
| 54 | + lw a4, 16(t1) /* a4 = argv[4] */ |
| 55 | + lw a5, 20(t1) /* a5 = argv[5] */ |
| 56 | + lw a6, 24(t1) /* a6 = argv[6] */ |
| 57 | + lw a7, 28(t1) /* a7 = argv[7] */ |
| 58 | + |
| 59 | + /* fill in fa0-7 float-registers*/ |
| 60 | + fld fa0, 32(t1) /* fa0 = argv[8] */ |
| 61 | + fld fa1, 40(t1) /* fa1 = argv[9] */ |
| 62 | + fld fa2, 48(t1) /* fa2 = argv[10] */ |
| 63 | + fld fa3, 56(t1) /* fa3 = argv[11] */ |
| 64 | + fld fa4, 64(t1) /* fa4 = argv[12] */ |
| 65 | + fld fa5, 72(t1) /* fa5 = argv[13] */ |
| 66 | + fld fa6, 80(t1) /* fa6 = argv[14] */ |
| 67 | + fld fa7, 88(t1) /* fa7 = argv[15] */ |
| 68 | + |
| 69 | + addi t1, t1, 96 /* t1 points to stack args */ |
| 70 | + |
| 71 | + /* directly call the function if no args in stack, |
| 72 | + x0 always holds 0 */ |
| 73 | + beq t2, x0, call_func |
| 74 | + |
| 75 | + /* reserve enough stack space for function arguments */ |
| 76 | + sll t3, t2, 2 /* shift left 2 bits. t3 = n_stacks * 4 */ |
| 77 | + sub sp, sp, t3 |
| 78 | + |
| 79 | + /* make 16-byte aligned */ |
| 80 | + and sp, sp, ~15 |
| 81 | + |
| 82 | + /* save sp in t4 register */ |
| 83 | + mv t4, sp |
| 84 | + |
| 85 | + /* copy left arguments from caller stack to own frame stack */ |
| 86 | +loop_stack_args: |
| 87 | + beq t2, x0, call_func |
| 88 | + lw t5, 0(t1) /* load stack argument, t5 = argv[i] */ |
| 89 | + sw t5, 0(t4) /* store t5 to reseved stack, sp[j] = t5 */ |
| 90 | + addi t1, t1, 4 /* move to next stack argument */ |
| 91 | + addi t4, t4, 4 /* move to next stack pointer */ |
| 92 | + addi t2, t2, -1 /* decrease t2 every loop, nstacks = nstacks -1 */ |
| 93 | + j loop_stack_args |
| 94 | + |
| 95 | +call_func: |
| 96 | + jalr t0 |
| 97 | + |
| 98 | + /* restore registers pushed in stack or saved in another register */ |
| 99 | +return: |
| 100 | + mv sp, fp /* restore sp saved in fp before function call */ |
| 101 | + lw fp, 0(sp) /* load previous frame poniter to fp register */ |
| 102 | + lw ra, 4(sp) /* load previous return address to ra register */ |
| 103 | + addi sp, sp, 8 /* pop frame, restore sp */ |
| 104 | + jr ra |
0 commit comments