image: add tests

Author: delan

lib/data/image.ex

@@ -59,17 +59,18 @@ defmodule Memorable.Data.Image.DerivedMetadata do
     with {:read_file, {:ok, data}} <- {:read_file, File.read(path)},
          {:read_metadata, {:ok, metadata}} <-
            {:read_metadata, Image.read_metadata(image)} do
-      %__MODULE__{
-        image_id: image_id,
-        file_hash: :crypto.hash(:sha256, data),
-        original_datetime: original_datetime(metadata),
-        lens_model: Map.get(metadata, "LensID"),
-        body_model: Map.get(metadata, "Model"),
-        focal_length: focal_length(metadata),
-        aperture: Map.get(metadata, "Aperture"),
-        exposure_time: Map.get(metadata, "ExposureTime"),
-        iso: Map.get(metadata, "ISO")
-      }
+      {:ok,
+       %__MODULE__{
+         image_id: image_id,
+         file_hash: :crypto.hash(:sha256, data),
+         original_datetime: original_datetime(metadata),
+         lens_model: Map.get(metadata, "LensID"),
+         body_model: Map.get(metadata, "Model"),
+         focal_length: focal_length(metadata),
+         aperture: Map.get(metadata, "Aperture"),
+         exposure_time: Map.get(metadata, "ExposureTime"),
+         iso: Map.get(metadata, "ISO")
+       }}
     else
       {:read_file, error} -> {:error, {:read_file, error}}
       {:read_metadata, error} -> {:error, {:read_metadata, error}}

test/data/image_test.exs

@@ -0,0 +1,53 @@
+defmodule Memorable.Data.ImageTest do
+  use ExUnit.Case
+  alias Memorable.Data.Image
+  alias Memorable.Data.Image.DerivedMetadata
+  doctest Memorable.Data.Image
+
+  setup_all do
+    on_exit(fn ->
+      Memento.Table.clear(Image)
+    end)
+
+    # `Command` in rust needs to call waitpid(2), which fails with ECHILD when the signal handler
+    # for SIGCHLD is set to SIG_IGN, as is done in the erlang vm.
+    # <https://github.com/rusterlium/rustler/issues/446>
+    # <http://erlang.org/pipermail/erlang-questions/2020-November/100109.html>
+    :os.set_signal(:sigchld, :default)
+
+    [
+      image: %Image{
+        id: 1,
+        collection_id: nil,
+        path: "test/data/20250317_0_0028_01.jpg",
+        imported_datetime: DateTime.utc_now()
+      }
+    ]
+  end
+
+  describe "Image.read_metadata/1" do
+    test "dumps exif data for the given image", %{image: image} do
+      {:ok, metadata} = Image.read_metadata(image)
+      assert Map.get(metadata, "DateTimeOriginal") == "2025-03-17T18:38:23"
+      assert Map.get(metadata, "Model") == "Canon EOS 1000D"
+      assert Map.get(metadata, "LensID") == "Canon EF-S 55-250mm f/4-5.6 IS STM"
+      assert Map.get(metadata, "FocalLength") == "250.0 mm"
+      assert Map.get(metadata, "Aperture") == 5.6
+      assert Map.get(metadata, "ExposureTime") == "1/1250"
+      assert Map.get(metadata, "ISO") == 100
+    end
+  end
+
+  describe "DerivedMetadata.from_image/1" do
+    test "parses exif data for the given image", %{image: image} do
+      {:ok, metadata} = DerivedMetadata.from_image(image) |> IO.inspect()
+      assert Map.get(metadata, :original_datetime) == ~N[2025-03-17 18:38:23]
+      assert Map.get(metadata, :body_model) == "Canon EOS 1000D"
+      assert Map.get(metadata, :lens_model) == "Canon EF-S 55-250mm f/4-5.6 IS STM"
+      assert Map.get(metadata, :focal_length) == 250.0
+      assert Map.get(metadata, :aperture) == 5.6
+      assert Map.get(metadata, :exposure_time) == "1/1250"
+      assert Map.get(metadata, :iso) == 100
+    end
+  end
+end