feat: cloudflare provider

Author: cgarvis

lib/models.ex

@@ -1,6 +1,7 @@
 defmodule HyperLLM.Models do
   @providers %{
     "anthropic" => HyperLLM.Provider.Anthropic,
+    "cloudflare" => HyperLLM.Provider.Cloudflare,
     "groq" => HyperLLM.Provider.Groq,
     "openai" => HyperLLM.Provider.OpenAI
   }
@@ -42,7 +43,7 @@ defmodule HyperLLM.Models do
   Example:
 
       iex> HyperLLM.Models.list_providers()
-      ["anthropic", "groq", "openai"]
+      ["anthropic", "cloudflare", "groq", "openai"]
   """
   def list_providers, do: Map.keys(@providers)
 end

lib/providers/cloudflare.ex

@@ -0,0 +1,77 @@
+defmodule HyperLLM.Provider.Cloudflare do
+  @behaviour HyperLLM.Provider
+
+  @moduledoc """
+  Provider implementation for Cloudflare.
+
+  Uses Cloudflare's [OpenAI compatibility API](https://developers.cloudflare.com/workers-ai/configuration/open-ai-compatibility/) for chat completions.
+
+  ## Configuration:
+
+      congfig :hyper_llm, 
+        cloudflare: [
+          api_key: "sk-...",
+          account_id: "..."
+        ]
+  """
+
+  @impl true
+  def completion(messages, config) do
+    model = Keyword.fetch!(config, :model)
+
+    {_request, response} =
+      request("/ai/v1/chat/completions",
+        method: :post,
+        receive_timeout: 30_000,
+        json: %{
+          model: model,
+          messages: messages
+        }
+      )
+
+    case response do
+      %{status: 200, body: body} ->
+        choices = body["choices"]
+        choice = List.first(choices)
+        {:ok, choice["message"]["content"]}
+
+      %{status: 400, body: body} ->
+        {:error, body.error.message}
+
+      %{status: 401} ->
+        {:error, "Cloudflare API key is invalid"}
+
+      %{status: 404} ->
+        {:error, "Cloudflare API not found"}
+
+      %{status: 500} ->
+        {:error, "Cloudflare Server error"}
+
+      _ ->
+        {:error, "Unknown error"}
+    end
+  end
+
+  @impl true
+  @doc """
+  Check if a model is supported by the provider.
+  Currently it's just checking that the model name starts with `@`
+  """
+  def has_model?(model) do
+    String.starts_with?(model, "@")
+  end
+
+  defp request(url, opts) do
+    api_key = HyperLLM.config!(:cloudflare, :api_key)
+    account_id = HyperLLM.config!(:cloudflare, :account_id)
+
+    req =
+      Req.new(
+        auth: {:bearer, api_key},
+        base_url: "https://api.cloudflare.com/client/v4/accounts/#{account_id}",
+        url: url
+      )
+
+    Req.run(req, opts)
+  end
+end

test/models_test.exs

@@ -19,7 +19,7 @@ defmodule HyperLLM.ModelsTest do
 
   describe "list_providers/0" do
     test "returns a list of providers" do
-      assert ["anthropic", "groq", "openai"] = HyperLLM.Models.list_providers()
+      assert ["anthropic", "cloudflare", "groq", "openai"] = HyperLLM.Models.list_providers()
     end
   end
 end