Fix erroneous HeaderMap type hints

Turns out that there are in fact two distinct types of that name which are used to abstract over the
different classes representing header maps in Netty's H1 and H2 implementations. Introduce a
protocol instead which is implemented by both wrapper types for accessing raw header values.

Author: DerGuteMoritz

src/aleph/http.clj

@@ -4,6 +4,7 @@
     [aleph.flow :as flow]
     [aleph.http.client :as client]
     [aleph.http.client-middleware :as middleware]
+    [aleph.http.common :as common]
     [aleph.http.file :as file]
     [aleph.http.server :as server]
     [aleph.http.websocket.client :as ws.client]
@@ -15,8 +16,6 @@
     [manifold.deferred :as d]
     [manifold.executor :as executor])
   (:import
-    (aleph.http.core
-      HeaderMap)
     (aleph.utils
       ConnectionTimeoutException
       PoolTimeoutException
@@ -502,12 +501,8 @@
 (defn get-all
   "Given a header map from an HTTP request or response, returns a collection of
    values associated with the key, rather than a comma-delimited string."
-  [^HeaderMap header-m ^String k]
-  (let [raw-headers (.headers header-m)]
-    (condp instance? raw-headers
-      HttpHeaders (.getAll ^HttpHeaders raw-headers k)
-      Headers (.getAll ^Headers raw-headers k)
-      (throw (IllegalArgumentException. (str "Unknown headers type: " (class raw-headers)))))))
+  [header-m ^String k]
+  (common/get-header-values header-m k))
 
 (defn wrap-ring-async-handler
   "Converts given asynchronous Ring handler to Aleph-compliant handler.

src/aleph/http/client_middleware.clj

@@ -2,6 +2,7 @@
   "This middleware is adapted from clj-http, whose license is amenable to this sort of
    copy/pastery"
   (:require
+    [aleph.http.common :as common]
     ;; leave this dependency to make sure that HeaderMap is already compiled
     [aleph.http.core :as http]
     [aleph.http.schema :as schema]
@@ -743,18 +744,12 @@
             (parse-cookie cookie-spec)
             (netty-cookie->cookie))))
 
-;; we might want to use here http/get-all helper,
-;; but it would result in circular dependencies
 (defn ^:no-doc extract-cookies-from-response-headers
   ([headers]
    (extract-cookies-from-response-headers default-cookie-spec headers))
   ([cookie-spec ^HeaderMap header-m]
-   (let [raw-headers (.headers header-m)]
-     (->> (condp instance? raw-headers
-            HttpHeaders (.getAll ^HttpHeaders raw-headers set-cookie-header-name)
-            Headers (.getAll ^Headers raw-headers set-cookie-header-name)
-            (throw (IllegalArgumentException. (str "Unknown headers type: " (class raw-headers)))))
-          (map (partial decode-set-cookie-header cookie-spec))))))
+   (->> (common/get-header-values header-m set-cookie-header-name)
+        (map (partial decode-set-cookie-header cookie-spec)))))
 
 (defn ^:no-doc handle-cookies [{:keys [cookie-store cookie-spec]
                                 :or   {cookie-spec default-cookie-spec}}

src/aleph/http/common.clj

@@ -29,6 +29,9 @@
 
 (def aleph-server-header "Aleph value for the Server header" (AsciiString. "Aleph/0.7.0-alpha1"))
 
+(defprotocol HeaderMap
+  (get-header-values [m ^String k]))
+
 (defn coerce-element
   "Turns an object into something writable to a Netty channel.
 

src/aleph/http/core.clj

@@ -103,6 +103,8 @@
       s')))
 
 ;; About 10x faster than using Clojure maps, and handles more keys
+;; Note that there's a copy of this in aleph.http.http2 because unfortunately, Netty uses a different class
+;; for representing H2 headers (See https://github.com/netty/netty/issues/8528)
 (def-map-type HeaderMap
   [^HttpHeaders headers
    added
@@ -145,7 +147,10 @@
             default-value
             (if (== 1 (.size vs))
               (.toString (.get vs 0))
-              (str/join "," vs))))))))
+              (str/join "," vs)))))))
+  common/HeaderMap
+  (get-header-values [_ k]
+                     (.getAll headers ^String k)))
 
 (defn headers->map
   "Returns a map of Ring headers from a Netty HttpHeaders object."

src/aleph/http/http2.clj

@@ -423,7 +423,10 @@
                default-value
                (if (== 1 (.size vs))
                  (.toString (.get vs 0))
-                 (str/join "," vs))))))))
+                 (str/join "," vs)))))))
+  common/HeaderMap
+  (get-header-values [_ k]
+                     (.getAll headers ^String k)))
 
 (defn headers->map
   "Returns a map of Ring headers from a Netty Headers object.