Add eastwood linting to bb lint task

Bb lint task is called as part of ci-unit-tests tasks so explicit
call to eastwood no longer required in github action unit-test workflow.

Update deveveloper guide to reflect changes in linting.

Author: lread

.github/workflows/unit-test.yml

@@ -147,8 +147,3 @@ jobs:
     #
     - name: Run CI tests
       run: bb ci-unit-tests
-
-    # Runs after ci-unit-tests (which runs clj-kondo), for fail-fast behavior (as Eastwood is slower)
-    - name: Lint with Eastwood
-      run: clojure -A:test-common:eastwood
-       

bb.edn

@@ -15,7 +15,9 @@
          :leave (let [{:keys [name]} (current-task)] (status/line :detail "\nTASK %s done." name))
          ;; commands
          apply-import-vars {:task apply-import-vars/-main :doc "(check|gen-code) - export APIs statically from templates"}
-         lint              {:task lint/-main              :doc "[--rebuild-cache]"}
+         lint              {:task lint/-main              :doc "[--rebuild-cache] lint source code with clj-kondo and eastwood"}
+         -lint-kondo       {:task lint-kondo/-main        :doc "[--rebuild-cache]"}
+         -lint-eastwood    {:task lint-eastwood/-main}
          test-clj          {:task test-clj/-main          :doc "[--clojure-version (1.9|1.10)]"}
          test-cljs         {:task test-cljs/-main         :doc "use --help for args"}
          test-shadow-cljs  {:task test-shadow-cljs/-main}

doc/02-developer-guide.adoc

@@ -290,7 +290,7 @@ Note that checks are only done against installed `./node_modules`, so you may wa
 
 [#linting]
 == Linting
-We use https://github.com/borkdude/clj-kondo[clj-kondo] for linting rewrite-clj source code.
+We use https://github.com/borkdude/clj-kondo[clj-kondo] and https://github.com/jonase/eastwood[eastwood] to lint rewrite-clj source code.
 
 We fail the build on any lint violations.
 The CI server runs:
@@ -305,6 +305,11 @@ bb lint --rebuild-cache
 
 https://github.com/borkdude/clj-kondo/blob/master/doc/editor-integration.md[Integrate clj-kondo into your editor] to catch mistakes as they happen.
 
+You can optionally:
+
+* `bb -lint-kondo` to only run clj-kondo linter
+* `bb -lint-eastwood` to only run eastwood linter
+
 == API diffs
 Rewrite-clj v1's primary goals include remaining compatible with rewrite-clj v0 and rewrite-cljs and avoiding breaking changes.
 

script/lint.clj

@@ -1,61 +1,12 @@
-#!/usr/bin/env bb
-
 (ns lint
-  (:require [babashka.classpath :as bbcp]
-            [babashka.fs :as fs]
-            [clojure.string :as string]
-            [helper.main :as main]
-            [helper.shell :as shell]
-            [lread.status-line :as status]))
-
-(def clj-kondo-cache ".clj-kondo/.cache")
-
-(defn- cache-exists? []
-  (fs/exists? clj-kondo-cache))
-
-(defn- delete-cache []
-  (when (cache-exists?)
-    (fs/delete-tree clj-kondo-cache)))
-
-(defn- build-cache []
-  (status/line :head "clj-kondo: building cache")
-  (let [clj-cp (-> (shell/command ["clojure" "-A:test:lint-cache" "-Spath"] {:out :string}) :out string/trim)
-        bb-cp (bbcp/get-classpath)]
-    (shell/command ["clojure" "-M:clj-kondo"
-                    "--dependencies" "--copy-configs"
-                    "--lint" clj-cp bb-cp])))
-
-(defn- lint []
-  (if (not (cache-exists?))
-    (build-cache)
-    (let [updated-dep-files (fs/modified-since clj-kondo-cache ["deps.edn" "bb.edn"])]
-      (when (seq updated-dep-files)
-        (status/line :detail "Found deps files newer than lint cache: %s" (mapv str updated-dep-files))
-        (delete-cache)
-        (build-cache))))
-  (status/line :head "clj-kondo: linting")
-  (let [{:keys [exit]}
-        (shell/command-no-exit ["clojure" "-M:clj-kondo"
-                                "--lint" "src" "test" "script" "deps.edn"])]
-    (cond
-      (= 2 exit) (status/die exit "clj-kondo found one or more lint errors")
-      (= 3 exit) (status/die exit "clj-kondo found one or more lint warnings")
-      (> exit 0) (status/die exit "clj-kondo returned unexpected exit code"))))
-
-(def args-usage "Valid args: [options]
-
-Options:
-  --rebuild-cache  Force rebuild of lint cache.
-  --help           Show this help.")
+  (:require [helper.main :as main]
+            [lint-eastwood :as eastwood]
+            [lint-kondo :as kondo]))
 
 (defn -main [& args]
-  (when-let [opts (main/doc-arg-opt args-usage args)]
-    (cond
-      (get opts "--rebuild-cache")
-      (do (delete-cache) (lint))
-
-      :else
-      (lint))))
+  (when (main/doc-arg-opt kondo/args-usage args)
+    (apply kondo/-main args)
+    (eastwood/-main)))
 
 (main/when-invoked-as-script
  (apply -main *command-line-args*))

script/lint_eastwood.clj

@@ -0,0 +1,18 @@
+#!/usr/bin/env bb
+
+(ns lint-eastwood
+  (:require [helper.main :as main]
+            [helper.shell :as shell]
+            [lread.status-line :as status]))
+
+(defn- lint []
+  (status/line :head "eastwood: linting")
+  (shell/command ["clojure" "-M:test-common:eastwood"]))
+
+(defn -main [& args]
+  (when (main/doc-arg-opt args)
+    (lint))
+  nil)
+
+(main/when-invoked-as-script
+ (apply -main *command-line-args*))

script/lint_kondo.clj

@@ -0,0 +1,69 @@
+#!/usr/bin/env bb
+
+(ns lint-kondo
+  (:require [babashka.classpath :as bbcp]
+            [babashka.fs :as fs]
+            [clojure.string :as string]
+            [helper.main :as main]
+            [helper.shell :as shell]
+            [lread.status-line :as status]))
+
+(def clj-kondo-cache ".clj-kondo/.cache")
+
+(defn- cache-exists? []
+  (fs/exists? clj-kondo-cache))
+
+(defn- delete-cache []
+  (when (cache-exists?)
+    (fs/delete-tree clj-kondo-cache)))
+
+(defn- build-cache []
+  (status/line :detail "Building cache")
+  (when (cache-exists?)
+    (delete-cache))
+  (let [clj-cp (-> (shell/command ["clojure" "-A:test:lint-cache" "-Spath"] {:out :string}) :out string/trim)
+        bb-cp (bbcp/get-classpath)]
+    (shell/command ["clojure" "-M:clj-kondo"
+                    "--dependencies" "--copy-configs"
+                    "--lint" clj-cp bb-cp])))
+
+(defn- check-cache [{:keys [rebuild-cache]}]
+  (status/line :head "clj-kondo: cache check")
+  (if-let [rebuild-reason (cond
+                            rebuild-cache
+                            "Rebuild requested"
+
+                            (not (cache-exists?))
+                            "Cache not found"
+
+                            :else
+                            (let [updated-dep-files (fs/modified-since clj-kondo-cache ["deps.edn" "bb.edn"])]
+                              (when (seq updated-dep-files)
+                                (format "Found deps files newer than lint cache: %s" (mapv str updated-dep-files)))))]
+    (do (status/line :detail rebuild-reason)
+        (build-cache))
+    (status/line :detail "Using existing cache")))
+
+(defn- lint [opts]
+  (check-cache opts)
+  (status/line :head "clj-kondo: linting")
+  (let [{:keys [exit]}
+        (shell/command-no-exit ["clojure" "-M:clj-kondo"
+                                "--lint" "src" "test" "script" "deps.edn"])]
+    (cond
+      (= 2 exit) (status/die exit "clj-kondo found one or more lint errors")
+      (= 3 exit) (status/die exit "clj-kondo found one or more lint warnings")
+      (> exit 0) (status/die exit "clj-kondo returned unexpected exit code"))))
+
+(def args-usage "Valid args: [options]
+
+Options:
+  --rebuild-cache  Force rebuild of clj-kondo lint cache.
+  --help           Show this help.")
+
+(defn -main [& args]
+  (when-let [opts (main/doc-arg-opt args-usage args)]
+    (lint {:rebuild-cache (get opts "--rebuild-cache")})))
+
+(main/when-invoked-as-script
+ (apply -main *command-line-args*))