fix conversion of :fn node to sexpr.

Author: Yannick Scherer

src/rewrite_clj/node.clj

@@ -4,6 +4,7 @@
   (:require [rewrite-clj.node
              coerce
              comment
+             fn
              forms
              integer
              keyword
@@ -39,6 +40,9 @@
    comment-node
    comment?]
 
+  [rewrite-clj.node.fn
+   fn-node]
+
   [rewrite-clj.node.forms
    forms-node]
 
@@ -55,7 +59,6 @@
   [rewrite-clj.node.reader-macro
    deref-node
    eval-node
-   fn-node
    reader-macro-node
    uneval-node
    var-node]

src/rewrite_clj/node/fn.clj

@@ -0,0 +1,93 @@
+(ns ^:no-doc rewrite-clj.node.fn
+  (:require [rewrite-clj.node.protocols :as node]
+            [clojure.walk :as w]))
+
+;; ## Conversion
+
+(defn- construct-fn
+  "Construct function form."
+  [syms vararg body]
+  (list
+    'fn*
+    (vec
+      (concat
+        syms
+        (if vararg
+          (list '& vararg))))
+    body))
+
+(defn- sym-index
+  "Get index based on the substring following the parameter's `%`.
+   Zero means vararg."
+  [^String n]
+  (cond (= n "&") 0
+        (= n "") 1
+        (re-matches #"\d+" n) (Long/parseLong n)
+        :else (throw (Exception. "arg literal must be %, %& or %integer."))))
+
+(defn- symbol->gensym
+  "If symbol starting with `%`, convert to respective gensym."
+  [sym-seq vararg? max-n sym]
+  (if (symbol? sym)
+    (let [nm (name sym)]
+      (if (.startsWith nm "%")
+        (let [i (sym-index (subs nm 1))]
+          (if (and (= i 0) (not (realized? vararg?)))
+            (deliver vararg? true))
+          (swap! max-n max i)
+          (nth sym-seq i))))))
+
+(defn- fn-walk
+  "Walk the form and create an expand function form."
+  [form]
+  (let [syms (for [i (range)
+                   :let [base (if (= i 0)
+                                "rest__"
+                                (str "p" i "__"))
+                         s (name (gensym base))]]
+               (symbol (str s "#")))
+        vararg? (promise)
+        max-n (atom 0)
+        body (w/prewalk
+               #(or (symbol->gensym syms vararg? max-n %) %)
+               form)]
+    (construct-fn
+      (take @max-n (rest syms))
+      (if (deref vararg? 0 nil)
+        (first syms))
+      body)))
+
+;; ## Node
+
+(defrecord FnNode [children]
+  node/Node
+  (tag [_] :fn)
+  (printable-only? [_]
+    false)
+  (sexpr [_]
+    (fn-walk (node/sexprs children)))
+  (length [_]
+    (+ 3 (node/sum-lengths children)))
+  (string [_]
+    (str "#(" (node/concat-strings children) ")"))
+
+  node/InnerNode
+  (inner? [_]
+    true)
+  (children [_]
+    children)
+  (replace-children [this children']
+    (assoc this :children children'))
+
+  Object
+  (toString [this]
+    (node/string this)))
+
+(node/make-printable! FnNode)
+
+;; ## Constructor
+
+(defn fn-node
+  "Create node representing an anonymous function."
+  [children]
+  (->FnNode children))

src/rewrite_clj/node/reader_macro.clj

@@ -107,11 +107,6 @@
     (->node :var "'" "" #(list* 'var %) 1 children)
     (recur [children])))
 
-(defn fn-node
-  "Create node representing an anonymous function."
-  [children]
-  (->node :fn "(" ")" nil nil children))
-
 (defn eval-node
   "Create node representing an inline evaluation. (`#=...`)
    Takes either a seq of nodes or a single one."