all integer nodes produce readable strings

Author: eraserhd

src/rewrite_clj/node/integer.clj

@@ -11,13 +11,16 @@
   (length [this]
     (count (node/string this)))
   (string [_]
-    (let [s (.toString (biginteger value) base)
+    (let [sign (if (< value 0)
+                 "-")
+          abs-value (cond-> value (< value 0) -)
+          s (.toString (biginteger abs-value) base)
           prefix (case (long base)
                    8  "0"
                    10 ""
                    16 "0x"
                    (str base "r"))]
-      (str prefix s)))
+      (str sign prefix s)))
 
   Object
   (toString [this]

test/rewrite_clj/node/generators.clj

@@ -0,0 +1,11 @@
+(ns rewrite-clj.node.generators
+  (:require [clojure.test.check.generators :as gen]
+            [rewrite-clj.node :as node]))
+
+(def integer-node
+  (gen/fmap
+    (fn [[n base]]
+      (node/integer-node n base))
+    (gen/tuple
+      (gen/choose Long/MIN_VALUE Long/MAX_VALUE)
+      (gen/choose 2 36))))

test/rewrite_clj/node/integer_test.clj

@@ -0,0 +1,11 @@
+(ns rewrite-clj.node.integer-test
+  (:require [clojure.test.check.properties :as prop]
+            [midje.sweet :refer :all]
+            [rewrite-clj.node :as node]
+            [rewrite-clj.node.generators :as g]
+            [rewrite-clj.test-helpers :refer :all]))
+
+(facts "about integer nodes"
+  (property "all integer nodes produce readable strings" 100
+    (prop/for-all [node g/integer-node]
+      (read-string (node/string node)))))

test/rewrite_clj/test_helpers.clj

@@ -0,0 +1,18 @@
+(ns rewrite-clj.test-helpers
+  (:require [clojure.test.check :as tc]
+            [midje.sweet :refer :all]))
+
+(defn holds
+  "A midje checker to check whether a property \"holds\".
+
+  e.g. (fact (tc/quick-check ...) => holds)"
+  [result]
+  (= true (:result result)))
+
+(defmacro property
+  "Make a test.check property into a midje fact."
+  ([descr prop]
+   `(property ~descr 25 ~prop))
+  ([descr trials prop]
+  `(fact ~descr
+     (tc/quick-check ~trials ~prop) => holds)))