Add picocalc stm32 i2c keyboard code

Author: cuu

Code/picocalc_keyboard/README.md

@@ -0,0 +1,5 @@
+# picocalc keyboard
+ * STM32F103R8T6
+ 
+## Libraries
+* https://github.com/stm32duino/Arduino_Core_STM32/

Code/picocalc_keyboard/backlight.h

@@ -0,0 +1,9 @@
+#ifndef BACKLIGHT_H
+#define BACKLIGHT_H
+
+void lcd_backlight_update_reg();
+
+void lcd_backlight_update(int);
+void kbd_backlight_update(int);
+
+#endif

Code/picocalc_keyboard/backlight.ino

@@ -0,0 +1,59 @@
+
+#include "backlight.h"
+
+#define KBD_BACKLIGHT_SEG 4
+uint8_t kbd_backlight_segs[KBD_BACKLIGHT_SEG] = {20,40,80,110};
+uint8_t kbd_backlight_offset = 0;
+
+void lcd_backlight_update_reg() {
+
+  uint8_t val;
+
+  val = reg_get_value(REG_ID_BKL);
+  val = val & 0xff;
+  
+  analogWriteFrequency(10000); 
+  analogWrite(PA8, val);
+
+}
+
+void lcd_backlight_update(int v) {
+  int val;
+
+  val = reg_get_value(REG_ID_BKL);
+  val += v;
+  if(val < 0) val = 0;
+  if(val > 0xff) val = 0xff;
+ 
+  analogWriteFrequency(10000); 
+  analogWrite(PA8, val);  
+  reg_set_value(REG_ID_BKL,val);
+}
+
+void kbd_backlight_update(int v){
+  int val;
+
+  val = reg_get_value(REG_ID_BK2);
+  val += v;
+  if(val < 20 ) val = 0;
+  if(val > 0xff) val = 0;
+ 
+  analogWriteFrequency(10000); 
+  analogWrite(PC8, val);  
+  reg_set_value(REG_ID_BK2,val);
+}
+
+void kbd_backlight_update_offset(){
+  int val;
+  kbd_backlight_offset++;
+  kbd_backlight_offset =  kbd_backlight_offset % KBD_BACKLIGHT_SEG;
+  
+  val = reg_get_value(REG_ID_BK2);
+  val += kbd_backlight_segs[kbd_backlight_offset];
+  if(val < 20 ) val = 0;
+  if(val > 0xff) val = 0;
+ 
+  analogWriteFrequency(10000); 
+  analogWrite(PC8, val);  
+  reg_set_value(REG_ID_BK2,val);
+}

Code/picocalc_keyboard/battery.h

@@ -0,0 +1,11 @@
+#ifndef BATTERY_H
+#define BATTERY_H
+
+void show_bat_segs();
+
+void low_bat();
+
+void start_chg();
+void stop_chg();
+
+#endif

Code/picocalc_keyboard/battery.ino

@@ -0,0 +1,74 @@
+#include "battery.h"
+
+
+void indicator_led_on(){
+    digitalWrite(PC13, LOW);
+}
+
+void indicator_led_off(){
+    digitalWrite(PC13, HIGH);
+}
+
+void flash_one_time(int ts,int restore_status) {
+    for(int i=0;i<ts;i++) {
+      indicator_led_on();
+      delay(400);
+      indicator_led_off();
+      delay(200);
+    }
+    digitalWrite(PC13,restore_status);
+}
+
+void show_bat_segs(){
+  if(!PMU.isBatteryConnect()) return;
+
+  int pcnt =  PMU.getBatteryPercent();
+  int last_d201_status = digitalRead(PC13);
+  
+  if(pcnt >0 && pcnt < 33) {
+    //show one time
+    flash_one_time(1,last_d201_status);
+  }else if(pcnt >= 33 && pcnt <66){
+    //show 2 times
+     flash_one_time(2,last_d201_status);   
+  }else if(pcnt >=66 && pcnt <= 100){
+    //show 3 times
+     flash_one_time(3,last_d201_status);
+  }
+  
+  if(PMU.isCharging()){
+    start_chg();
+  }
+
+}
+
+void low_bat(){
+  if(PMU.isBatteryConnect() && !PMU.isCharging()){
+    int pcnt = PMU.getBatteryPercent();
+     if(pcnt <= LOW_BAT_VAL){
+      //This is related to the battery charging and discharging logic. If you're not sure what you're doing, please don't modify it, as it could damage the battery.
+        indicator_led_off();      
+        if(pcnt <= 1) {//This is related to the battery charging and discharging logic. If you're not sure what you're doing, please don't modify it, as it could damage the battery.
+          PMU.setChargingLedMode(XPOWERS_CHG_LED_BLINK_4HZ);
+          if(pcnt==0){//This is related to the battery charging and discharging logic. If you're not sure what you're doing, please don't modify it, as it could damage the battery.
+            PMU.shutdown();//This is related to the battery charging and discharging logic. If you're not sure what you're doing, please don't modify it, as it could damage the battery.
+          }
+        }else{
+          PMU.setChargingLedMode(XPOWERS_CHG_LED_ON);
+        }
+     }else{
+        indicator_led_on();
+        PMU.setChargingLedMode(XPOWERS_CHG_LED_OFF);
+     }
+  }
+}
+
+void start_chg(){
+  indicator_led_on();
+  PMU.setChargingLedMode(XPOWERS_CHG_LED_BLINK_1HZ);
+}
+
+void stop_chg(){
+  PMU.setChargingLedMode(XPOWERS_CHG_LED_OFF);
+  low_bat();
+}

Code/picocalc_keyboard/conf_app.h

@@ -0,0 +1,31 @@
+#ifndef CONF_APP_H
+#define CONF_APP_H
+
+#define SLAVE_ADDRESS      0x1F
+#define FIFO_SIZE        31
+
+#define INT_DURATION_MS  1
+
+#ifndef CONFIG_PMU_SDA
+#define CONFIG_PMU_SDA PB11
+#endif
+
+#ifndef CONFIG_PMU_SCL
+#define CONFIG_PMU_SCL PB10
+#endif
+
+#ifndef CONFIG_PMU_IRQ
+#define CONFIG_PMU_IRQ PC9
+#endif
+
+
+#define LOW_BAT_VAL 20
+#define LCD_BACKLIGHT_STEP 10
+
+
+#define bitRead(value, bit) (((value) >> (bit)) & 0x01)
+#define bitSet(value, bit) ((value) |= (1 << (bit)))
+#define bitClear(value, bit) ((value) &= ~(1 << (bit)))
+#define bitWrite(value, bit, bitvalue) ((bitvalue) ? bitSet((value), (bit)) : bitClear((value), (bit) ))
+
+#endif

Code/picocalc_keyboard/fifo.h

@@ -0,0 +1,18 @@
+#ifndef FIFO_H
+#define FIFO_H
+
+#include "keyboard.h"
+
+struct fifo_item {
+  char key;
+  enum key_state state;
+};
+
+uint8_t fifo_count(void);
+void fifo_flush(void);
+bool fifo_enqueue(const struct fifo_item item);
+void fifo_enqueue_force(const struct fifo_item item);
+struct fifo_item fifo_dequeue(void);
+
+
+#endif

Code/picocalc_keyboard/fifo.ino

@@ -0,0 +1,58 @@
+#include "fifo.h"
+
+static struct {
+  struct fifo_item fifo[FIFO_SIZE];
+  uint8_t count;
+  uint8_t read_idx;
+  uint8_t write_idx;
+} fifo_self;
+
+uint8_t fifo_count(void)
+{
+  return fifo_self.count;
+}
+
+void fifo_flush(void)
+{
+  fifo_self.write_idx = 0;
+  fifo_self.read_idx = 0;
+  fifo_self.count = 0;
+}
+
+bool fifo_enqueue(const struct fifo_item item)
+{
+  if (fifo_self.count >= FIFO_SIZE)
+    return false;
+
+  fifo_self.fifo[fifo_self.write_idx++] = item;
+
+  fifo_self.write_idx %= FIFO_SIZE;
+  ++fifo_self.count;
+
+  return true;
+}
+
+void fifo_enqueue_force(const struct fifo_item item)
+{
+  if (fifo_enqueue(item))
+    return;
+
+  fifo_self.fifo[fifo_self.write_idx++] = item;
+  fifo_self.write_idx %= FIFO_SIZE;
+
+  fifo_self.read_idx++;
+  fifo_self.read_idx %= FIFO_SIZE;
+}
+
+struct fifo_item fifo_dequeue(void)
+{
+  struct fifo_item item = { 0 };
+  if (fifo_self.count == 0)
+    return item;
+
+  item = fifo_self.fifo[fifo_self.read_idx++];
+  fifo_self.read_idx %= FIFO_SIZE;
+  --fifo_self.count;
+
+  return item;
+}

Code/picocalc_keyboard/keyboard.h

@@ -0,0 +1,83 @@
+#ifndef KEYBOARD_H
+#define KEYBOARD_H
+
+enum key_state
+{
+    KEY_STATE_IDLE = 0,
+    KEY_STATE_PRESSED,
+    KEY_STATE_HOLD,
+    KEY_STATE_RELEASED,
+};
+
+#define KEY_JOY_UP      0x01
+#define KEY_JOY_DOWN    0x02
+#define KEY_JOY_LEFT    0x03
+#define KEY_JOY_RIGHT   0x04
+#define KEY_JOY_CENTER  0x05
+#define KEY_BTN_LEFT1   0x06
+#define KEY_BTN_RIGHT1  0x07
+
+#define KEY_BACKSPACE   0x08 
+#define KEY_TAB         0x09
+#define KEY_ENTER       0x0A 
+// 0x0D - CARRIAGE RETURN
+#define KEY_BTN_LEFT2   0x11
+#define KEY_BTN_RIGHT2  0x12
+
+
+#define KEY_MOD_ALT     0xA1
+#define KEY_MOD_SHL     0xA2
+#define KEY_MOD_SHR     0xA3
+#define KEY_MOD_SYM     0xA4
+#define KEY_MOD_CTRL    0xA5
+
+#define KEY_ESC       0xB1
+#define KEY_UP        0xb5
+#define KEY_DOWN      0xb6
+#define KEY_LEFT      0xb4
+#define KEY_RIGHT     0xb7
+
+#define KEY_BREAK     0xd0 // == KEY_PAUSE
+#define KEY_INSERT    0xD1
+#define KEY_HOME      0xD2
+#define KEY_DEL       0xD4
+#define KEY_END       0xD5
+#define KEY_PAGE_UP    0xd6
+#define KEY_PAGE_DOWN  0xd7
+
+#define KEY_CAPS_LOCK   0xC1
+
+#define KEY_F1 0x81
+#define KEY_F2 0x82
+#define KEY_F3 0x83
+#define KEY_F4 0x84
+#define KEY_F5 0x85
+#define KEY_F6 0x86
+#define KEY_F7 0x87
+#define KEY_F8 0x88
+#define KEY_F9 0x89
+#define KEY_F10 0x90
+
+typedef void (*key_callback)(char, enum key_state);
+typedef void (*lock_callback)(bool, bool);
+
+void keyboard_process(void);
+void keyboard_set_key_callback(key_callback callback);
+void keyboard_set_lock_callback(lock_callback callback);
+bool keyboard_get_capslock(void);
+bool keyboard_get_numlock(void);
+void keyboard_init(void);
+
+#define NUM_OF_COLS 8
+#define NUM_OF_ROWS 7
+
+#define NUM_OF_BTNS 12
+
+#define KEY_POLL_TIME 16
+
+#define KEY_LIST_SIZE 10
+
+
+#define KEY_HOLD_TIME 300
+
+#endif