Add Grimoire integration

Author: Bozhidar Batsov

CHANGELOG.md

@@ -19,6 +19,8 @@ integration.
 * [#664](https://github.com/clojure-emacs/cider/pull/664): New apropos support:
 search function/var names (bound to <kbd>C-c C-h a</kbd>) or documentation
 (bound to <kbd>C-c C-h d</kbd>).
+* You can open Grimoire's entry for a particular Clojure (built-in) symbol with
+  `cider-grimoire` (<kbd>C-c C-h g</kbd>).
 
 ### Changes
 

README.md

@@ -562,6 +562,7 @@ Keyboard shortcut                    | Description
 <kbd>C-c M-.</kbd>                   | Jump to the resource referenced by the string at point.
 <kbd>M-,</kbd>                       | Return to your pre-jump location.
 <kbd>M-TAB</kbd>                     | Complete the symbol at point.
+<kbd>C-c C-h g</kbd>                 | Lookup symbol in Grimoire.
 <kbd>C-c C-h a</kbd>                 | Apropos search for functions/vars.
 <kbd>C-c C-h d</kbd>                 | Apropos search for documentation.
 

cider-interaction.el

@@ -1408,6 +1408,38 @@ under point, prompts for a var."
   (interactive "P")
   (cider-read-symbol-name "Symbol: " 'cider-doc-lookup query))
 
+(defun cider-grimoire-replace-dashes (name)
+  "Convert the dashes in NAME to a grimoire friendly format."
+  (setq name (if (string-match "\\`-" name)
+                 (replace-match "DASH_" t t name)
+               name))
+  (setq name (if (string-match "-\\'" name)
+                 (replace-match "_DASH" t t name)
+               name))
+  (replace-regexp-in-string "-" "_DASH_" name))
+
+(defun cider-grimoire-url (name ns clojure-version)
+  "Generate a grimoire url from NAME, NS and CLOJURE-VERSION."
+  (let ((clojure-version (concat (substring clojure-version 0 4) "0"))
+        (base-url "http://grimoire.arrdem.com/"))
+    (if name
+        (concat base-url clojure-version "/" ns "/" (cider-grimoire-replace-dashes name) "/")
+      (concat base-url clojure-version "/" ns "/"))))
+
+(defun cider-grimoire-lookup (symbol)
+  "Look up the grimoire documentation for SYMBOL."
+  (-if-let (var-info (cider-var-info symbol))
+      (let ((name (cider-get-var-attr var-info "name"))
+            (ns (cider-get-var-attr var-info "ns")))
+        ;; TODO: add a whitelist of supported namespaces
+        (browse-url (cider-grimoire-url name ns (cider--clojure-version))))
+    (message "Symbol %s not resolved" symbol)))
+
+(defun cider-grimoire (query)
+  "Open the grimoire documentation for QUERY in the default web browser."
+  (interactive "P")
+  (cider-read-symbol-name "Symbol: " 'cider-grimoire-lookup query))
+
 (defun cider-apropos-doc (button)
   "Display documentation for the symbol represented at BUTTON."
   (cider-doc-lookup (button-get button 'apropos-symbol)))

cider-mode.el

@@ -40,6 +40,7 @@
     (define-key map (kbd "M-TAB") 'complete-symbol)
     (define-key map (kbd "C-c C-h a") 'cider-apropos)
     (define-key map (kbd "C-c C-h d") 'cider-apropos-documentation)
+    (define-key map (kbd "C-c C-h g") 'cider-grimoire)
     (define-key map (kbd "C-M-x")   'cider-eval-defun-at-point)
     (define-key map (kbd "C-c C-c") 'cider-eval-defun-at-point)
     (define-key map (kbd "C-x C-e") 'cider-eval-last-sexp)

test/cider-tests.el

@@ -542,3 +542,15 @@
 (ert-deftest test-cider--url-to-file ()
   (should (equal "/space test" (cider--url-to-file "file:/space%20test")))
   (should (equal "C:/space test" (cider--url-to-file "file:/C:/space%20test"))))
+
+;;; grimoire tests
+(ert-deftest cider-grimoire-replace-dashes ()
+  (should (equal (cider-grimoire-replace-dashes "defn-") "defn_DASH"))
+  (should (equal (cider-grimoire-replace-dashes "-map-indexed") "DASH_map_DASH_indexed"))
+  (should (equal (cider-grimoire-replace-dashes "-foo-bar-baz-") "DASH_foo_DASH_bar_DASH_baz_DASH")))
+
+(ert-deftest cider-grimoire-url ()
+  (should (equal "http://grimoire.arrdem.com/1.5.0/clojure.core/defn_DASH/"
+                 (cider-grimoire-url "defn-" "clojure.core" "1.5.1")))
+  (should (equal "http://grimoire.arrdem.com/1.5.0/clojure.core/"
+                 (cider-grimoire-url nil "clojure.core" "1.5.1"))))