New utility function cider-run-chained-hook

Author: vspinu

cider-util.el

@@ -212,6 +212,28 @@ PROP is the name of a text property."
   (when more-text (insert more-text))
   (when break (insert "\n")))
 
+
+;;; Hooks
+
+(defun cider-run-chained-hook (hook arg)
+  "Like `run-hook-with-args' but pass intermediate return values through.
+HOOK is a name of a hook (a symbol).  You can use `add-hook' or
+`remove-hook' to add functions to this variable.  ARG is passed to first
+function.  Its return value is passed to the second function and so forth
+till all functions are called or one of them returns nil.  Return the value
+return by the last called function."
+  (let ((functions (copy-sequence (symbol-value hook))))
+    (while (and functions arg)
+      (if (eq (car functions) t)
+          ;; global value of the hook
+          (let ((functions (default-value hook)))
+            (while (and functions arg)
+              (setq arg (funcall (car functions) arg))
+              (setq functions (cdr functions))))
+        (setq arg (funcall (car functions) arg)))
+      (setq functions (cdr functions)))
+    arg))
+
 
 ;;; Font lock
 

test/cider-util-tests.el

@@ -54,6 +54,22 @@
           cider-codename "Victory")
     (expect (cider--version) :to-equal "0.11.0snapshot (package: 20160301.2217)")))
 
+(defvar some-cider-hook)
+
+(describe "cider-run-chained-hook"
+  :var (some-cider-hook)
+
+  (it "chains correctly"
+    (setq some-cider-hook (list #'upcase (lambda (x) (substring x 2 5))))
+    (expect (cider-run-chained-hook 'some-cider-hook "abcdefg")
+            :to-equal "CDE"))
+
+  (it "exits on first nil"
+    (let (here)
+      (setq some-cider-hook (list #'upcase (lambda (x) nil) (lambda (x) (setq here t))))
+      (cider-run-chained-hook 'some-cider-hook "A")
+      (expect here :to-be nil))))
+
 (describe "cider-symbol-at-point"
   (it "doesn't move the cursor"
     (with-temp-buffer