Show only or hide when on stackframe lines

In order to add "positive" filters, we must only show or hide when we're
actually on a stackframe line. This method takes a very naive way of starting at
the top of the buffer and considering whether to hide all lines. The other lines
just don't have any 'flags properties so they never come up as needing to be
hidden in the `(seq-intersection filters flags)` part, so hide is always false
on them. But if we want to show _only_ those lines with a particular flag this
hides the cause line and any other lines that don't have flags at all.

Author: Dan Sutton

cider-stacktrace.el

@@ -273,6 +273,12 @@ searching and update the hidden count text."
           (replace-match
            (number-to-string cider-stacktrace-hidden-frame-count)))))))
 
+(defun cider-stacktrace-frame-p ()
+  (get-text-property (point) 'cider-stacktrace-frame))
+
+(defun cider-stacktrace-collapsed-p ()
+  (get-text-property (point) 'collapsed))
+
 (defun cider-stacktrace-apply-filters (filters)
   "Set visibility on stack frames using FILTERS.
 Update `cider-stacktrace-hidden-frame-count' and indicate filters applied.
@@ -284,11 +290,13 @@ hidden count."
       (let ((inhibit-read-only t)
             (hidden 0))
         (while (not (eobp))
-          (unless (get-text-property (point) 'collapsed)
+          (when (and (cider-stacktrace-frame-p)
+                     (not (cider-stacktrace-collapsed-p)))
             (let* ((flags (get-text-property (point) 'flags))
                    (hide (if (seq-intersection filters flags) t nil)))
               (when hide (cl-incf hidden))
-              (put-text-property (point) (line-beginning-position 2) 'invisible hide)))
+              (put-text-property (point) (line-beginning-position 2)
+                                 'invisible hide)))
           (forward-line 1))
         (setq cider-stacktrace-hidden-frame-count hidden)))
     (cider-stacktrace-indicate-filters filters)))
@@ -606,7 +614,9 @@ This associates text properties to enable filtering and source navigation."
                 (p2 (search-forward "/"))
                 (p3 (search-forward-regexp "[^/$]+")))
             (put-text-property p1 p4 'font-lock-face 'cider-stacktrace-ns-face)
-            (put-text-property p2 p3 'font-lock-face 'cider-stacktrace-fn-face)))
+            (put-text-property p2 p3 'font-lock-face 'cider-stacktrace-fn-face)
+            (put-text-property (line-beginning-position) (line-end-position)
+                               'cider-stacktrace-frame t)))
         (insert "\n")))))
 
 (declare-function cider-jump-to "cider-interaction")
@@ -717,6 +727,7 @@ through the `cider-stacktrace-suppressed-errors' variable."
     (cider-stacktrace-initialize causes)
     (font-lock-refresh-defaults)))
 
+
 (provide 'cider-stacktrace)
 
 ;;; cider-stacktrace.el ends here

test/cider-stacktrace-tests.el

@@ -83,3 +83,34 @@
                                  (cider-stacktrace-promote-error "x")
                                  :test 'equal)
             :not :to-be-truthy)))
+
+(defun cider--testing-dict (names &optional stipulated)
+  (let ((numeric? (lambda (sym) (member sym '(line column)))))
+    (apply #'nrepl-dict
+           (append (mapcan (lambda (name) (list (symbol-name name)
+                                                (if (funcall numeric? name)
+                                                    4
+                                                  (symbol-name name))))
+                           names)
+                   stipulated))))
+
+(defun cider--frame-of-type (flags)
+  (cider--testing-dict '(file class method name var ns fn line column path)
+                       (list "flags" (mapcar #'symbol-name flags))))
+
+(describe "cider-stacktrace-frame-p-tests"
+  (it "returns true on frames"
+    (with-temp-buffer
+      ;; a stackframe
+      (cider-stacktrace-render-frame (current-buffer)
+                                     (cider--frame-of-type '(clj)))
+      (goto-char (point-min))
+      (expect (cider-stacktrace-frame-p) :to-be-truthy)))
+
+  (it "returns false otherwise"
+    (with-temp-buffer
+      ;; not a stackframe but a compile error
+      (cider-stacktrace-render-compile-error (current-buffer)
+                                             (cider--testing-dict '(file path column line)))
+      (goto-char (point-min))
+      (expect (cider-stacktrace-frame-p) :to-be nil))))