Merge pull request #496 from jonpither/known-endpoints

Cider command uses known endpoints

Author: bbatsov

CHANGELOG.md

@@ -4,6 +4,7 @@
 
 ### New features
 
+* Cider command uses `cider-known-endpoints`.
 * [#490](https://github.com/clojure-emacs/cider/pull/490) Dedicated
   support for `company-mode` in `cider-complete-at-point`.
 * [#460](https://github.com/clojure-emacs/cider/issues/460) Support for

README.md

@@ -268,6 +268,15 @@ underlying project directories:
 (setq cider-switch-to-repl-command 'cider-switch-to-current-repl-buffer)
 ```
 
+* You can configure known endpoints used by the cider command. This is useful if you
+have a list of common host/ports you want to establish remote nREPL connections to.
+Using an optional label is helpful for identifying each host.
+If you want to bypass IDO selection of an endpoint, use <kbd>C-j</kbd>.
+
+```el
+(setq cider-known-endpoints '(("host-a" "10.10.10.1" "7888") ("host-b" "7888")))
+```
+
 ### REPL History
 
 * To make the REPL history wrap around when its end is reached:

cider.el

@@ -70,6 +70,14 @@
 Normally it won't be used, unless `pkg-info' fails to extract the
 version from the CIDER package or library.")
 
+(defcustom cider-known-endpoints nil
+  "Specify a list of custom endpoints where each endpoint is a list.
+For example: '((\"label\" \"host\" \"port\")).
+The label is optional so that '(\"host\" \"port\") will suffice.
+This variable is used by the CIDER command."
+  :type 'list
+  :group 'cider)
+
 ;;;###autoload
 (defun cider-version ()
   "Display CIDER's version."
@@ -104,12 +112,35 @@ start the server."
           (setq nrepl-project-dir project-dir))
         (message "Starting nREPL server...")))))
 
+(defun cider-known-endpoint-candidates ()
+  "Known endpoint candidates for establishing an nREPL connection.
+A default will be included consisting of `nrepl-default-host' and
+`nrepl-default-port'."
+  (-distinct
+   (mapcar (lambda (endpoint)
+             (mapconcat 'identity endpoint " "))
+           (cons (list (nrepl-current-host) (nrepl-default-port))
+                 cider-known-endpoints))))
+
+(defun cider-select-known-endpoint ()
+  "Select an endpoint from known endpoints.
+The returned endpoint has the label removed."
+  (let ((selected-endpoint (split-string
+                            (ido-completing-read
+                             "Host: " (cider-known-endpoint-candidates)))))
+    (if (= 3 (length selected-endpoint))
+        (cdr selected-endpoint)
+      selected-endpoint)))
+
 ;;;###autoload
 (defun cider (host port)
   "Connect to an nREPL server identified by HOST and PORT."
-  (interactive (list (read-string "Host: " (nrepl-current-host) nil (nrepl-current-host))
-                     (string-to-number (let ((port (nrepl-default-port)))
-                                         (read-string "Port: " port nil port)))))
+  (interactive (let ((known-endpoint (when cider-known-endpoints
+                                       (cider-select-known-endpoint))))
+                 (list (or (car known-endpoint)
+                           (read-string "Host: " (nrepl-current-host) nil (nrepl-current-host)))
+                       (string-to-number (let ((port (or (cadr known-endpoint) (nrepl-default-port))))
+                                           (read-string "Port: " port nil port))))))
   (setq cider-current-clojure-buffer (current-buffer))
   (when (nrepl-check-for-repl-buffer `(,host ,port) nil)
     (nrepl-connect host port)))

test/cider-tests.el

@@ -412,3 +412,22 @@
 
       (dolist (buf (list b1 b2 b3 b1-repl b2-repl b3-repl))
         (kill-buffer buf)))))
+
+(ert-deftest test-cider-known-endpoint-candidates ()
+  (let ((cider-known-endpoints '(("label" "host" "port"))))
+    (noflet ((nrepl-current-host () "current-host")
+             (nrepl-default-port () "current-port"))
+      (should (equal '("current-host current-port" "label host port")
+                     (cider-known-endpoint-candidates))))))
+
+(ert-deftest test-cider-known-endpoint-candidates-remove-duplicates ()
+  (let ((cider-known-endpoints '(("label" "host" "port") ("label" "host" "port"))))
+    (noflet ((nrepl-current-host () "current-host")
+             (nrepl-default-port () "current-port"))
+      (should (equal '("current-host current-port" "label host port")
+                     (cider-known-endpoint-candidates))))))
+
+(ert-deftest test-cider-select-known-endpoint-remove-label ()
+  (noflet ((cider-known-endpoint-candidates () '())
+           (ido-completing-read (dontcare dontcare) "label host port"))
+      (should (equal '("host" "port") (cider-select-known-endpoint)))))