Merge pull request #500 from jonpither/rename-buf

Change cider buffers designation

Author: bbatsov

CHANGELOG.md

@@ -4,6 +4,7 @@
 
 ### New features
 
+* New interactive command `cider-change-buffers-designation`.
 * Cider command uses `cider-known-endpoints`.
 * [#490](https://github.com/clojure-emacs/cider/pull/490) Dedicated
   support for `company-mode` in `cider-complete-at-point`.

README.md

@@ -540,6 +540,8 @@ The single prefix <kbd>C-u C-c C-z</kbd>, will switch you to the relevant REPL b
 
 To explicitly choose the REPL buffer that <kbd>C-c C-z</kbd> uses based on project directory, use a double prefix <kbd>C-u C-u C-c C-z</kbd>. This assumes you have `cider-switch-to-relevant-repl` mapped to the var `cider-switch-to-repl-command` which is the default configuration.
 
+To change the designation used for CIDER buffers use <kbd>M-x cider-change-buffers-designation</kbd>. This changes the CIDER REPL buffer, nREPL connection buffer and nREPL server buffer. For example using `cider-change-buffers-designation` with the string "foo" would change `*cider-repl localhost*` to `*cider-repl foo*`.
+
 ## Requirements
 
 * [Leiningen](http://leiningen.org) 2.x (only for `cider-jack-in`)

cider-interaction.el

@@ -143,6 +143,42 @@ endpoint and Clojure version."
                 (list (car nrepl-connection-list))))
   (message (cider--connection-info (car nrepl-connection-list))))
 
+(defun cider-extract-designation-from-current-repl-buffer ()
+  "Extract the designation from the cider repl buffer name."
+  (let ((repl-buffer-name (cider-current-repl-buffer))
+        (template (split-string nrepl-repl-buffer-name-template "%s")))
+    (string-match (format "^%s\\(.*\\)%s"
+                          (regexp-quote (concat (car template) nrepl-buffer-name-separator))
+                          (regexp-quote (cadr template)))
+                  repl-buffer-name)
+    (or (match-string 1 repl-buffer-name) "<no designation>")))
+
+(defun cider-change-buffers-designation ()
+  "Changes the designation in cider buffer names.
+Buffer names changed are cider-repl, nrepl-connection and nrepl-server."
+  (interactive)
+  (cider-ensure-connected)
+  (let* ((designation (read-string (format "Change CIDER buffer designation from '%s': "
+                                           (cider-extract-designation-from-current-repl-buffer))))
+         (new-repl-buffer-name (nrepl-format-buffer-name-template
+                                nrepl-repl-buffer-name-template designation)))
+    (with-current-buffer (cider-current-repl-buffer)
+      (rename-buffer new-repl-buffer-name))
+    (with-current-buffer (nrepl-current-connection-buffer)
+      (setq-local nrepl-repl-buffer new-repl-buffer-name)
+      (let ((new-connection-buffer-name (nrepl-format-buffer-name-template
+                                         nrepl-connection-buffer-name-template designation)))
+        (rename-buffer new-connection-buffer-name)
+        (setq nrepl-connection-list
+              (cons new-connection-buffer-name (cdr nrepl-connection-list)))
+        (when nrepl-server-buffer
+          (let ((new-server-buffer-name (nrepl-format-buffer-name-template
+                                         nrepl-server-buffer-name-template designation)))
+            (with-current-buffer nrepl-server-buffer
+              (rename-buffer new-server-buffer-name))
+            (setq-local nrepl-server-buffer new-server-buffer-name)))))
+    (message "CIDER buffer designation changed to: %s" designation)))
+
 ;;; Switching between REPL & source buffers
 (make-variable-buffer-local
  (defvar cider-last-clojure-buffer nil

test/cider-tests.el

@@ -448,3 +448,69 @@
   (noflet ((cider-known-endpoint-candidates () '())
            (ido-completing-read (dontcare dontcare) "label host port"))
       (should (equal '("host" "port") (cider-select-known-endpoint)))))
+
+(ert-deftest test-cider-change-buffers-designation ()
+  (with-temp-buffer
+    (let ((server-buffer (current-buffer)))
+      (with-temp-buffer
+        (let* ((connection-buffer (current-buffer))
+               (nrepl-connection-list (list (buffer-name connection-buffer))))
+          (with-temp-buffer
+            (let ((repl-buffer (current-buffer)))
+              (with-current-buffer connection-buffer
+                (setq-local nrepl-repl-buffer (buffer-name repl-buffer))
+                (setq-local nrepl-server-buffer (buffer-name server-buffer)))
+              (noflet ((read-string (dontcare) "bob"))
+                (cider-change-buffers-designation)
+                (should (equal "*cider-repl bob*" (buffer-name repl-buffer)))
+                (should (equal "*nrepl-connection bob*" (buffer-name connection-buffer)))
+                (should (equal "*nrepl-server bob*" (buffer-name server-buffer)))))))))))
+
+(ert-deftest test-cider-change-buffers-designation-to-existing-designation-has-no-effect ()
+  (with-temp-buffer
+    (let ((server-buffer (current-buffer)))
+      (with-temp-buffer
+        (let* ((connection-buffer (current-buffer))
+               (nrepl-connection-list (list (buffer-name connection-buffer))))
+          (with-temp-buffer
+            (rename-buffer "*cider-repl bob*") ;; Make a buffer that already has the designation
+            (with-temp-buffer
+              (let* ((repl-buffer (current-buffer))
+                    (before-repl-buffer-name (buffer-name repl-buffer))
+                    (before-connection-buffer-name (buffer-name connection-buffer))
+                    (before-server-buffer-name (buffer-name server-buffer)))
+
+                (with-current-buffer connection-buffer
+                  (setq-local nrepl-repl-buffer (buffer-name repl-buffer))
+                  (setq-local nrepl-server-buffer (buffer-name server-buffer)))
+
+                (noflet ((read-string (dontcare) "bob"))
+                        (should-error
+                         (cider-change-buffers-designation))
+                        (should (equal before-repl-buffer-name (buffer-name repl-buffer)))
+                        (should (equal before-connection-buffer-name (buffer-name connection-buffer)))
+                        (should (equal before-server-buffer-name (buffer-name server-buffer))))))))))))
+
+(ert-deftest cider-extract-designation-from-current-repl-buffer ()
+  (with-temp-buffer
+    (let* ((connection-buffer (current-buffer))
+           (nrepl-connection-list (list (buffer-name connection-buffer))))
+      (with-temp-buffer
+        (let ((repl-buffer (current-buffer)))
+          (rename-buffer "*cider-repl bob*")
+          (with-temp-buffer
+            (with-current-buffer connection-buffer
+              (setq-local nrepl-repl-buffer (buffer-name repl-buffer)))
+            (should (equal "bob" (cider-extract-designation-from-current-repl-buffer)))))))))
+
+(ert-deftest cider-extract-designation-from-current-repl-buffer-no-designation()
+  (with-temp-buffer
+    (let* ((connection-buffer (current-buffer))
+           (nrepl-connection-list (list (buffer-name connection-buffer))))
+      (with-temp-buffer
+        (let ((repl-buffer (current-buffer)))
+          (rename-buffer "*cider-repl*")
+          (with-temp-buffer
+            (with-current-buffer connection-buffer
+              (setq-local nrepl-repl-buffer (buffer-name repl-buffer)))
+            (should (equal "<no designation>" (cider-extract-designation-from-current-repl-buffer)))))))))